suppresion automatique pour tous les utilisateurs

**bubu87** · 31/07/2009, 14h31

bonjour à tous ,
j'ai créer un batch dans le but de supprimer les fichiers temporaires
il marche tr‚s bien cependant j'aimerais que quand je le lance il se fasse sut tous les fichiers de tous les utilisateurs de la machine (administrateur,moi,unautre....)y aurait il un moyen pour le faire?
merci d'avance pour vos conseils avisés
PS le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
@echo off
echo "script de supression des fichiers temporairs dans les profils utilisateurs"

echo "supression des fichiers inutiles"

if exist "%HomePath%\Cookies" del /F /S /Q "%HomePath%\Cookies\*.*"
if exist "%HomePath%\Local Settings\Temporary Internet Files" del /F /S /Q "%HomePath%\Local Settings\Temporary Internet Files\*.*"
if exist "%HomePath%\Application Data\Microsoft\Word" del /F /S /Q "%HomePath%\Application Data\Microsoft\Word\*.tmp">nul
if exist "%HomePath%\Application Data\Microsoft\Word" del /F /S /Q "%HomePath%\Application Data\Microsoft\Word\*.wbk">nul
if exist "%HomePath%\Application Data\Microsoft\Office\R‚cent" del /F /S /Q "%HomePath%\Application Data\Microsoft\Office\R‚cent\*.*"
if exist "%HomePath%\Recent" del /F /S /Q "%HomePath%\Recent\*.*"
sleep 10
@echo off

PS: je ne parle pas de script d'ouverture de session

**Mac LAK** · 01/08/2009, 16h57

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
@echo off
setlocal enableextensions enabledelayedexpansion
REM Récupération du "Documents and settings" : parent du profil de l'utilisateur courant.
pushd %HOMEDRIVE%%HOMEPATH%
cd ..
REM Parcours des profils eux-mêmes.
for /d %%P in ("*.*") do (
	set HOME=%%P
	echo Nettoyage du profil : %%~nP
	REM Rediriger vers NUL + stderr vers stdin permet de rendre le del totalement muet.
	echo      Suppression : Cookies.
	del /F /S /Q "!HOME!\Cookies\*.*" > NUL 2>&1
	echo      Suppression : Fichiers temporaires.
	del /F /S /Q "!HOME!\Local Settings\Temporary Internet Files\*.*" > NUL 2>&1
	del /F /S /Q "!HOME!\Application Data\Microsoft\Word\*.tmp" > NUL 2>&1
	echo      Suppression : Fichiers récents.
	del /F /S /Q "!HOME!\Application Data\Microsoft\Office\R‚cent\*.*" > NUL 2>&1
	del /F /S /Q "!HOME!\Recent\*.*" > NUL 2>&1
)
popd

Cela devrait fonctionner... N'oublie pas non plus, en dehors des profils eux-même, de supprimer le répertoire temporaire global ("%TMP" et "%TEMP").

EDIT : N'oublie pas non plus que ça ne marchera pas si tu n'as pas administrateur lorsque tu lances le script !

**ram-0000** · 02/08/2009, 22h04

Envoyé par Mac LAK;4534074[B

EDIT :[/B] N'oublie pas non plus que ça ne marchera pas si tu n'as pas administrateur lorsque tu lances le script !

Et encore, cela ne marchera que si l'administrateur à des droits sur le ou les répertoires concernés.

Il y a des configurations où l'administrateur n'a aucun droit même en lecture mis à part le droit de s'approprier les répertoires.

**Mac LAK** · 03/08/2009, 00h53

Envoyé par ram-0000

Et encore, cela ne marchera que si l'administrateur à des droits sur le ou les répertoires concernés.

Il y a des configurations où l'administrateur n'a aucun droit même en lecture mis à part le droit de s'approprier les répertoires.

C'est vrai : ce n'est pas courant, mais ça existe. Bon, reconnaissons quand même que ce n'est jamais le cas "par défaut", il faudrait le faire exprès, mais c'est effectivement possible.

**bubu87** · 03/08/2009, 14h10

Merci beaucoup ce script marche à merveille

Encore merci

**bubu87** · 06/08/2009, 10h51

rebonjour,
j'ai une petite question dans le but d'améliorer le script : est il possible de lister les fichiers qui sont supprimés (dans un but de verification)

j'ai créé un fichier log qui liste les users sur lesquels le script opére
mais je n'arrive pas a faire de même pour les fichier...

Merci d'avance