Discussion :

[doudou8mc]

Bonjour,


j'ai une colonne ("A") qui contient par exemple des noms de mois (ex: les 5 premières cellules contiennent "janvier", les 3 d'apres "fevrier", les 4 d'apres "mars" et ainsi de suite). Je souhaite écrire un code pour qu'un indice parcours la colonne et qu'il fusionne les cellules contenant le meme nom de mois.

Merci d'avance

[vbnetnet]

tu peux faire ça à travers d une macros
tu peux faire la fusion lors de l enregistrement de macro et apres tu a le droit de voir le code inscrit de ctte macro
1. enregistrer la macro en cliquant sur le menu outil et macro et enregistrer macro
2 .fais la fusion de ce que tu veux
3 .arrete la macro en cliquant la boutton arreter l enregistrement
4. clique sur executer macro et faires selectionner notre macro
5. ne fais pas "executer" mais "plutot" modifier pour acceder au code et voila le code que tu cherche c est une astuce pour atteindre un code si on a pas les outils pour en faire implimenter.

[youn1096]

bonjour,

Ensuite si tu veux pas lancer la macro pour chaque mois, essayes de boucler sur les cellules de ta colonrne contenant les mois, de vérifier le nombre de cellule qui contiennent le même mois et de lancer ta macro enregistrée en fonction de ces cellules (plage de cellules)

Cdt

[LeForestier]

Bonjour,
Une macro qui fait ça .. ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub FusionnerCel()
Dim Lig As Long, M, P As Long, Lig1 As Long
Dim DerLig As Long
    Application.DisplayAlerts = False
    Lig1 = 1 'Commencer à la ligne 1 à adapter
    With Sheets("Feuil3") 'nom de la feuille à adapter
        DerLig = Range("A65536").End(xlUp).Row
        M = Cells(Lig1, 1): P = Lig1
        For Lig = Lig1 To DerLig + 1
            If Cells(Lig, 1) <> M Then
                Range(Cells(P, 1), Cells(Lig - 1, 1)).Merge
                M = Cells(Lig, 1): P = Lig
            End If
        Next Lig
        With .Range(Cells(Lig1, 1), Cells(Lig - 1, 1))
            .HorizontalAlignment = xlCenter
            .VerticalAlignment = xlCenter
        End With
    End With
    Application.DisplayAlerts = True
End Sub

M'étonnerais quand même que l'éditeur de macro sorte ça !!
A+

[doudou8mc]

Bonjour,

merci à tous pour votre collaboration et un MERCI spécial pour leforestier pour le code proposé. En effet c'est exactement ce qu'il me fallait .

merci et à bientôt

[LeForestier]

Je viens de m'apercevoir que j'ai oublié des points un peu partout.
Ca fonctionne si la feuille est active mais risque de problème si non.
Remplacer la macro par..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub FusionnerCel()
Dim Lig As Long, M, P As Long, Lig1 As Long
Dim DerLig As Long
    Application.DisplayAlerts = False
    Lig1 = 1 'Commencer à la ligne 1 à adapter
    With Sheets("Feuil3") 'nom de la feuille à adapter
        DerLig = .Range("A65536").End(xlUp).Row
        M = .Cells(Lig1, 1): P = Lig1
        For Lig = Lig1 To DerLig + 1
            If .Cells(Lig, 1) <> M Then
                .Range(.Cells(P, 1), .Cells(Lig - 1, 1)).Merge
                M = .Cells(Lig, 1): P = Lig
            End If
        Next Lig
        With .Range(.Cells(Lig1, 1), .Cells(Lig - 1, 1))
            .HorizontalAlignment = xlCenter
            .VerticalAlignment = xlCenter
        End With
    End With
    Application.DisplayAlerts = True
End Sub

Y a rien qui change si ce n'est les points.
A+