Discussion :

[sebhm]

Bonjour,

sur ma feuille Excel, j'ai :
- un bouton "RAZ"
- un bouton "debut traitement"

Le bouton "debut traitement" va faire tout plein de trucs et notamment créer un 3eme bouton "action 2" (Ce bouton "action 2" sera relié à une macro "Sub suite_traitement").
ce qui donne dans mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
    ActiveSheet.Buttons.Add(75.75, 228, 72, 72).Select
    Selection.OnAction = "suite_traitement"
    Selection.Characters.Text = "action 2"
    With Selection.Characters(Start:=1, Length:=9).Font
        .Name = "Arial"
        .FontStyle = "Normal"
        .Size = 10
        .Strikethrough = False
        .Superscript = False
        .Subscript = False
        .OutlineFont = False
        .Shadow = False
        .Underline = xlUnderlineStyleNone
        .ColorIndex = xlAutomatic
    End With

mon bouton "RAZ" doit faire le ménage dans ma page et notamment supprimer mon bouton "action 2". Le seul truc que j'ai trouvé pour supprimer le bouton est de le "Couper" (peut etre y a-til mieux à faire..?), ce qui donne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    ActiveSheet.Shapes("Button 9").Select
    Selection.Cut

Mon probleme vient du fait que je ne peux pas supprimer mon bouton en faisant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    ActiveSheet.Shapes("action 2").Select
    Selection.Cut

car mon bouton s'appelle "Button 9" pour Excel (nom donné automatiquement lors de la création d'objet) et pas "action 2"....

Puis je modifier ce nom lors de la création du bouton ??
une autre solution sinon ??

merci
(en esperant que c'est clair)

[sebhm]

j'ai trouvé le code suivant sur le forum :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub bouton()
dim obj as OleObject
set obj=    ActiveSheet.OLEObjects.Add(ClassType:="Forms.CommandButton.1", Link:=False _
        , DisplayAsIcon:=False, Left:=546.75, Top:=14.25, Width:=72, Height:= _
        24)
obj.Select
obj.name="toto"
    Selection.ShapeRange.IncrementLeft -28.5
    Selection.ShapeRange.IncrementTop -9.75
End Sub

cela crée un bouton qu'on ne peut modifier/déplacer/supprimer depuis la feuille Excel (Pourquoi ??)

mais à la limite ca m'ira du moment que je peux le supprimer par macro... comment ??

[fring]

Bonjour,

Tu peux essayer comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub creation_bouton()
Dim Cbut As Object
 
Set Cbut = ActiveSheet.Buttons.Add(75.75, 228, 72, 72)
 
With Cbut
    .OnAction = "suite_traitement"
    .Characters.Text = "action 2"
    .Name = "MonBouton"
End With
 
Set Cbut = Nothing
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub suppression_bouton()
ActiveSheet.Shapes("MonBouton").Delete
End Sub

[sebhm]

c'est nickel.
Merci

[fring]

Un petit bonus, positionnement et dimensionnement du bouton par rapport aux cellules

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub creation_bouton()
Dim Cbut As Object
Dim L As Single, T As Single, W As Single, H As Single
 
'position et dimensions du bouton par rapport aux cellules B2 et B3
L = Range("B2").Left '<-- position horizontale
T = Range("B2").Top '<-- position verticale
W = Range("B2").Width '<-- largeur
H = Range("B2:B3").Height '<-- hauteur
 
Set Cbut = ActiveSheet.Buttons.Add(L, T, W, H)
 
With Cbut
    .OnAction = "suite_traitement"
    .Characters.Text = "action 2"
    .Name = "MonBouton"
End With
 
Set Cbut = Nothing
End Sub