Discussion :

[yahnou]

Bonjour,
je cherche à convertir certaines variables d'alphanumérique à numérique ! le problème est que pour qq variables j'ai des modalités "NSP', 'Non disponible', 'Missing Data'.

Ma question : Existe t-il un codage particulier qui pourrait me permettre de garder l'information lorsque je transforme les variables ?
je crois savoir qu'il existe un codage .A, .N ou .D mais je ne trouve rien la-dessus sur le net !

Merci à vous !

[Bruno.Thevenin]

Bonjour,

Pour transformer une variable caractère en numérique, il faut passer par la fonction INPUT en spécifiant l'INFORMAT de la variable (4. dans l'exemple) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

input ('1234', 4.) ;

En cas d'erreur (cas de 'NSP' par exemple), le résultat de la fonction INPUT sera la valeur MISSING numérique (Généralement représentée par le caractère '.').

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
data test ;
   input mavar $ ;
   cards ;
123
NSP
456
;
run ;
data test_num ;
   set test ;
   mavar_num=input (mavar, 3.) ;
run ;

Bon courage !

[yahnou]

Merci bien mais mon soucis est que les "NSP" ne passent pas en point lorsque je transforme la variable ! je pourrais toujours appliquer un code pour ces données style '9999' ou '8888' mais je crois qu'il existe un codage spécial !

[Bruno.Thevenin]

Bonjour,

les "NSP" ne passent pas en point

Que veux-tu dire exactement par là ?
Qu'obtiens-tu comme résultat ?

Bon courage !

[yahnou]

Lorsque je transforme ma variable en numérique, je ne veux pas perdre l'information 'NSP'... si j'fais un input classique le 'NSP' passe en 'point'... alors que j'veux un codage spécial en numérique pour ce genre de modalités !
j'espère être plus clair

[Bruno.Thevenin]

Bonjour,

Effectivement tu as un problème : une variable numérique ne peut contenir que des chiffres ou la valeur manquante (symbolisée par '.') !!!
Si tu veux retrouver à la place du point une valeur type 'NSP', il faut passer par un FORMAT d'affichage.
Mais la valeur réelle de ta donnée sera toujours MISSING ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
DATA test ;
   input mavar $ ;
   cards ;
123
NSP
456
;
run ;
proc format ;
   value myfmt
      . = 'NSP'
   ;
run ;
DATA test_num ;
   SET test ;
   format mavar_num myfmt. ;
   mavar_num=input (mavar, 3.) ;
run ;

Bon courage !

[yahnou]

On m'a dit qu'il existait un code style .A, .N ou .D !!
J'vais attendre le retour de cette personne pour avoir plus d'infos du coup !!
Merci qd même !

[RemiBousquet]

Effectivement,
tu peux coder comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
data test ;
    mavar = "Non disponible" ; output ;
    mavar = "3"              ; output ;
    mavar = "NSP"            ; output ;
    mavar = "2"              ; output ;
    mavar = "Missing Data"   ; output ;
    mavar = "0"              ; output ;
    mavar = ""               ; output ;    
run ;     
 
DATA test_num ;
   SET test ;
        if mavar = "NSP"            then mavar_num = .n ;
   else if mavar = "Non disponible" then mavar_num = .d ;
   else if mavar = "Missing Data"   then mavar_num = .m ;
   else    mavar_num=input (mavar, 3.) ;
run ;                                      
 
proc freq data = test_num ;
    tables mavar 
           mavar_num 
           / missing ;
run ;

Ca te donnerait après un proc freq par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
                                                       Cumulative    Cumulative
                 mavar_num    Frequency     Percent     Frequency      Percent
                 ƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒƒ
                         .           1       14.29             1        14.29
                         D           1       14.29             2        28.57
                         M           1       14.29             3        42.86
                         N           1       14.29             4        57.14
                         0           1       14.29             5        71.43
                         2           1       14.29             6        85.71
                         3           1       14.29             7       100.00

[Bruno.Thevenin]

Bonjour,

Bravo Rémi, je ne connaissais pas cette notation...
Pour mémoire, je laisse le code proposé plus haut pour (ma) mémoire !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
DATA test ;
   input mavar:$14. ;
   cards ;
0
123
Non-disponible
Missing_Data
Nsp
.
;
run ;
DATA test_num ;
   SET test ;
   select(strip(upcase(mavar)));
      when('NON-DISPONIBLE') mavar_num= .d ;
      when('MISSING_DATA')   mavar_num= .m ;
      when('NSP')            mavar_num= .n ;
      otherwise mavar_num=input (mavar, 3.) ;
   end;
run ;

[olivier.decourt]

Bonsoir.
Pour compléter les réponses de Rémi et de Bruno, j'ajoute qu'on peut aussi se bricoler son propre informat pour l'utiliser dans INPUT.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
DATA work.test ;
   INPUT maVar :$14. ;
   CARDS ;
0
123
Non-disponible
Missing_Data
Nsp
.
;
RUN ;
PROC FORMAT ;
	INVALUE import
		"Non-disponible" = .N
		"Missing_Data"   = .M
		"Nsp"            = .A
		.                = .
		OTHER            = [BEST12.]
	;
RUN ;
DATA work.test ;
	SET work.test ;
	maVarNum = INPUT(maVar, import.) ;
RUN ;

Et tant qu'on parle de valeurs manquantes, puisque tu n'en trouves pas mention sur Internet, je me dis que c'est l'occasion d'un petit rappel :

• il y a 27 valeurs manquantes numériques distinctes en SAS : ., mais aussi .1, .B, ..., .Z
• quand on écrit dans un test (IF ou WHERE) maVar = ., on ne teste qu'un type de valeur manquante
• mais quand on écrit dans un WHERE maVar IS MISSING, ou dans un IF MISSING(maVar), on prend en compte les 27 genres de valeurs manquantes

Olivier