Discussion :

[romain_t]

Bonsoir! J'aimerais vous demander de l'aide sur un point que je n'ai pas réussi à éclaircir. J'ai un plateau de jeu sur lequel je dois générer des pièces de jeu, c'est à dire des arbres, ou des personnages. Le problème, c'est que ces arbres doivent etre générés de façon aléatoire sur mon plateau. Quelqu'un pourrait-il m'expliquer comment réaliser une fonction aléatoire ?
En vous remerciant d'avance de l'intérêt que vous voudrez bien porter à ma requête, je vous souhaite de passer une bonne soirée.

[FR119492]

Salut!

comment réaliser une fonction aléatoire

Sauf erreur, le Fortran comporte une fonction ran. Sinon, voir "Numerical Recipes", chapitre 7.
Jean-Marc Blanc

[Grame]

Bonsoir! J'aimerais vous demander de l'aide sur un point que je n'ai pas réussi à éclaircir. J'ai un plateau de jeu sur lequel je dois générer des pièces de jeu, c'est à dire des arbres, ou des personnages. Le problème, c'est que ces arbres doivent etre générés de façon aléatoire sur mon plateau. Quelqu'un pourrait-il m'expliquer comment réaliser une fonction aléatoire ?
En vous remerciant d'avance de l'intérêt que vous voudrez bien porter à ma requête, je vous souhaite de passer une bonne soirée.

Il n'y a pas de générateur de nombres aléatoires dans la norme FORTRAN77.
Certains compilateurs en propose un. Sinon, tu peux utiliser ce petit générateur
simple que m'avait donné un collègue probabiliste il y a quelques années.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
      FUNCTION RANDOM (N0)
 
C     On initialise N0 a une valeur quelconque ENTIERE 
C     RANDOM renvoie un REEL compris entre 0.0 et 1.0
 
      REAL      RANDOM
      INTEGER   N0, K, CONST1, CONST2, CONST3, CONST4
      PARAMETER (CONST1 = 127773)
      PARAMETER (CONST2 = 16807)
      PARAMETER (CONST3 = 2836)
      PARAMETER (CONST4 = 2147483647)
 
      K = N0 / CONST1
      N0 = CONST2 * (N0 - K * CONST1) - K * CONST3
      IF (N0 .LT. 0) N0 = N0 + CONST4
      RANDOM = REAL(N0) / REAL(CONST4)
 
      END

[romain_t]

Merci beaucoup! Je vais tester comme ca alors! Et au niveau de la syntaxe je la relie au programme principal comme une subroutine non ?
Merci beaucoup

[Grame]

Merci beaucoup! Je vais tester comme ca alors! Et au niveau de la syntaxe je la relie au programme principal comme une subroutine non ?
Merci beaucoup

Non pas une subroutine, une fonction.

Si tu cherches à générer des entiers, j'ai une autre petit générateur encore plus simple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
      FUNCTION GECOLI (GRAINE,BORNE)
      INTEGER GECOLI, GRAINE, BORNE
      INTEGER A,M
 
      PARAMETER (A=1117)
      PARAMETER (M=19991)
 
      GRAINE = MOD(GRAINE * A, M)
      GECOLI = 1 + INT(BORNE * REAL(GRAINE) / REAL(M))
 
      END

Tu peux l'appeler à partir d'u programme suivant, par exemple , pour en tester l'équiprobabilité, qui n'est pas mauvaise compte tenu de l'extrême simplicité du générateur, juste congruentiel linéaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
      PROGRAM TESRND
 
C- Borne 
      INTEGER BORNE
      PARAMETER (BORNE=10)
C- Fonction générateur
      INTEGER GECOLI
C- Graine initiale du générateur
      INTEGER GRAIN0
C- Boucle
      INTEGER I
C- Nombre tiré 
      INTEGER N     
C- Tableaux contenant les tirages
      INTEGER RES(BORNE)
C- Nombre de tirages  
      INTEGER TIRS
 
C- Initialisations globales
      GRAIN0 = 7333 
      TIRS = 10000000 
      DO 10 I=1,BORNE
         RES(I)=0
10    CONTINUE
 
      WRITE(*,*)'Graine de départ  = ',GRAIN0
      WRITE(*,*)'Borne             = ',BORNE 
      WRITE(*,*)'Nombre de tirages = ',TIRS   
      DO 20  I=1,TIRS
        N = GECOLI (GRAIN0, BORNE)
        RES(N) = RES(N) + 1
20    CONTINUE
 
      WRITE(*,*)'Résultats'
      DO 30 I=1,BORNE
         WRITE(*,*) I, RES(I)
30    CONTINUE  
 
      END