IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Macros et VBA Excel Discussion :

Récupération liste de choix après filtre


Sujet :

Macros et VBA Excel

Vue hybride

Message précédent Message précédent   Message suivant Message suivant
  1. #1
    Membre averti
    Profil pro
    Inscrit en
    Janvier 2010
    Messages
    26
    Détails du profil
    Informations personnelles :
    Localisation : Canada

    Informations forums :
    Inscription : Janvier 2010
    Messages : 26
    Par défaut Récupération liste de choix après filtre
    Bonjour le forum, ca fait un bout de temps que je n'avais pas mis les pieds ici !

    aujourdhui j'ai besoin de votre aide pour résoudre mon problème. Après avoir recherché un peu partour sur le forum je n'ai pas trouvé solution à mon problème.

    Donc, dans mon application j'effectue un filtre dans un tableau. ensuite je veux récupérer la liste de la colonne "I" pour la mettre dans un combo box.
    Jusque là tout fonctionne très bien. Mais une fois affiché j'aimerais que les données soit trié en ordre croissant, car ma méthode les affiche tout pêle mêle....
    voici mon code :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    Sub Test_Liste()
     
     
        Set liste = CreateObject("Scripting.Dictionary")
         For Each c In Sheets("Sheet1").Range("I3", [I65000].End(xlUp)).SpecialCells(xlCellTypeVisible)
         If Not liste.Exists(c.Value) Then liste.Add c.Value, c.Value
        Next c
        Sheets("main").combo_choix.Clear
        For Each i In liste.items
         Sheets("main").combo_choix.AddItem i
        Next
     
        Sheets("Main").Activate
     
    End Sub
    Je ne sais pas si je m'y prend de la bonne façon pour récupérer ma liste de choix, si vous avez une solution elle sera grandement apprécié !

    merci à tous !

  2. #2
    Expert éminent Avatar de mercatog
    Homme Profil pro
    Inscrit en
    Juillet 2008
    Messages
    9 435
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Autre

    Informations forums :
    Inscription : Juillet 2008
    Messages : 9 435
    Par défaut
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    Sub Test_Liste()
    Dim Liste As Object
    Dim Tablo
    Dim c As Range
     
    Set Liste = CreateObject("Scripting.Dictionary")
    With Sheets("Sheet1")
       For Each c In .Range("I3:" & .Cells(Rows.Count, "I").End(xlUp).Address).SpecialCells(xlCellTypeVisible)
          If Not Liste.Exists(c.Value) Then Liste.Add c.Value, c.Value
       Next c
    End With
    Tablo = Liste.items
    Tri Tablo, 0, UBound(Tablo)
    With Sheets("main").combo_choix
       .Clear
       .List = Tablo
    End With
    End Sub
     
    Sub Tri(Tableau, L As Integer, R As Integer)
    Dim G As Integer, D As Integer
    Dim Ref, Temp
     
    Ref = Tableau((L + R) \ 2)
    G = L
    D = R
    Do
       Do While Tableau(G) < Ref
          G = G + 1
       Loop
       Do While Ref < Tableau(D)
          D = D - 1
       Loop
       If G <= D Then
          Temp = Tableau(G)
          Tableau(G) = Tableau(D)
          Tableau(D) = Temp
          G = G + 1
          D = D - 1
       End If
    Loop While G <= D
    If G < R Then Tri Tableau, G, R
    If L < D Then Tri Tableau, L, D
    End Sub

  3. #3
    Membre averti
    Profil pro
    Inscrit en
    Janvier 2010
    Messages
    26
    Détails du profil
    Informations personnelles :
    Localisation : Canada

    Informations forums :
    Inscription : Janvier 2010
    Messages : 26
    Par défaut
    un gros merci mon ami !

    fonctionne nickel !

+ Répondre à la discussion
Cette discussion est résolue.

Discussions similaires

  1. [XL-2010] Listes de choix et filtres
    Par Tankian dans le forum Excel
    Réponses: 2
    Dernier message: 25/09/2013, 22h08
  2. [Vxi3] VB : récupération liste de choix possible
    Par gillou13 dans le forum Deski
    Réponses: 2
    Dernier message: 21/04/2011, 09h38
  3. récupération variable apres liste de choix
    Par polux31 dans le forum Langage
    Réponses: 21
    Dernier message: 15/02/2011, 19h59
  4. Réponses: 5
    Dernier message: 09/05/2006, 15h57
  5. [Débutant][JSP] récupération liste choix multiple
    Par Jovial dans le forum Servlets/JSP
    Réponses: 2
    Dernier message: 14/05/2004, 13h59

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo