Discussion :

[pointp]

Bonjour à tous,
Difficile de s'exprimer clairement sur le titre, en fait je désire supprimer les lignes sur une feuille dont la colonne A correspond à un code si ce code se trouve dans une liste sur un autre fichier. Je vous précise que le code est composé de lettres et de chiffres.
Si vous avez une idée pour réaliser ceci en VBA, ça serait super.

Merci à tous

[zyhack]

Bonjour

en commentaire dans le code les lignes que tu doit modifier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub supprimeLigne()
Dim wbk As Workbook
Dim wshListe As Worksheet
Dim plage As Range
Dim ligne As Long
 
Set wbk = Workbooks("Classeur5") 'classeur liste des codes
Set wshListe = wbk.Worksheets("Feuil1") 'Feuille des codes
Set plage = wshListe.Range("A1:A" & Cells(Rows.Count, 1).End(xlUp).Row) 'plage des codes
ligne = 2' 
 
With Workbooks("Classeur4").Worksheets("Feuil1") 'classeur ou on doit supprimer les lignes
  Do While .Cells(ligne, 1) <> ""
    If Not plage.Find(.Cells(ligne, 1), LookIn:=xlValues, lookat:=xlWhole) Is Nothing Then
      .Cells(ligne, 1).EntireRow.Delete Shift:=xlShiftUp
    Else
      ligne = ligne + 1
    End If
  Loop
End With
 
End Sub

[pointp]

Merci pour ce code, il marche à merveille, je l'ai une peit peu adapté car je voulais qu'il se réalise sur le classeur et la feuille qui est ouverte à l'écran.
Je donne le code modifié pour ceux qui sont intéressé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub supprime ligne()
Dim wbk As Workbook
Dim wbk2 As Workbook
Dim wshliste As Worksheet
Dim plage As Range
Dim ligne As Long
 
Set wbk2 = ActiveWorkbook 'le classeur ouvert
Set wbk = Workbooks("Automatisation BAG.xls")
Set wshliste = wbk.Worksheets("Grand Compte")
Set plage = wshliste.Range("A1:A" & Cells(Rows.Count, 1).End(xlUp).Row)
ligne = 2
 
With wbk2.ActiveSheet 'la feuille ouverte
Do While .Cells(ligne, 1) <> ""
    If Not plage.Find(.Cells(ligne, 1), LookIn:=xlValues, lookat:=xlWhole) Is Nothing Then
      .Cells(ligne, 1).EntireRow.Delete Shift:=xlShiftUp
    Else
      ligne = ligne + 1
    End If
  Loop
End With
End Sub

Encore merci à toi et bonne continuation