Discussion :

[PC81]

Bonjour,

Je souhaiterai faire un programme qui cherche le document Excel le plus récemment créé dans un répertoire. Par ailleur, il faudrait que le nom de ce fichier soit stocké dans une variable.

J'ai trouver ce code que j'ai modifier pour trouver la date de creation d'un fichier:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub test()
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile("C:\...\doc.xls")
    p = f.DateCreated
    MsgBox ("date creation : " & p)
End Sub

J'aimerai faire un truc du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Set fs = CreateObject("Scripting.FileSystemObject")
fichier_recent = 01/01/1995
For Each ..?..
    ..
    fichier_courant = f.DateCreated
    If fichier_courant > fichier_recent Then
        fichier_recent = fichier_courant
    End If
Next
...
Msgbox(fichier_recent)

Je ne sais pas comment concrétiser mes idées. Est-ce que quelqu'un pourrait m'aider svp ?
Merci d'avance

[ucfoutu]

Bonjour

en ennemi de FSO, je te proposerais d'utiliser directement ce que t'offre VB !

Exemple (ici des fichiers .txt dans le répertoire "d:\"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub Command1_Click()
  Dim monrep As String, monfic As String, derdate As Date, ledernier As String
  monrep = "d:\"
  monfic = Dir(monrep & "*.txt")
  derdate = DateSerial(1, 1, 1)
  Do While monfic <> ""
    If FileDateTime(monrep & monfic) > derdate Then
      ledernier = monrep & monfic
      derdate = FileDateTime(monrep & monfic)
    End If
    monfic = Dir
  Loop
  MsgBox "le plus récent des fichiers txt dans ce répertoire est " & ledernier
End Sub

[PC81]

Merci de ta réponse, je viens de testé et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox "le plus récent des fichiers txt dans ce répertoire est " & ledernier

ne renvoie rien, enfin je vois la phrase affiché mais la variable "ledernier" n'apparait pas.
J'ai donc essayé d'afficher la variable "monfic" avec un Msgbox mais ça n'affiche rien non plus..

Edit -> En fait, je n'arrive pas à rentré dans ma boucle "Do While", c'est pour ça.
Il faudrait remplacer ça par autre chose :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Do While monfic <> ""

[ucfoutu]

Cela veut dire :
soit que ton répertoire n'existe pas
soit que tu n'y a aucun fichier de l'extension choisie
soit que tu a mal adapté ton code

J'ai testé et retesté ! tout marche à la perfection !

Montre-nous ton code, donc (tel qu'il est) !

Autre chose : tes fichiers seraient-ils dotés d'attributs ? (si oui : lesquels ?)

[PC81]

Mon répertoire et mes fichiers existent bien.

Mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub CommandButton1_Click()
  Dim monrep As String, monfic As String, derdate As Date, ledernier As String
  monrep = "C:\Documents"
  monfic = Dir(monrep & "*.xls")
  derdate = DateSerial(1, 1, 1)
  Do While monfic <> ""
    If FileDateTime(monrep & monfic) > derdate Then
      ledernier = monrep & monfic
      derdate = FileDateTime(monrep & monfic)
    End If
    monfic = Dir
  Loop
  MsgBox "le plus récent des fichiers txt dans ce répertoire est " & ledernier
 
End Sub

Autre chose : tes fichiers seraient-ils dotés d'attributs ? (si oui : lesquels ?)

Je ne comprends pas ce que tu veux dire par la

[ucfoutu]

Regarde ce que tu as écrit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

monrep = "C:\Documents"

!!!!!ù

Il ne te semble pas qu'il manque un "petit détail" ? (un slash final, par exemple) ? (relis mon code !)

[PC81]

Oupsss
Effectivement, de suite ça marche beaucoup mieux.. mdr

Ca marche impec !!! Merci beaucoup !
Juste ça se base sur la date de dernier modification, c'est ça ?

[ucfoutu]

Oui : la date de création ou celle de dernière modification
C'est cette date qui est en général utile.

Si tu tiens à la seule date de création, on peut faire aussi, avec la fonction GetFileInformationByHandle de l'API de Windows ... Mais : en es-tu vraiment certain ?

[PC81]

Non non t'inquiètes ça me va très bien. Merci de ton aide