Discussion :

[tipouciais]

Bonjour,

J'ai un tableau et je veux que mon code parcourt ce tableau tant que les valeurs des cellules de la colonne 1 sont égales et dès qu'elles sont différentes j'aimerais qu'il s'arrête et réalise une somme des valeurs qui sont au niveau de ma deuxième colonne. Ensuite quand il a sommé, il reprend la ou il s'est arrêté et fait pareil pour les cellules suivantes identiques de la colonne1
Je sais que je peux faire une boucle do while mais mon problème provient de la sélection des cellules à sommer par rapport à ma première colonne.

Si je ne suis pas claire et je crois que je ne le suis pas, dites moi.
J'ai un rapport à rendre et je bloque la dessus

Merci encore pour votre aide

[Qwazerty]

Salut
Essai avec ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub tipouciais()
Dim CelF As Range
Dim ValueCel As Long 'mettre As Double si il y a des nombres a virgule
Dim NbCel As Integer
 
NbCel = 0
ValueCel = Range("A2") 'je suppose ici que les données commence a la ligne 2, la ligne 1 contenant les entetes
 
For Each CelF In Range("A2", Cells(Rows.Count, "A").End(xlUp).Offset(1, 0))
    If (ValueCel <> CelF) Then
        CelF.Offset(-1, 1).Value = NbCel * CelF.Offset(-1, 0)
        NbCel = 1
        ValueCel = CelF
    Else
        NbCel = NbCel + 1
    End If
Next
 
End Sub

Par contre tu devrais poser ce genre de question directement sur le forum VBA Excel, tu aura plus rapidement une réponse je pense.
A++
Qwaz

[pgz]

Bonjour à tous, bonjour à QWAZERTY

Le pb n'est pas posé avec une grande précision, mais je crois comprendre que les valeurs à comparer sont en colonne A et les valeurs à additionner en colonne B.
Si c'est le cas, QWAZERTY, la multiplication de convient pas.
EN fait on ne sait pas ce qu'il y a en colonne 1 (j'ai postulé qu'il s'agit de texte), en colonne 2 cela ne peut être que des nombres (sans autre précision), et on ne sait pas où il faut écrire la somme, j'ai supposé en colonne 3 sur la dernière ligne de chaque groupement.

Avec ces hypthèses, cela me donne cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub tipouciais()
Dim sh As Excel.Worksheet, CelF As Range
Dim ValueCel As String 'mettre single ou double s'il s'agit de nombres
Dim dblSomme As Double
 
dblSomme = 0
Set sh = ThisWorkbook.Worksheets("Feuil1")
ValueCel = Range("A2") 'je suppose ici que les données commence a la ligne 2, la ligne 1 contenant les entetes
 
For Each CelF In sh.Range("A2:A" & sh.Cells(Application.Rows.Count, 1).End(xlUp).Row + 1)
    If (ValueCel <> CelF) Then
        CelF.Offset(-1, 2).Value = dblSomme
        ValueCel = CelF
        dblSomme = CelF.Offset(0, 1)
    Else
        dblSomme = dblSomme + CelF.Offset(0, 1)
    End If
Next CelF
 
Set sh = Nothing
End Sub

Cordialement,

PGZ

[mercatog]

Bonjour,
les sous totaux sont fait pour ça (données triés au préalable)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub test()
Dim LastLig As Long
LastLig = Cells(Rows.Count, 1).End(xlUp).Row
Range("A1:B" & LastLig).Subtotal GroupBy:=1, Function:=xlSum, _
    TotalList:=Array(2), Replace:=True, SummaryBelowData:=True
End Sub

[Qwazerty]

Salut a tous
Ah oui, en effet pgz, tu as tout a fait raison, le problème était pourtant énoncé clairement et je suis clairement passé a coté ^^.
++
Qwaz