Discussion :

[Décibel]

J'ai cherché de partout sans trouver de réponse...

J'utilise VBA pour générer dans Word des signets et cela marche à merveille !
Mais je voudrais maintenant faire de même avec Excel et je ne connais pas la démarche...
En claire : Comment d'une base Access envoyer des données précisément dans des cellules d'Excel via des signets ou autre chose ?

Petite précision, avec les signets dans word, un utilisateur positionne où il souhaite le signet dans la page, puis VBA lis la page et positionne les données là où le signet est.
L'utilisateur n'a donc pas à mettre en place du code VB quand il fait son document modele, c'est bien ce genre de fonction que je souhaite mettre en place, en gros c'est récupérer des données simple comme le nom, l'adresse, le CP et la ville d'un client dans l'entête d'un document Excel en laissant l'utilisateur choisir l'endroit dans la page Excel...

Merci !

[LedZeppII]

Bonsoir,

ce que je connais de plus proche dans Excel ce sont les noms que l'on peut donner à une cellule ou une plage de cellules.

Insertion->Nom->Définir
On crée une association entre un nom et une cellule (ou une plage de cellules)
Ces noms sont accessibles dans la collection Names de l'objet Workbook.

Exemple rapide de code créé dans Excel

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Dim wbk As Excel.Workbook
Dim nm As Excel.Name, strMsg As String
 
Set wbk = ActiveWorkbook
 
strMsg = strMsg & wbk.Names("Client").RefersToRange.Cells(1, 1) & vbCrLf
strMsg = strMsg & wbk.Names("Adresse").RefersToRange.Cells(1, 1) & vbCrLf
strMsg = strMsg & wbk.Names("CP").RefersToRange.Cells(1, 1) & " "
strMsg = strMsg & wbk.Names("Ville").RefersToRange.Cells(1, 1)
 
MsgBox strMsg

Dans l'exemple j'ai quatre cellules nommées Client, Adresse, CP, et Ville.
Je récupère le contenu à l'aide de la propriété RefersToRange qui renvoie un objet Range (plage de 1 ou plusieurs cellules).
Avec Cells(1,1) je prends la première Cellule de chaque plage (Range) nommée.

Pour de plus amples informations, tu fais comme moi : F1 dans l'éditeur VB d'Excel.

A+

[Décibel]

Merci pour ce code
Mais si j'ai bien compris c'est l'utilisateur qui en créant son modèle dans Excel est obligé de se taper le code vba sous Excel => Pas bon !

L'avantage des signets dans Word c'est bien que l'utilisateur met en place avec un menu tout bête ses signets dans son doc Word et la programmation de vba dans Access qui fait tout le reste...
Alors effectivement nommer une cellule peut-être une bonne piste, mais comment à partir d'Access faire pour injecter les données qu'on souhaite dans les cellules de la page Excel sans que l'utilisateur ait à saisir du code vba ???

[LedZeppII]

L'utilisateur à juste à faire
Insertion->Nom->Définir dans Excel sur la cellule de son choix
au lieu de
Insertion->signet dans Word

Mon exemple de code montre comment lire le contenu de cellules auxquelles on a donné un nom.
Pour y écrire (toujours avec mon exemple)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wbk.Names("Client").RefersToRange.Cells(1, 1) = "Toto"

Si Client fait référence à la cellule C3 de la deuxième feuille du classeur, cela va mettre "Toto" dans cette cellule.

A+

[Décibel]

Et le code si dessous il est dans la base access ou dans le fichier excel ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wbk.Names("Client").RefersToRange.Cells(1, 1) = "Toto"

[LedZeppII]

Bonjour,

Voici un exemple de code depuis Access.
Il faut ajouter une référence à "Microsoft Excel x.x Object Library" (x.x selon version d'office)

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Dim xlApp As Excel.Application
Dim wbk As Excel.Workbook, blnKillExcelOnExit As Boolean
Dim strXlFile As String
 
' Obtenir ou créer instance d'Excel.exe
On Error Resume Next
Set xlApp = GetObject(, "Excel.Application")
On Error GoTo 0
If xlApp Is Nothing Then
   Set xlApp = New Excel.Application
   blnKillExcelOnExit = True
End If
 
' Ouvrir le classeur
strXlFile = "C:\Mes Documents\LeClasseur.xls"
Set wbk = xlApp.Workbooks.Open(strXlFile)
' Ecrire dans classeur
wbk.Names("Client").RefersToRange(1, 1) = "Toto"
' Sauver et fermer le classeur
wbk.Save
wbk.Close
 
' Libérer les objets
Set wbk = Nothing
If blnKillExcelOnExit Then xlApp.Quit
Set xlApp = Nothing

A+