Discussion :

[pael013]

Bonjour,

J'ai des centaines de tableaux de largeur fixe 4 colonnes mais de longueur variable jusqu'à 10 lignes.
Ces tableaux sont affichés l'un après l'autre dans le sens horizontal.
je voudrais essayer de faire une macro qui puisse les afficher l'un en dessous de l'autre (sens verticale).

Quelqu'un a t-il une piste?

Merci d'avance !!!

[Fvandermeulen]

Salut,
Juste pour être précis, sur la même feuille, ou une nouvelle ?
A tu déjà des notions sur les boucles ?
A+

[pael013]

Je prefere sur une nouvelle feuille, mais sur la meme ca me convient aussi !!!
Oui j'ai quelques notion de boucle !!!

[Fvandermeulen]

Re,
Voici un petit code avec la méthode Copy.
Je n'ai pas intégrer l'ajout de feuille dans le code, je te laisse faire si nécessaire. La feuille dans laquelle on place les tableaux est appelé FeuilCible dans le code, le code fonctionnera en l'état pour autant que la feuille active soit ta feuille source, sinon précise le nom de celle-ci.
Bonne continuation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub CopieTableau()
 
Dim c As Long, DerLigne As Long, LigPaste As Long, DerCol As Long
 
DerCol = Cells(1, Rows(1).Cells.Count).End(xlToLeft).Column 'Def la dernière colonne remplie
 
For c = 1 To DerCol Step 4 'On ballaie toute les 4 colonnes jusquà la dernière remplie
 
    DerLigne = Cells(Columns(c).Cells.Count, c).End(xlUp).Row 'défini la dernière ligne remplie
    LigPaste = Sheets("FeuilCible").Cells(Columns(1).Cells.Count, 1).End(xlUp).Row + 1 'Défini la ligne où copier, colonne A
 
    Range(Cells(1, c), Cells(DerLigne, c + 3)).Copy Destination:=Sheets("FeuilCible").Cells(LigPaste, 1)
    Range(Cells(1, c), Cells(DerLigne, c + 3)).Clear 'si tu veux effacer le tableau source
Next c
 
End Sub

Edit: Ajout d'un comment dans le code; le clear uniquement si il faut effacer les données du tableau initial.

[pael013]

J'ai testé le code,
mais j'ai quelques problemes...
Quand je teste avec un seul tableau, ca se passe bien !!!
Lorsque je mets plus de 1 tableau ca bug, il me copie une partie de 2eme.

Faut-il changer le step?

ci joint mon fichier réduit et ce que je veux faire avec sur la feuille 2

[Fvandermeulen]

Re,
Tu ne nous avais pas tout dit, ce ne sont pas des Tableaux au sens stricte.
Mais tu as raison, c'est le step qu'il faut adapter car je n'avais pas considéré d'espace entre les tableaux.
MAIS comme tu n'as pas un tableau au sens strict et que tu utilise un MergeCell dans la première colonne de chaque tableau la définition de ce tableau dans le code est faux.
Il faut donc utiliser la 2ème colonne de chaque tableau pour définir la dernière ligne et la ligne où copier (j'ai également ajouté l'espace)
N'hésites pas si tu as des questions.
A+

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub CopieTableau()
 
Dim c As Long, DerLigne As Long, LigPaste As Long, DerCol As Long
 
DerCol = Cells(2, Rows(2).Cells.Count).End(xlToLeft).Column 'Def la dernière colonne remplie sur base de la ligne 2
 
For c = 1 To DerCol Step 5 'On ballaie toute les 5 colonnes jusquà la dernière remplie
 
    DerLigne = Cells(Columns(c + 1).Cells.Count, c + 1).End(xlUp).Row 'défini la dernière ligne remplie selon 2è col du tableau
    LigPaste = Sheets("FeuilCible").Cells(Columns(2).Cells.Count, 2).End(xlUp).Row + 2 'Défini la ligne où copier, colonne B
 
    Range(Cells(2, c), Cells(DerLigne, c + 3)).Copy Destination:=Sheets("FeuilCible").Cells(LigPaste, 1)
    'Range(Cells(1, c), Cells(DerLigne, c + 3)).Clear 'si tu veux effacer le tableau source
Next c
 
End Sub

Edit: corrections de coquilles

[diude54]

Evidemment tu as une colonne vide entre tes tableaux, essaye avec step 5