Discussion :

[Cercle]

Bonjour,

J'ai cette macro qui me permet de supprimer des lignes si les cellules de la colonne x sont vides.

Seulement voila, au lieu d'aller modifier la lettre de la colonne dans la macro, j'aimerais au moyen d'un inputbox, par exemple, choisir la colonne de rérérence. J'aimerai aussi pouvoir dire toujours par inputbox à quelle ligne la macro doit s'arrêter.

Merci d'avance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub SupprimerLignesVides()
'
' SupprimerLignesVides Macro
'
' Supprime les lignes vides (à définir : 1ère ligne et colonne)
'
'
'
' désactiver le rafraîchissement de l'écran pour accélérer le traitement
    Application.ScreenUpdating = False
    ' désactiver les alertes pour empêcher l'affichage
    ' des messages du genre "Voulez-vous etc."
    Application.DisplayAlerts = False
 
    ' se placer sur la dernière ligne contenant des données ET CHOIX DE LA COLONNE
    Range("H65536").End(xlUp).Select
        Do
        If IsEmpty(ActiveCell) Then
            ActiveCell.EntireRow.Delete
        End If
        ActiveCell.Offset(-1, 0).Select
 
    ' suppression des lignes vides jusqu'à la ligne selon CRITERE CI-DESSOUS
    Loop Until ActiveCell.Row = 3
 
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
 
'
'
End Sub

[fring]

Bonsoir,

Quelque chose comme ça ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub SupprimerLignesVides()
Dim Cel As Range, Lig As Long, i As Long
 
'sélection d'une cellule dans la colonne concernée
Set Cel = Application.InputBox("Veuillez sélectionner une cellule" & Chr(10) _
                            & "dans la colonne concernée", Type:=8)
 
'insertion du n° de la dernière ligne
Lig = Application.InputBox("Veuillez indiquer le numéro" & Chr(10) _
                            & "de la dernière ligne à supprimer", Type:=1)
 
For i = Lig To 3 Step -1
    If Cells(i, Cel.Column) = "" Then Rows(i).Delete
Next
End Sub

[Cercle]

Bonsoir fring,

Merci de la réponse. En fait, j'aimerais simplement indiquer la lettre de la colonne dans le premier Inputbox. Pour la suite, c'est ok.

[fring]

Là ça devrait le faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub SupprimerLignesVides()
Dim Col, Lig, i As Long
 
'sélection d'une cellule dans la colonne concernée
Col = Application.InputBox("Veuillez indiquer la lettre" & Chr(10) _
                            & "de la colonne concernée")
 
'si clic sur annuler on stoppe la procédure
If Col = False Then Exit Sub
 
'insertion du n° de la dernière ligne
Lig = Application.InputBox("Veuillez indiquer le numéro" & Chr(10) _
                            & "de la dernière ligne à supprimer", Type:=1)
 
'si clic sur annuler on stoppe la procédure
If Lig = False Then Exit Sub
 
For i = Lig To 3 Step -1
    If Cells(i, Col) = "" Then Rows(i).Delete
Next
End Sub

[Cercle]

fring, merci encore pour les réponses rapides

C'est ok