Discussion :

[debo41]

Bonjour,

J'ai une erreur 400 en éxécutant ma macro. Je pense que c'est une erreur de syntaxe mais je tourne en rond....

voici ma fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub test_test()
 
 
        Dim TxtComm ' variable pour modification du commentaire
        Dim X ' variable pour chaine à rechercher
        Dim Y ' variable pour chaine de remplacement
        X = "test"
        Y = "ca marche"
 
    For i = 1 To 10
        If (Not (Range(Cells(i, 1)).Comment = "")) Then
                Range(Cells(i, 1)).Select
                TxtComm = ActiveCell.Comment.Text 'récupération du commentaire de la cellule active
                TxtComm = Replace(TxtComm, X, Y) ' remplace une chaine X par un chaine Y
                ActiveCell.Comment.Text Text:=TxtComm ' on ré injecte le commentaire dans la callule active
        End If
    Next i
 
 
 End Sub

Est ce que vous pouvez m'aider

[Minick]

Re,

Ci-joint les corrections de synthaxes et declarations de variable:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub test_test()
    Dim i As Byte ' a adapter si la derniere lignes est au dela de 255
    Dim TxtComm As String ' variable pour modification du commentaire
    Dim X As String ' variable pour chaine à rechercher
    Dim Y As String ' variable pour chaine de remplacement
 
    X = "test"
    Y = "ca marche"
 
    For i = 1 To 10
        With Cells(i, 1)
            If Not .Comment Is Nothing Then 'Si il y a un commentaire dans la cellule traitee
                TxtComm = .Comment.Text 'récupération du commentaire de la cellule traitée
                TxtComm = Replace(TxtComm, X, Y) ' remplace une chaine X par un chaine Y
                .Comment.Text Text:=TxtComm ' on ré injecte le commentaire dans la cellule traitée
            End If
        End With
    Next i
 End Sub

[debo41]

Merci bcp en plus avec les commentaires c'est clair
Merci