Discussion :

[potili2]

bonjour;
j'ai plusieurs macros qui peuvent se déclencher dans mon classeur, nécessitant l'activation de l'une ou l'autre feuille, ceci à partir d'une feuille qqconque.
mon souci est de revenir à la feuille de départ après la macro, ce qui, à mon sens, nécessite d'enregistrer le nom de la feuille active avant la macro. comment peut on connaitre le nom de la feuille active?
merci
Jean Pierre

[fring]

Bonjour,

En principe une procédure ne nécessite pas l'activation d'une feuille mais il faudrait voir le code pour pouvoir éventuellement corriger ça.

Sinon pour répondre à ta question

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub MaMacro()
Dim Sh As Worksheet
 
Set Sh = ActiveSheet
 
'début procédure
'...
'fin de procédure
 
Sh.Activate
End Sub

[zazaraignée]

Salut

Faudrait pas oublier de libérer la mémoire...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
'fin de procédure
 
Sh.Activate
Set Sh = Nothing    ' <-- détruit l'objet Sh, donc libère la mémoire.
End Sub

[potili2]

merci à vous deux, ça marche...
j'active une feuille pour importer un fichier texte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Workbooks("Fondecran1").Worksheets("importation").Activate
 Workbooks("Fondecran1").Worksheets("importation").Range("AE75:AM115").Value = ""
    Workbooks.OpenText Filename:="C:\Documents and Settings\All Users\Documents\MS_direct_ordi2\bb_1_5_15_ordi2.txt", _
        Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
        xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _
        Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(1, 1)
       Workbooks("Fondecran1").Worksheets("importation").Cells(75, 31).Value = Workbooks("bb_1_5_15_ordi2").Sheets("bb_1_5_15_ordi2").Cells(1, 1).Value     'importe l'isin
       Workbooks("Fondecran1").Worksheets("importation").Cells(75, 32).Value = Workbooks("bb_1_5_15_ordi2").Sheets("bb_1_5_15_ordi2").Cells(2, 1).Value     'importe la date et l'heure de crétion
       For comm = 3 To 7
       Workbooks("Fondecran1").Worksheets("importation").Cells(76, 28 + comm).Value = Workbooks("bb_1_5_15_ordi2").Sheets("bb_1_5_15_ordi2").Cells(comm, 1).Value
       Workbooks("Fondecran1").Worksheets("importation").Cells(77, 28 + comm).Value = Workbooks("bb_1_5_15_ordi2").Sheets("bb_1_5_15_ordi2").Cells(comm + 5, 1).Value
       Workbooks("Fondecran1").Worksheets("importation").Cells(78, 28 + comm).Value = Workbooks("bb_1_5_15_ordi2").Sheets("bb_1_5_15_ordi2").Cells(comm + 10, 1).Value
       Next
    Windows("bb_1_5_15_ordi2.txt").Activate
    ActiveWindow.Close

je n'ai pas trouvé comment faire autrement

de même pour recopier des colonnes entières d'une feuille sur l'autre sans copier les cellules une après l'autre, je suis obligé d'activer la feuille, dans ce cas.
si c'est possible de s'en passer, merci de bien vouloir me le signaler.

Jean Pierre

[fring]

Ci-dessous le code un peu remanié, tu peux tester pour moi stp ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub test()
Dim SHimport As Worksheet, SHordi2 As Worksheet, Wbk As Workbook, comm As Byte
Application.ScreenUpdating = False
 
Set SHimport = ThisWorkbook.Sheets("importation")
 
Workbooks.OpenText Filename:="C:\Documents and Settings\All Users\Documents\MS_direct_ordi2\bb_1_5_15_ordi2.txt", _
    Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
    xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _
    Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(1, 1)
 
Set Wbk = ActiveWorkbook
Set SHordi2 = ActiveWorkbook.ActiveSheet
 
With SHimport
    .Range("AE75:AM115").ClearContents
    .Cells(75, 31) = SHordi2.Cells(1, 1) '<- importe l'isin
    .Cells(75, 32) = SHordi2.Cells(2, 1) '<- importe la date et l'heure de crétion
    For comm = 3 To 7
        .Cells(76, 28 + comm) = SHordi2.Cells(comm, 1)
        .Cells(77, 28 + comm) = SHordi2.Cells(comm + 5, 1)
        .Cells(78, 28 + comm) = SHordi2.Cells(comm + 10, 1)
    Next
End With
 
Wbk.Saved = True
Wbk.Close
Set Wbk = Nothing
Set SHimport = Nothing
Set SHordi2 = Nothing
Application.ScreenUpdating = True
End Sub