Discussion :

[yamat]

Bonjour à tous,

Normalement je trouve toujours mes réponses en cherchant sur internet mais là je me suis inscrits et sollicite votre aide car je suis bloqué depuis quelques jours.

Je dois réaliser un outil sous Excel pour mon entreprise: générer des documents Word à partir des informations saisies dans Excel. Ex: nom client, coordonnées, version du document, etc. Les employés saisissent seulement les informations dans les cellules, puis cliquent sur un bouton pour générer le document. La macro va chercher le document Word modèle et les informations sont reportées directement vers des signets:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

WordDoc.Bookmarks("date1").Range.Text = Sheets("Informaciones generales").Range("C12").Value

Je ne peux pas faire du publipostage puisque les documents sont différents selon les clients.

Jusque ici tout va bien, sauf que les documents évoluent. Ainsi ma macro va en permanence rechercher le dernier document Word créé. Sauf que lors de l'actualisation (ex: numéro de version changée), je me retrouve avec toutes les informations en double au niveau des signets. C'est à dire que le texte n'est pas modifié mais ajouté à droite du texte de l'ancienne version.

Après recherche il serait plus facile de passer par des champs:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

WordDoc.Fields("date1").Result.Text = "valeur a reporter"

Sauf que je ne sais pas comment définir ce fameux "Fields" dans Word. Je sais que c'est un champ, ctrl+F9, mais je ne sais pas quoi mettre dedans.

J'ai également trouvé cette formule qui me renvoie des erreurs:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim objRange As Range
Set objRange = ActiveDocument.Bookmarks.Item("date1").Range
objRange.Text = Sheets("Informaciones generales").Range("C12").Value
ActiveDocument.Bookmarks("date1").Range.Select
Selection.Text = Sheets("Informaciones generales").Range("C12").Value
objRange.Bookmarks.Add "date1"

J'espère que j'ai été clair et que vous pourrez m'aider.

Merci d'avance

[yamat]

Bonjour,

Je ne comprends rien car j'ai une macro qui ne fonctionne qu'une fois sur deux. Les codes me paraissent corrects.

Je change la valeur de la cellule "C12" par exemple, lance la macro test(), le document word s'ouvre, et j'ai une erreur '462' au niveau de la ligne en vert.

Je debug, ferme le document word, relance la macro Test(), et cela marche, le signet dans Word est bien modifié.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Public Sub RemplirSignet(S As String, T As String)
   
Dim Place As Long
Place = ActiveDocument.Bookmarks(S).Range.Start
ActiveDocument.Bookmarks(S).Range.Text = T
ActiveDocument.Bookmarks.Add Name:=S, _
Range:=ActiveDocument.Range(Place, Place + Len(T))

End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub test()
 
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Set WordApp = CreateObject("word.application")
Set WordDoc = WordApp.Documents.Open("C:\\\.docx") 'ouvre document Word
WordApp.Visible = True
RemplirSignet "date1", Sheets("Informaciones generales").Range("C12").Value
RemplirSignet "nombre_proyecto", Sheets("Informaciones generales").Range("C3").Value
End Sub

Donc si quelqu'un voit une erreur dans le code car je n'y comprends rien.
Car la macro fonctionne vraiment 1 fois sur 2, j'ai testé une 20 de fois à la suite....


Merci

[ouskel'n'or]

tu ne peux pas utiliser Activedocument dans une instance de Word, tu dois passer par l'instance du document.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public WordApp As Word.Application
Public WordDoc As Word.Document
 
Public Sub RemplirSignet(S As String, T As String)
Dim Place As Long
    Place = WordDoc.Bookmarks(S).Range.Start '*******
    WordDoc.Bookmarks(S).Range.Text = T
    WordDoc.Bookmarks.Add Name:=S, _
    Range:=WordDoc.Range(Place, Place + Len(T))
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub test()
    Set WordApp = CreateObject("word.application")
    Set WordDoc = WordApp.Documents.Open("C:\\\.docx") 'ouvre document Word
    WordApp.Visible = True
    RemplirSignet "date1", Sheets("Informaciones generales").Range("C12").Value
    RemplirSignet "nombre_proyecto", Sheets("Informaciones generales").Range("C3").Value
End Sub

Sans tester, je ne me souviens plus si tu dois utiliser l'instance du document ou de l'application.
Tu peux tester l'un ou l'autre, pour moi ?
A+

[yamat]

Avec ce code j'ai maintenant toujours la même erreur a la même ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public Sub RemplirSignet(S As String, T As String)
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
 
Dim Place As Long
    Place = WordDoc.Bookmarks(S).Range.Start 
    WordDoc.Bookmarks(S).Range.Text = T
    WordDoc.Bookmarks.Add Name:=S, _
    Range:=WordDoc.Range(Place, Place + Len(T))
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
 
Set WordApp = CreateObject("word.application")
Set WordDoc = WordApp.Documents.Open("C:\Documents and Settings\tquevarec\Mis documentos\ADS\Travaux à réaliser\Generation documentation\Plan de Proyecto Template3.docx") 'ouvre document Word
WordApp.Visible = True
RemplirSignet "date1", Sheets("Informaciones generales").Range("C12").Value
RemplirSignet "nombre_proyecto", Sheets("Informaciones generales").Range("C3").Value
End Sub

Et j'ai bien essayé avec les deux...

[ucfoutu]

Tel que tu l'as écrit (où tu l'as déclaré), Wordoc est inconnu dans ta sub remplissage !
Regarde ce qu'à écrit Ousk ...!

[yamat]

Il me semble que les variables S et T sont définies ici:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Public Sub RemplirSignet(S As String, T As String)

Sinon j'ai voulu définir Worddoc de cette façon mais j'ai une erreur a ce niveau-ci, ce que je ne comprends pas car la macro test() ouvre le document non ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Public Sub RemplirSignet(S As String, T As String)
Dim WordObj As Word.Application
Dim WordDoc As Word.Document
Set WordObj = CreateObject("word.application") 'ouvre session word
Set WordDoc = WordObj.ActiveDocument

Dim Place As Long
    Place = WordDoc.Bookmarks(S).Range.Start
    WordDoc.Bookmarks(S).Range.Text = T
    WordDoc.Bookmarks.Add Name:=S, _
    Range:=WordDoc.Range(Place, Place + Len(T))
 
End Sub

Excusez-moi si je pose des question idiotes mais j'ai une formation mécanique à l'origine et la je dois faire quelque chose qui dépasse mes compétences en VB, d'où ma venue ici pour demander de l'aide...

Mais ce qui m'etonne le plus c'est que la toute première macro fonctionnait..une fois sur deux certe mais fonctionnait.

[yamat]

c'est bon j'ai trouvé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Public Sub RemplirSignet(S As String, T As String, WordDoc As Word.Document)
 
Dim Place As Long
    Place = WordDoc.Bookmarks(S).Range.Start
    WordDoc.Bookmarks(S).Range.Text = T
    WordDoc.Bookmarks.Add Name:=S, _
    Range:=WordDoc.Range(Place, Place + Len(T))
 
End Sub
 
Sub test()
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
 
Set WordApp = CreateObject("word.application")
Set WordDoc = WordApp.Documents.Open("C:\.docx") 'ouvre document Word
WordApp.Visible = True
RemplirSignet "date1", Sheets("Informaciones generales").Range("C12").Value, WordDoc
RemplirSignet "nombre_proyecto", Sheets("Informaciones generales").Range("C3").Value, WordDoc
End Sub

Merci pour votre aide, je mets le sujet en resolu

[yamat]

Solution trouvée: je mets le code qui pourrait être utilse à d'autres.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Public Sub RemplirSignet(S As String, T As String, WordDoc As Word.Document)
 
Dim Place As Long
    Place = WordDoc.Bookmarks(S).Range.Start
    WordDoc.Bookmarks(S).Range.Text = T
    WordDoc.Bookmarks.Add Name:=S, _
    Range:=WordDoc.Range(Place, Place + Len(T))
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub test()
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
 
Set WordApp = CreateObject("word.application")
Set WordDoc = WordApp.Documents.Open("C:\.docx") 'ouvre document Word
WordApp.Visible = True
RemplirSignet "date1", Sheets("Informaciones generales").Range("C12").Value, WordDoc
RemplirSignet "nombre_proyecto", Sheets("Informaciones generales").Range("C3").Value, WordDoc
End Sub

[ouskel'n'or]

N'ouvre pas deux discussions pour une même question.
Je fusionne.
Pour faire ce que tu veux sans détruire le signet, regarde là, tu as deux solutions. C'est dans le forum VBA-Word, tu devras simplement utiliser tes instances à la place de Selection ou ActiveDocument.