Discussion :

[lenul78570]

Bonjour à Tous,
La feuille sur laquelle je souhaite faire fonctionner cette macro se compose ainsi
L1 à 10 : Texte de présentation
L11 : Titre de mes colonnes A à M
En colonne L le titre est "TYPE"
La plage sur laquelle cette macro doit fonctionner est A12:M2012

Ci-dessous le début de mon code, avec au centre "mon ignorance" !
Merci de votre aide
Lenul

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub selection()
'
    Sheets("Prospects").Select
    selectiontype = InputBox("Entrez le nom du TYPE")
    Set colonne = Range("L12:M2012").Find(waht:=selectiontype, LookIn:=xlValue, lookat:=xlWhole)
        If colonne Is Nothing Then
            MsgBox "désolé ce TYPE n'existe pas"
        Else
 
'C'est là que je voudrais dire: "on sélectionne les colonnes
'A à M de toutes les lignes qui ont dans la colonne TYPE
'le TYPE saisi dans InputBox.
'Mais en VBA je sais pas faire...
'Ensuite le code se poursuit comme ci-dessous:
 
            selection.Copy
            Sheets("Recap").Select
            Range("A1").Select
            selction .Paste
        End If
End Sub

[mercatog]

Voilà une proposition avec filtre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Selektion()
Dim SelectionType
Dim Colonne As Range
Dim LastLig As Long
 
With Sheets("Prospects")
    SelectionType = InputBox("Entrez le nom du TYPE")
    If SelectionType <> "" Then
        LastLig = .Cells(Rows.Count, "L").End(xlUp).Row
        Set Colonne = .Range("L12:L" & LastLig).Find(What:=SelectionType, LookIn:=xlValues, lookat:=xlWhole)
        If Colonne Is Nothing Then
            MsgBox "désolé ce TYPE n'existe pas"
        Else
            With .Range("L11:L" & LastLig)
                .AutoFilter
                .AutoFilter field:=1, Criteria1:=SelectionType
            End With
            .Range("A12:M" & LastLig).SpecialCells(xlCellTypeVisible).Copy Sheets("Recap").Range("A1")  'Ici au lieu de A1; tu peux utiliser la première cellule vide
            .Range("L11:L" & LastLig).AutoFilter
        End If
        Set Colonne = Nothing
    End If
End With
End Sub

PS: Attention, dans ton code, beaucoup de fautes de frappe
PS2: Evits d'utiliser des nom de procédures ou variables réservés à vba (exemple ton nom de procédure selection)

[lenul78570]

Merci Mercatog
Ton code fonctionne à merveille
oui j'ai vu les fautes de frappe de mon code
Encore merci
Vraiment ce site mérite toutes les éloges
Lenul