Discussion :

[syl20k]

Bonjour,
J’ai un catalogue produit avec une colonne référence. Dans cette colonne , j’ai des références tel que FX450, BPA10, LC2905
Je veux savoir si il serait possible de séparer les chiffres et les lettres pour créer 2 colonnes supplémentaires, une colonne avec FX et BPA et la deuxième colonne avec chiffre correspondant.

Merci à vous

[mercatog]

Bonjour
à l'aide de boucles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub test()
Dim i As Long
Dim mot As String
Dim j As Byte
 
For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row 'colonne A
    mot = Range("A" & i).Value
    For j = 1 To Len(mot)
        If IsNumeric(Mid(mot, j, 1)) Then Exit For
    Next j
    Range("B" & i).Value = Left(mot, j - 1)
    Range("C" & i).Value = Mid(mot, j)
Next i
End Sub

[Fvandermeulen]

Salut et bienvenue sur le Forum,

Voici une proposition, il y a certainement d'autres méthode.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Split_ref()
Dim DerLig As Long, r As Long, s As Long
 
DerLig = Sheets("TaFeuil").Cells(Columns(1).Cells.Count, 1).End(xlUp).Row 'Récupère le N° de la dernière ligne remplie sur base de la colonne A
 
For r = 2 To DerLig 'Boucle sur toutes les lignes remplies, à partir de 2 car j'imagine qu'il y des titres
    For s = 1 To Len(Cells(r, 1)) 'boucle sur chaque caractère contenu dans la cellule
        If Not IsNumeric(Mid(Cells(r, 1), s, 1)) Then 'Vérifie si la caractère est numérique
            Sheets("TaFeuil").Cells(r, 2) = Sheets("TaFeuil").Cells(r, 2) & Mid(Cells(r, 1), s, 1) 'Non numérique donc dans colonne B avec principe de concaténation
        Else
            Sheets("TaFeuil").Cells(r, 3) = Sheets("TaFeuil").Cells(r, 3) & Mid(Cells(r, 1), s, 1) 'Numérique donc dans colonne C, toujours avec principe de concaténation
        End If
    Next s 'Passe au caractère suivant
Next r 'Passe à la ligne suivante
 
End Sub

A+

Edit: Salut Mercatog, désolé pas rafraichi...