Discussion :

[nicollok]

Bonjour,
Je voudrais créer une feuille et lui attribuer du code en vba, sous excel.
Il me renvoi l'erreur suivante:

Erreur d'exécution '9'
L'indice n'appartient pas à la sélection

J'ai vu que le sujet était traité, mais je ne trouve pas mes réponses.

Mon code est le suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Worksheets.Add.Name = nomFeuille
Worksheets(nomFeuille).Activate
Code = "Private Sub Worksheet_Activate()" & vbCrLf
Code = Code & ...
...
With ActiveWorkbook.VBProject.VBComponents(nomFeuille).CodeModule
    .insertlines .CountOfLines + 1, Code
End With

Je ne comprend pas!!

J'ai oublié de préciser que mon erreur se fait sur la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
With ActiveWorkbook.VBProject.VBComponents(nomFeuille).CodeModule

[=JBO=]

Bonjour,

Je crois que ton souci vient d'une confusion entre (1) le nom de la feuille pour Excel et (2) le nom du VBComponent correspondant pour VBA.

L'objet Worksheet possède une propriété CodeName qui retourne le nom du VBComponent correspondant.

Je te propose une petite fonction:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Public Sub Ajoute(sNomFeuille As String)
    Dim oWS As Excel.Worksheet
    Dim sNomComposant As String
    Dim sCode As String
 
    Set oWS = Worksheets.Add
    oWS.Name = sNomFeuille
    sNomComposant = oWS.CodeName
 
    sCode = "Private Sub Worksheet_Activate()" & vbCrLf & "End Sub"
 
    With oWS.Parent.VBProject.VBComponents(sNomComposant).CodeModule
        .InsertLines .CountOfLines + 1, sCode
    End With
End Sub