Discussion :

[Bocage]

Bonjour/soir forum, tous et chacun,

Longtime no see !
Un tout petit problème se pose pour séparer une chaine de caractère. Le champ contient à la queue le loup: ville - province/état(occasionnel) - pays séparé par des virgules et espaces. Ces infos seront utilisées ailleurs.
J'ai écris ce code et le problème est que cela change le contenu initial du champ. Ce que je ne souhaite pas pour des raisons de répétition. Quelqu'un a une sln simple pour remédier à cela.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub separevillepays()
 
Dim i As Integer
Dim tableau() As String
Dim LaCellule As Range
Dim MaPlage As Range
Dim Xls As Worksheet
 
    Set Xls = ThisWorkbook.Worksheets("Test")
    Set MaPlage = Range(Xls.Cells(1, 1), Xls.Cells(6, 1))
 
  '  MaPlage.Replace " ", ""   'enlève les espaces vides superflus
  '  MaPlage.Replace ",", " "  'remplace les virgules par des espaces vides
 
    For Each LaCellule In MaPlage.Cells
 
        tableau = Split(LaCellule)
 
        For i = 0 To UBound(tableau)  'peut y avoir ville/étatouprovince/pays
           Xls.Cells(LaCellule.Row, i + 2).Value = tableau(i)
           Debug.Print tableau(i)
        Next i
 
    Next LaCellule
 
End Sub

Merci à l'avance
Bo

[mercatog]

Bonsoir,
pas assez clair pour moi

le problème est que cela change le contenu initial du champ. Ce que je ne souhaite pas pour des raisons de répétition. Quelqu'un a une sln simple pour remédier à cela.

si le séparateur est une virgule, ton code fonctionnera avec la modification sur la ligne du split

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub SepareVillePays()
Dim Xls As Worksheet
Dim i As Integer
Dim tableau() As String
Dim LaCellule As Range, MaPlage As Range
 
Set Xls = ThisWorkbook.Worksheets("Test")
Set MaPlage = Xls.Range(Xls.Cells(1, 1), Xls.Cells(6, 1))
For Each LaCellule In MaPlage
    tableau = Split(LaCellule, ",")
    For i = 0 To UBound(tableau)  'peut y avoir ville/étatouprovince/pays
       Xls.Cells(LaCellule.Row, i + 2).Value = Trim(tableau(i))
    Next i
Next LaCellule
 
End Sub

[Bocage]

Bonjour Mercatog, forum,

Pas tjrs clair en effet. Je ne voulais pas altérer le contenu de la plage de départ. Les repères ne sont plus les mêmes lorsque l'algorithme est répété. Je ne crois pas être beaucoup plus limpide ici...

Le split avec la virgule est la sln, a regarder à nouveau l'exemple de split et de join de SilkyRoad (Manip les chaines de caractère...) j'aurai du me douter.

Ça fait exactement ce que je souhaitais, merci!c'est très apprécié!

Bo