Discussion :

[Kimaos]

Bonsoir le forum,

J’ai un code d’impression d’une image contenue dans un userform, et lorsque je lance l’impression, configurant préalablement l’imprimante en mode paysage, ça sort systématiquement en portrait.

L’impression que je cherche le plus étant le paysage, ce serait sympa si quelqu’un me filait son bout de code, à défaut d’avoir un code qui permettrait de choisir le mode d’impression portrait/paysage.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim Img As String
Private Sub ImprimerImage_Click()
Dim ImpDefaut As Variant, FTemp As Worksheet
If Img = "" Then Exit Sub
If Application.Dialogs(Excel.XlBuiltInDialog.xlDialogPrinterSetup).Show = True Then
Application.DisplayAlerts = False
ImpDefaut = ActivePrinter
Set FTemp = Sheets.Add
FTemp.Pictures.Insert Img
FTemp.PrintOut
FTemp.Delete
Application.ActivePrinter = ImpDefaut
End If
Application.DisplayAlerts = True
End Sub

http://sd-1.archive-host.com/membres...ntaire_102.zip

Cordialement, Kim.

[casefayere]

Bonsoir,
tu peux essayer ce code, non vérifié

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.PageSetup.Orientation = xlLandscape' pour paysage

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.PageSetup.Orientation = xlPortrait 'pour portrait

[Antoniom]

Hello Kimaos, Casefayere,

Modifies ton code comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub ImprimerImage_Click()
 
    Dim ImpDefaut As Variant, FTemp As Worksheet
 
    If Img = "" Then Exit Sub
 
    If Application.Dialogs(Excel.XlBuiltInDialog.xlDialogPrinterSetup).Show = True Then
 
    Application.DisplayAlerts = False
    ImpDefaut = ActivePrinter
 
    Set FTemp = Sheets.Add
 
    '*********************************************************************************************
    'With ActiveSheet.PageSetup ' Tu peux aussi jouer sur le zoom ici, mais attention pas plus de 115% sinon ça dépasse !
    '    .Zoom = 115
    'End With
    '*********************************************************************************************
 
        FTemp.PageSetup.Orientation = xlLandscape 'Ici pour le paysage.
        FTemp.Pictures.Insert Img
        FTemp.PageSetup.CenterHorizontally = True 'Ici pour centrer Horizontalement.
        FTemp.PageSetup.CenterVertically = True 'Ici pour centrer Verticalement.
        FTemp.PrintOut
        FTemp.Delete
        Application.ActivePrinter = ImpDefaut
    End If
 
    Application.DisplayAlerts = True
 
End Sub

Bonne nuit !

Anton.

[Kimaos]

Hello Casfayere, Antoniom, le forum,

Merci pour le code, ça fonctionne bien,
Je vous souhaite une excellente journée,

Amicalement, Kim.