Discussion :

[Lucci]

Bonjour à tous,

J'ai beaucoup de mal avec le VBA, je n'ai jamais rien sorti... Mais là j'aurais absolument besoin d'une macro, vous êtes mon dernier espoir.

Au boulot, je suis sous Excel 2000.
Un classeur composé de deux feuilles. L'une se nome 'valeurs génériques' et l'autre 'CREA type'.
Sur 'valeurs génériques' on a une liste. CREA type est une simple feuille de calcul....

But de la macro:
Pour chaque valeur de la liste, créer un onglet (une feuille) qui portera le nom de l'élément de la liste. Le contenu de chacune de ces feuilles est une copie de 'CREA type'.

Exemple:
Sur valeurs génériques, on a chirurgie en B1, médecine interne en B2, morgue en B3... (ce n'est qu'un exemple ). On lance la macro et ça génère 3 feuilles supplémentaires nommées chirurgie, médecine interne et morgue. Le contenu de chacune de ces feuilles étant le contenu de 'CREA type'

Merci par avance
Bien à vous.

[bidou]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim MaCell As Range, Modele As Worksheet
 
Set MaCell = ThisWorkbook.Worksheets("valeurs génériques").Range("B1")
Set Modele = ThisWorkbook.Worksheets("CREA type")
Do While Len(MaCell.Value) > 0
    Modele.Copy after:=ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count)
    ThisWorkbook.ActiveSheet.Name = MaCell.Value
    Set MaCell = MaCell.Offset(1)
Loop

[fring]

Bonjour,

la même que bidou avec vérification que la feuille n'existe pas, ce qui permettrait de réutiliser la procédure suite à l'ajout de noms

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub creation_feuilles()
Application.ScreenUpdating = False
Dim i As Integer, x As Integer, Verif As Boolean, Nom As String
 
'boucle sur les valeurs de la colonne A, ligne 2 à la dernière ligne
For i = 2 To Sheets("valeurs génériques").Cells(Rows.Count, 1).End(xlUp).Row
    Nom = Sheets("valeurs génériques").Cells(i, 1)
    Verif = False
 
    'vérification si la feuille existe déjà
    For x = 1 To Sheets.Count
        If Sheets(x).Name = Nom Then Verif = True
    Next
 
    'si la feuille n'existe pas, copier la feuille CREA et renommer la nouvelle feuille
    If Verif = False Then
        Sheets("CREA type").Copy After:=Sheets(Sheets.Count)
        ActiveSheet.Name = Nom
    End If
Next
 
Sheets("valeurs génériques").Activate
Application.ScreenUpdating = True
End Sub

[Lucci]

Merci infiniment, ça semble tellement simple pour vous, c'est déconcertant.

En tout cas, je reviendrais à ce râtelier

À+

PS: Un tuto complet sous la main à me proposer?

[bidou]

http://bidou.developpez.com/article/VBA/

[Lucci]

Désolé... Soit je suis passé à coté ou j'ai recherché des tutos avant le 24 Janvier 2008 (je pense que c'est ça).
Plus de 200 pages c'est du lourd, merci

Et zou un [Résolu] dans le titre.