Discussion :

[aalex_38]

Bonjour,

J'ai renseigné les infobulles, dans les divers controles d'un userform.

Je voudrai pouvoir corriger l'orthographe de ces textes.

Pour extraire les textes, pas de problème, mon soucis c'est pour renseigner les controltiptext une fois les textes corrigés :

Ici le code qui extrait les textes, reste plus qu'a mettre à jour les différents contrôles de l'userform (UEXP) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub infobulles()
Dim Ctrl As Control
Dim Nonglet As String
Dim i As Integer
Dim Wk As Worksheet
 
Nonglet = "Propriétés de l'USF UEXP"
On Error Resume Next
Worksheets(Nonglet).Delete
Set Wk = Worksheets.Add
' Set Wk = Worksheets(Nonglet)
 
With Wk
    .Name = Nonglet
End With
 
'Boucle sur la collection de contrôles pour correction orthographique ControlTipText
For Each Ctrl In Uexp.Controls
    i = i + 1
    With Ctrl
    Cells(i, 1) = .Name
    Cells(i, 2) = .ControlTipText
   '  .ControlTipText = Cells(i, 2) 'Non valorisé définitivement
    End With
Next Ctrl
 
' ThisWorkbook.VBProject.VBComponents("Uexp") => ok pour les propriétés mais pour les controles de l'USF ?
End Sub

[Krovax]

Salut,
Je viens de tester ceci qui a l'air de fonctionner

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

UserForm1.Controls(Cells(1, 1).text).ControlTipText = Cells(1, 2).text

Du coup je dirais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
for i = 1 to derniereligne
     Uexp.Controls(Cells(i, 1).text).ControlTipText = Cells(i, 2) 
next i

J'espère que cela t'aidera, et que j'ai bien compris le problème

Edit : je retir ce que j'ai dit quand je relance le userform j'ai de nouveau le premier tipstext, désolé Il ne remplace pas celui défini à la création

[aalex_38]

Edit : je retir ce que j'ai dit quand je relance le userform j'ai de nouveau le premier tipstext, désolé Il ne remplace pas celui défini à la création

Effectivement, c'est bien là que se situe mon problème et je n'ai pas encore trouvé comment faire.

[aalex_38]

Re,

Je pense avoir trouvé, la solution ici, il ne me reste plus qu'a l'adapter.

[aalex_38]

Pour ceux que ça pourrait eventuellement intéresser, le code complet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Private Sub infobullesII()
Dim Ctrl As Control
Dim Nonglet As String
Dim i As Integer
Dim Wk As Worksheet
' ---------------------------------------------------------------------------------- '
' Creation de l'onglet
' ---------------------------------------------------------------------------------- '
Nonglet = "Propriétés de l'USF UEXP"
 
On Error Resume Next
Worksheets(Nonglet).Delete: Set Wk = Worksheets.Add   : Wk.Name = Nonglet 'SCND
'SCND Set Wk = Worksheets(Nonglet)
 
' ---------------------------------------------------------------------------------- '
'Boucle sur la collection de contrôles pour correction orthographique ControlTipText
' ---------------------------------------------------------------------------------- '
For Each Ctrl In ThisWorkbook.VBProject.VBComponents("Uexp").Designer.Controls
   i = i + 1
    With Ctrl
        Cells(i, 1) = Ctrl.Name
        Cells(i, 2) = Ctrl.ControlTipText
    End With
Next Ctrl
 
' -------------------------- '
' Correction orthographique
' -------------------------- '
 Cells.CheckSpelling SpellLang:=1036
 ' DoEvents
' ---------------------------------------------------------------------------------- '
' Mise à jour des ControlTiptext
' ---------------------------------------------------------------------------------- '
i = 0
For Each Ctrl In ThisWorkbook.VBProject.VBComponents("Uexp").Designer.Controls
 '   Debug.Print Ctrl.Name
   i = i + 1
   Ctrl.ControlTipText = Cells(i, 2)
Next Ctrl
 
End Sub

Edit : je travaille sur un code un peu similaire avant de mettre résolu.
Edit2 : Finalement j'ai repris ce code pour toutes les propriétés et ça fonctionne bien
Edit3 : en fait non, il me semble que j'ai un petit soucis pour le nom je fais des tests.