Discussion :

[lemaany]

Bonjour à tous,

J'ai un petit souci avec excel et je ne m'en sors pas!!!

Je suis en train d'éditer un fichier de suivi des heures et je souhaiterais convertir le format de la saisie pour avoir un format d'affichage différent.

C'est à dire, dans une même cellule je voudrais rentrer un temps en heure et minute (hh:mm) et qu'il soit converti automatiquement (à la fin de la saisie) au format décimal. Par exemple pour un temps de 3:30 (3h30 minutes) saisi, je souhaiterais avoir 3,5 qui s'affiche.

Merci de votre aide à tous.

[Fvandermeulen]

Salut,
Les heures dans Excel, sous le format hh:mm, cache une décimale qui est un 24ème d'une journée.
Donc si tu as en A1 "03:30" et que tu mets en B1:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=A1*24

Tu obtiendras 3,50; par contre à part passer par une autre colonne ou par VBA, je ne sais pas comment faire ça en une fois comme tu le souhaites.
A+

[Gorfael]

Salut lemaany et le forum
Le problème est qu'excel ne détecte pas les heures (avec mes maigres connaissances). Il faut donc lui demander de vérifier que la cellule contient un nombre. Et que ça ne concerne qu'une partie de la feuille. Un premier jet :
Clic-droit sur le nom de l'onglet>> Menu Contextuel>>Visualiser le code et tu colles la macro suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo Err_Worksheet_Change
Dim Plage As Range, Cel As Range
Set Plage = Intersect(Target, Columns(1))
If Plage Is Nothing Then Exit Sub
Application.EnableEvents = False
For Each Cel In Plage
    If IsNumeric(Cel) Then
        Cel = Hour(Cel) + (Minute(Cel) / 60)
        Cel.numberformat = "General"
    End If
Next Cel
Sort_Worksheet_Change:
    Application.EnableEvents = True
    Exit Sub
Err_Worksheet_Change:
    MsgBox Err.Description, , "Erreur Excel n°" & Err.Number
    Resume Sort_Worksheet_Change
End Sub

Tout nombre entré manuellement en colonne 1 (A) sera considéré comme devant être convertit en nombre décimal representant l'heure décimal :
Si tu entres 3:30 en A1, tu verras le résultat (format standard).
A+

[lemaany]

Merci de ta réponse!! ça m'aide vraiment.

J'aurais une autre question!
quelle est la syntaxe pour appliquer cette maco a certaines cellules de ma fiche excel??
C'est à dire, comment le mettre pour les colonnes 16 et 18, sur les lignes allant de 15 à 26 inclus??
Merci par avance

[Gorfael]

Salut lemaany et le forum

C'est à dire, comment le mettre pour les colonnes 16 et 18, sur les lignes allant de 15 à 26 inclus??

C'est-à-dire De P15 à P26 et de R15 à R26 : il suffit de remplacer la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Plage = Intersect(Target, Columns(1))

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Plage = Intersect(Target, Range("P15:P26,R15:R26"))

A+

[lemaany]

Merci beaucoup de ton aide précieuse