Discussion :

[gomodo]

Bonjour à tous.
Ma problématique, c'est modifier un fichier sql via awk :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
SET FOREIGN_KEY_CHECKS=0;
 
CREATE TABLE `AUTOTASK` (
  `ID_AUTOTASK` varchar(30) NOT NULL,
  `var_name` varchar(30) NOT NULL,
  PRIMARY KEY  (`id_autotask`,`var_name`)
) ENGINE=InnoDB DEFAULT CHARSET=latin1;
 
INSERT INTO `autotask` VALUES ('1HOUR_AUTOTASK.PHP', 'BASETIME');

Je souhaite harmoniser tous les champs et les noms de table en minuscule. Concrêtement mettre en minuscule toutes les chaines avec la syntaxe `ABC` ou `_ABC` ou `A_BC` ou `ABC_`, etc

Il parait que c'est simple avec l'outils awk (j'utilise une version java jawk qui répond exactement à la même syntaxe).

Mon expression rationnelle fonctionne, j'y suis presque avec le script :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
{ 
if (gsub(/\`[A-Z,_]*\`/,tolower($0), $0)==1) {print $0;}
else {print;}
}

Voici le résultat:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
SET FOREIGN_KEY_CHECKS=0;

CREATE TABLE create table `autotask` ( (
    `id_autotask` varchar(30) not null, varchar(30) NOT NULL,
  `var_name` varchar(30) NOT NULL,
  PRIMARY KEY  (`id_autotask  primary key  (`id_autotask`,`var_name`)var_name`)
) ENGINE=InnoDB DEFAULT CHARSET=latin1;

INSERT INTO `autotask` VALUES ('1HOUR_AUTOTASK.PHP', 'BASETIME');

Je constate que gsub m'insère la ligne entière (en rouge) au lieu de lu mot détecté. Je pense que mon print $0 ne doit pas être bon.

Y a des connaisseurs qui peuvent m'aider ?

Merci.

[jmelyn]

Bonjour,

Voici une solution qui fonctionne, avec prise en compte de l'indentation (awk supprime normalement les blancs de début et de fin!). Cependant, les blancs multiples à l'intérieur d'une ligne sont réduits à un seul (on le voit à la ligne qui commence par PRIMARY KEY).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
awk '
{
    indent = match($0, /[^ ]/)
    for (i = 1; i < indent; i++)
    {
        printf " "
    }
    space = ""
    for (i = 1; i <= NF; i++)
    {
        if ($i ~ /^`[[:upper:]_]*`$/)
        {
            $i = tolower($i)
        }
        printf "%s%s", space, $i
        space = " "
    }
    printf "\n"
}'

La première boucle for ajoute autant de blancs qu'il y en avait (c'est l'indentation qui est replacée). Attention: s'il y a des tabulations, ça ne marche pas.
La seconde boucle for écrit chaque ligne mot par mot et transforment ceux qui sont de la forme "lettres majuscules avec peut-être un '_'".

Edit: Oups, erreur grossière, les mots ne sont pas obligatoirement séparés par des blancs... je vais revoir ma copie

[jmelyn]

Bin désolé pour cette première version foireuse, en voici une qui me semble bien plus correcte. Il n'y a plus de problème d'indentation ni de multiples blancs au milieu des lignes. Tout reste identique (sauf ce qui doit changer, bien sûr). De plus, il peut y avoir de multiples changements sur la même ligne, ça marche toujours. Enfin ça devrait...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
awk '
{
    line = $0
    do
    {
        first = match(line, /`[[:upper:]_]*`/)
        if (first == 0)
        {
            printf "%s\n", line
            next
        }
        second = first + match(substr(line, first + 1), /`/)
        printf "%s%s", substr(line, 1, first), tolower(substr(line, first + 1, second - first))
        line = substr(line, second + 1)
    } while (line != "")
}'

Bon, explications:
first est l'index du ` qui ouvre un nom à changer, second est l'index du ` qui ferme ce nom. J'imprime tel quel le début de ligne, puis passe en minuscule le nom, et enfin retaille la ligne: il se peut qu'il y ait encore des changements dans cette ligne. Sinon, j'imprime le reste et passe à la ligne suivante.

Y a moins de lignes et ça marche mieux .

[gomodo]

Ma version JAWK ne semble pas accepter la même syntaxe des expressions rationnelle, j'ai donc juste modifié le regexp pour ma version:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
{
    line = $0
    do
    {
        first = match(line, /\`[A-Z,_]*\`/)
        if (first == 0)
        {
            printf "%s\n", line
            next
        }
        second = first + match(substr(line, first + 1), /`/)
        printf "%s%s", substr(line, 1, first), tolower(substr(line, first + 1, second - first))
        line = substr(line, second + 1)
    } while (line != "")
}

.. et ça marche nickel !

Merci et bravo !

(c'était pas si simple que ça)

[jmelyn]

Effectivement, l'interprétation des expressions régulières de jawk me semble bizarre:
* POSIX donne plein de classes de caractères comme [:alnum:], [:blank:] ou [:punct:].
* cette virgule devrait être interprétée comme le caractère , et pas comme un séparateur de champ.
* le caractère ` ne devrait pas avoir besoin d'être échappé. D'ailleurs, il ne l'est pas à la 11e ligne: second = ... /`/)

À partir du moment où l'on sait exactement ce qu'il faut faire, le codage devient simple (en général). J'espère que les explications sont suffisantes...