Discussion :

[hugues03]

Bonjour à tous,

J'ai sur la ligne 1, un certain nombre de cellule qui se suivent. Je voudrais en scrutant cette ligne, que pour chaque valeur de cellule une checkbox soit insérée (avec comme nom la valeur de la cellule) dans mon userform.

Je sais créer un userform par macro:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub CreerUserform()
 
'Création d'un UserForm
 
Dim UserForm As Object
 
Set UserForm = ThisWorkbook.VBProject.VBComponents.Add(3)
 
With UserForm
.Properties("Caption") = "Le caption de mon Userform"
.Properties("Width") = 300
.Properties("Height") = 200
End With
 
End Sub

En vous remerciant par avance.

[Mytå_Qc]

Salut le forum

Pour t'aider dans ta démarche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
 
Option Explicit 
Sub MakeUserForm() 
 
    Dim MyUserForm As VBComponent 
    Dim NewOptionButton As Msforms.OptionButton 
    Dim NewCommandButton1 As Msforms.CommandButton 
    Dim NewCommandButton2 As Msforms.CommandButton 
    Dim MyComboBox As Msforms.ComboBox 
    Dim N, X As Integer, MaxWidth As Long 
 
     '//First, check the form doesn't already exist
    For N = 1 To ActiveWorkbook.VBProject.VBComponents.Count 
        If ActiveWorkbook.VBProject.VBComponents(N).Name = "NewForm" Then 
            ShowForm 
            Exit Sub 
        Else 
        End If 
    Next N 
 
     '//Make a userform
    Set MyUserForm = ActiveWorkbook.VBProject _ 
    .VBComponents.Add(vbext_ct_MSForm) 
    With MyUserForm 
        .Properties("Height") = 100 
        .Properties("Width") = 200 
        On Error Resume Next 
        .Name = "NewForm" 
        .Properties("Caption") = "Here is your user form" 
    End With 
 
     '//Add a Cancel button to the form
    Set NewCommandButton1 = MyUserForm.Designer.Controls.Add("forms.CommandButton.1") 
    With NewCommandButton1 
        .Caption = "Cancel" 
        .Height = 18 
        .Width = 44 
        .Left = MaxWidth + 147 
        .Top = 6 
    End With 
 
     '//Add an OK button to the form
    Set NewCommandButton2 = MyUserForm.Designer.Controls.Add("forms.CommandButton.1") 
    With NewCommandButton2 
        .Caption = "OK" 
        .Height = 18 
        .Width = 44 
        .Left = MaxWidth + 147 
        .Top = 28 
    End With 
 
     '//Add code on the form for the CommandButtons
    With MyUserForm.CodeModule 
        X = .CountOfLines 
        .InsertLines X + 1, "Sub CommandButton1_Click()" 
        .InsertLines X + 2, "    Unload Me" 
        .InsertLines X + 3, "End Sub" 
        .InsertLines X + 4, "" 
        .InsertLines X + 5, "Sub CommandButton2_Click()" 
        .InsertLines X + 6, "    Unload Me" 
        .InsertLines X + 7, "End Sub" 
    End With 
 
     '//Add a combo box on the form
    Set MyComboBox = MyUserForm.Designer.Controls.Add("Forms.ComboBox.1") 
    With MyComboBox 
        .Name = "Combo1" 
        .Left = 10 
        .Top = 10 
        .Height = 16 
        .Width = 100 
    End With 
 
    ShowForm 
End Sub 
 
Sub ShowForm() 
    NewForm.Show 
End Sub

Mytå_Qc

[hugues03]

Super merci, j'ai adapté tout ça et ca fonctionne!!!

Maintenant je vais essayer d'adapter la hauteur de mon userform au nbre de combobox...

Merci encore!!