Discussion :

[riri2938]

Bonjour, avec access 2000, j'ai mis au point une application avec laquelle je lance un service web, puis copie l'écran avant de revenir dans mon appli et de vider le contenu du presse papier à l'intérieur d'une zone de texte. Je lance ensuite le traitement de conversion pour en extraire les données et le format convenu. Je souhaite néanmoins modifier cette procédure afin de la simplifier et je souhaiterai affecter le contenu du presse papier à une variable afin de manipuler cette variable. Est-ce réalisable et surtout ai-je été assez clair dans mes explications. Par avance, merci de vore aide

[Jean-Philippe André]

salut,
tout est dispo dans la

http://access.developpez.com/sources...s#PressePapier

et

http://access.developpez.com/faq/?pa...#Copier_Coller

bonne lecture

[riri2938]

J'avais déjà lu ces faqs mais je n'ai pas trouvé les réponses que j'étais venu chercher. Moi c'est l'inverse de la faq que je cherche. Je peux copier le contenu de mon presse papier avec la commande << sendkeys "^v" mais ce que je souhiate effectuer c'est affecter la valeur du contenu de mon presse papier à une variable, du style :
dim myvariable as string
myvariable = "contenu du presse papier"

Merci de votre aide

[Jean-Philippe André]

Si tu veux, fais ton coller dans un fichier texte, et récupère le contenu du dit fichier dans une variable string

sinon voir cette discussion : http://www.developpez.net/forums/d53...s-appactivate/

[riri2938]

En fait, j'effectue 2 fois la passe vers mon appli DOS et donc 2 fois un Ctrl C et 2 fois un Ctrl V, et je cherche donc à stoker mon premier Ctrl C pour le concaténer avec mon 2ème Ctrl C, afin de ne faire qu'un seul Ctrl V.
Est-ce possible

[LedZeppII]

Bonjour,

Code pour faire l'opération inverse de celle proposée dans les sources, Copier le contenu d'un contrôle vers le presse papier Windows

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Option Explicit
 
Private Declare Function GlobalLock Lib "kernel32.dll" (ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32.dll" (ByVal hMem As Long) As Boolean
Private Declare Function GlobalSize Lib "kernel32.dll" (ByVal hMem As Long) As Long
 
Private Declare Function lstrlen Lib "kernel32" (ByVal lpString As Any) As Long
Private Declare Function lstrcpy Lib "kernel32" (ByVal lpStrDest As String, ByVal lpStrSce As Any) As Long
 
Const CF_TEXT As Long = 1
Private Declare Function OpenClipboard Lib "user32.dll" (ByVal hWndNewOwner As Long) As Boolean
Private Declare Function CloseClipboard Lib "user32.dll" () As Boolean
Private Declare Function IsClipboardFormatAvailable Lib "user32.dll" (ByVal wFormat As Long) As Long
Private Declare Function GetClipboardData Lib "user32.dll" (ByVal wFormat As Long) As Long
 
Function GetClipboardTextAnsi() As String
Dim lRetVal As Long, lpSce As Long
Dim lAvailableFormat As Long
Dim hGlobMem As Long, lMemBytes As Long
Dim strTexte As String, lChars As Long
 
If IsClipboardFormatAvailable(CF_TEXT) = 0 Then Exit Function
lAvailableFormat = CF_TEXT
 
lRetVal = OpenClipboard(Application.hWndAccessApp)
If lRetVal = 0 Then Exit Function
 
hGlobMem = GetClipboardData(lAvailableFormat)
If hGlobMem = 0 Then
   CloseClipboard
   Exit Function
End If
 
lpSce = GlobalLock(hGlobMem)
If lpSce = 0 Then
   CloseClipboard
   Exit Function
End If
 
lMemBytes = GlobalSize(hGlobMem)
lChars = lstrlen(ByVal lpSce)
If lChars <= lMemBytes Then
   strTexte = String(lChars, vbNullChar)
   lstrcpy strTexte, ByVal lpSce
End If
 
GlobalUnlock hGlobMem
CloseClipboard
 
GetClipboardTextAnsi = strTexte
End Function

La fonction GetClipboardTextAnsi() renvoie une String si le presse-papier contient du texte.
Si le contenu du presse-papier n'est pas disponible au format texte, la fonction renvoie une chaîne de caractère vide.

A+

[riri2938]

merci LedZepII
Je vais essayer ce code et tiens informer la communauté du résultat

[riri2938]

ça marche, merci encore LedZeppII (cette fois avec les 2 P)