Discussion :

[Usgpa]

Bonjour, je m'en remets à vous car je suis au bord du gouffre. J'ai récupérer un fichier qu'un ex collaborateur avait fait et j'essaie tant bien que mal de le rendre utilisable mais je bloque sur certaines fonctionnalités.

Ainsi je souhaiterai, à la fermeture de mon fichier, effacer les lignes dont la cellule en colonne Z est égal (si possible en effacant la cellule la plus haute dans le tableau... ex: si Z1 = Z2 effacer Z1) et si possible effacer les lignes dont la cellule en colonne Z est égal à celle d'une ligne dans ma feuille 2.

Désolé si je me suis mal expliqué et je suis à votre disposition mais croyez-moi, je suis au bord de la crise de nerf...

[zyhack]

Bonjour

j'ai mis un peu de temps à trouver la bonne solution mais essaye ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub supLigne()
Dim ws1 As Worksheet, ws2 As Worksheet
Dim Lws1 As Integer, Lws2 As Integer
Dim VC As String, VT As Range
Dim suivant As Boolean
 
Set ws1 = Worksheets("Feuil4")
Set ws2 = Worksheets("Feuil5")
 
Lws1 = ws1.Cells(Rows.Count, 26).End(xlUp).Row
Lws2 = ws2.Cells(Rows.Count, 26).End(xlUp).Row
suivant = False
 
Do While Lws1 > 1
  VC = ws1.Cells(Lws1, 26) 'valeur à chercher
  Do
    With ws1
      'verifier si la valeur est dans la feuille 1
      Set VT = .Range("Z1:Z" & Lws1 - 1).Find(VC, LookIn:=xlValues, lookAt:=xlWhole)
      If Not VT Is Nothing Then 'si on la trouve au dessus
        .Rows(VT.Row & ":" & VT.Row).Delete Shift:=xlUp 'on supprime la ligne
        Lws1 = Lws1 - 1 '
        suivant = True ' on en cherche un autre
      Else
        suivant = False 'il n'y en a plus -> sortir de la boucle
      End If
    End With
  Loop While suivant = True And Lws1 > 1
 
  'idem en verifiant dans la feuille 2 si la valeur est dans la feuille 2
  If Not ws2.Range("Z1:Z" & Lws2).Find(VC, LookIn:=xlValues, lookAt:=xlWhole) Is Nothing Then _
    ws1.Rows(Lws1 & ":" & Lws1).Delete Shift:=xlUp
  Lws1 = Lws1 - 1
Loop
 
Set ws1 = Nothing
Set ws2 = Nothing
Set VT = Nothing
End Sub

ensuite si ça te conviens il faudra mettre le code dans thisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Workbook_BeforeClose(Cancel As Boolean)
 
'inserer le code ici
 
End Sub

a+

[laetitia]

bonjour Usgpa zyhack peut être comme cela dans thisworkbook a tester eventuellement utiliser with

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim i As Long
 Sheets("Feuil2").Activate
 For i = Cells(Rows.Count, 26).End(xlUp).Row To 2 Step -1
   If Cells(i, 26) = Cells(i - 1, 26) Then Cells(i - 1, 26).EntireRow.Delete
    Next i
ThisWorkbook.Save
End Sub

[mercatog]

Pour la première question

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim Plage As Range
Dim LastLig As Long, i As Long
 
Application.ScreenUpdating = False
With Sheets("Feuil3")
    LastLig = .Cells(Rows.Count, "Z").End(xlUp).Row
    Set Plage = .Range("Z1:Z" & LastLig)
    Plage.AdvancedFilter Action:=xlFilterInPlace, Unique:=True
    For i = LastLig To 2 Step -1
        If .Rows(i).Hidden Then .Rows(i).Delete
    Next i
    On Error Resume Next
    .ShowAllData
    On Error GoTo 0
End With

Edit: Bonjour Laétitia, Zyhak, désolé pas rafraichi

[Usgpa]

Merci beaucoup pour vos réponses !!!