Discussion :

[kluh]

Bonjour,
je souhaite savoir s'il est possible, en vba, d'enregistrer un feuillet excel en format .doc?
Merci

[ouskel'n'or]

Non, tout au moins dans la version 2003, mais tu peux exporter un tableau dans Word (lié ou non) ou copier le tableau dans Word au format Word avec collage spécial RTF avec mise en forme. Manquera un trait dessous à ajouter
Bon après-midi

[kluh]

Merci, je connais l'export, mais pas le collag special RTF...
Y'a un tuto?

Par contre, rajouter un trait ca voudrait dire devoir modifier le word avec le vba?
C'est ce que je voulais éviter pour gagner en temps de traitement...

[ouskel'n'or]

Tu vas dans Word, tu copies quelque chose et tu vas dans le menu Editer -> Collage spécial. Tu as plein de choses

[kluh]

Ha...je pensais qu'on pouvait le faire en vba...

[ouskel'n'or]

On peut bien sûr le faire en VBA. Je répondais à ça

je connais l'export, mais pas le collage special RTF

Mais pour te donner un conseil il est nécessaire de préciser le type de collage que tu souhaites : Une plage de données liées au classeur, non liée, obtenir un tableau Word...
Tu m'as demandé :

je souhaite savoir s'il est possible, en vba, d'enregistrer un feuillet excel en format .doc

Je t'ai répondu :

Non, tout au moins dans la version 2003, mais tu peux exporter un tableau dans Word (lié ou non) ou copier le tableau dans Word au format Word avec collage spécial RTF avec mise en forme

On passe donc à la suite : Le doc existe-t-il ? Quel résultat attends-tu ? Tableau Word ? Plage de cellules liée au classeur ? Bref, dis-nous tout
A+

[kluh]

Bonjour,
le doc n'existe pas, en fait, j'aurais souhaité le créer directement depuis une macro vb excel en enregistrant un feuillet...
Mais bon, je peux le créer, puis l'ouvrir pour le modifier...

En fait, je vais avoir un feuillet excel, avec 2 images (logo), un tableau avec pas mal de données, et je veux juste enregistrer ça au format doc
(pas de lien avec le classeur...)
Je pensais que cela pouvait se faire facilement, mais j'ai bien l'impression qu'il va falloir que je créais mon .doc de toute pièce depuis la macro excel...

Merci

[Godzestla]

Bonjour,
En fait, je vais avoir un feuillet excel, avec 2 images (logo), un tableau avec pas mal de données, et je veux juste enregistrer ça au format doc
(pas de lien avec le classeur...)
Je pensais que cela pouvait se faire facilement, mais j'ai bien l'impression qu'il va falloir que je créais mon .doc de toute pièce depuis la macro excel...

Merci

Bonjour Kluh,
si tes 2 images (logo) sont toujours identiques, tu peux aussi créer un modèle en word avec un bookmark à l'endroit où tu souhaites insérer ton tableau et alors te contenter depuis excel (VBA) d'ouvrir le modèle, insérer le tableau à l'endroit prévu et sauver le modèle sous un nom .doc.

Tu trouveras des exemples sur ce forum et/ou dans la faq.

Bonne journée.

[ouskel'n'or]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub Test()
Dim AppWd As Object
Dim WdDoc As Object
Dim CL1 As Workbook
    'Instance du classeur dont les éléments seront copié
    Set CL1 = ThisWorkbook
    'Ouvre Word
    Set AppWd = CreateObject("Word.Application")
    'AppWd.Visible = True 'juste pour voir ce qu'il se passe dans Word (pourra être supprimé)
 
    'Ajoute un document tout neuf
    Set WdDoc = AppWd.Documents.Add
 
    'Ouvre le document s'il existe
    'Set WdDoc = AppWd.Documents.Open(FileName:="D:\Doc\Collage Special.doc")
 
    'Copie de la plage renseignée de la feuille de calculs
    CL1.Worksheets("feuil1").UsedRange.Copy
 
    'Collage en tant que tableau Word dans le document
    AppWd.Selection.PasteSpecial Link:=False, DataType:=wdPasteRTF, _
    Placement:=wdInLine
 
    'Enregistrement du document Word
    WdDoc.SaveAs FileName:="D:\Doc\Collage Special.doc"
    DoEvents
    'fermeture du document
    WdDoc.Close False
    'Fermeture de Word
    AppWd.Quit
    Set AppWd = Nothing
    Set WdDoc = Nothing
    Set CL1 = Nothing
End Sub

Teste ça en modifiant le nom du fichier et son chemin

Te restera à déterminer où tu veux coller tes affaires dans le document Word.
Bonne journée