Discussion :

[NOOSH2]

Bonjour,
comment pourrais je fermer et sauvegarder un classeur si il est inactif (pas de mouvement ou click souris ou pas de modif de cellule) depuis par exemple 10mn.J'ai consulté les 30 dernieres pages mais sans succès
Merci A+

[laetitia]

bonjour NOOSH2 le forum essai ce code par defaut delai 1 minute a adapter
dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
Option Private Module
'Ti
'Delai est le temps d'inactivité maxi en minutes
Const Delai = 1
Sub Programmation()
Dim Heure As Date
  Heure = Now + TimeValue("00:" & Delai & ":00")
  ThisWorkbook.Names.Add Name:="ChronoTime", RefersTo:=Heure
  ThisWorkbook.Names.Add Name:="Chrono", RefersTo:=0
  Application.OnTime Heure, "Interruption"
End Sub
Private Sub Interruption()
  With ThisWorkbook
    If .Sheets(1).Evaluate("Chrono") = 0 Then
      .Save
      .Close
    Else
      Programmation
    End If
  End With
End Sub
Sub SupprimeInterruption()
Dim Heure As Date
 On Error Resume Next
Heure = ThisWorkbook.Sheets(1).Evaluate("ChronoTime")
 Application.OnTime Heure, "Interruption", schedule:=False
End Sub

dans thisworkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Option Explicit
Private Sub Workbook_BeforeClose(Cancel As Boolean)
 SupprimeInterruption
End Sub
Private Sub Workbook_Open()
  Programmation
End Sub
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Excel.Range)
  ThisWorkbook.Names("Chrono").Value = 1
End Sub

l'auteur un certain TI

[NOOSH2]

cela fonctionne parfaitement, c'est beau la connaissance

[kiki29]

Salut, fonctionne sauf si une personne saisit qqch dans une cellule mais ne valide pas le contenu.