Discussion :

[tuntulin]

Bonjour, j'aimerais pouvoir remplir une combobox à deux colonne avec une source de donnée excel mais avec duex colonnes différente. En fait j'aimerais que ma premiere colonne de la combobox se remplisse avec la colonne A de ma feuille excel et que ma seconde colonne se remplisse avec la colonne R de la meme feuille excel.

Pour l'instant, je n'arrive qu'a remplir avec A et B si je met deux colonne, A B C si je met 3....

Merci de me donner vos solutions.

[Pierrot93]

Bonjour,

essaye peut être le code ci-dessous, à utiliser dans le module de ton USF, s'applique aux valeurs de la feuille active :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub UserForm_Initialize()
Dim i As Integer
With ComboBox1
    .ColumnCount = 2
    For i = 1 To Range("A65536").End(xlUp).Row
        .AddItem Cells(i, 1)
        .List(i - 1, 1) = Cells(i, 18)
    Next i
End With
End Sub

bonne journée
@+

[Didier Gonard]

Bonjour,

une autre piste :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Explicit
Option Base 1 'voir aide vba si besoin
 
Private Sub UserForm_Initialize()
Dim cell As Range
Dim I As Integer
Dim J As Integer
Dim intNumcol1 As Integer
Dim intNumcol2 As Integer
Dim objZoneCible1 As Object
Dim objZoneCible2 As Object
Dim tabvarForCbo() As Variant
Dim lngDimTabMax As Long
 
intNumcol1 = 1 'on prend ici les colonnes A et D
intNumcol2 = 4
'il est aisé d'ajouter d'autres col si besoin..
Set objZoneCible1 = Range(Cells(2, intNumcol1), Cells(Rows.Count, intNumcol1).End(xlUp)) 'on met les plages voulues en variable
Set objZoneCible2 = Range(Cells(2, intNumcol2), Cells(Rows.Count, intNumcol2).End(xlUp)) 'on a ici une ligne de titre...
 
lngDimTabMax = Application.WorksheetFunction.Max(objZoneCible1.Count, objZoneCible2.Count) 'on calcule la valeur de la colonne la + grande.
ReDim tabvarForCbo(lngDimTabMax, lngDimTabMax) ' on dimentionne notre array en conséquence
 
For Each cell In objZoneCible1 'on alimente notre  array
    I = I + 1
    tabvarForCbo(1, I) = cell.Value
Next cell
For Each cell In objZoneCible2
    J = J + 1
    tabvarForCbo(2, J) = cell.Value
Next cell
cboExemple.Column = tabvarForCbo ' on charge notre combobox
 
Set objZoneCible1 = Nothing
Set objZoneCible2 = Nothing
Set cell = Nothing
End Sub

nb : tuntulin, penses à indiquer ta version d'excel, entre 2003 et 2007, les nombres de colonnes et de lignes ont changés

cordialement,

Didier

[tuntulin]

Ca marche merci....