Bonjour

La question de l'info-bulle a été posée sur le forum, il y avait la solution du lien hypertexte.

Voici une autre solution, en faisant appel aux formes de PowerPoint.

Collez ce code dans un module standard.
Code vb : Sélectionner tout - Visualiser dans une fenêtre à part
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Public Sub AffichageBulleForm(shpSelect As Shape)
    ' ===== déclaration des variables =====
    Dim shpBulle As Shape   ' il s'agit de l'info-bulle qui sera crée
    Dim sldParent As Slide  ' il s'agit d'une slide (diapositive ou se trouve la forme
    Dim t As Date           ' va servir pour la temporisation de l'affichage de l'info-bulle
 
    ' ===== affectation =====
    ' on récupére le slide
    Set sldParent = shpSelect.Parent
 
    ' ===== on crée la bulle =====
 
    Set shpBulle = sldParent.Shapes.AddShape(msoShapeRectangle, shpSelect.Left + shpSelect.Width, shpSelect.Top, 100, 100)
    With shpBulle
        .Name = "Bulle"
        ' couleur de fond
        .Fill.ForeColor.RGB = RGB(150, 150, 120)
        ' texte de la bulle
        .TextFrame.TextRange.Text = "toto"
        .TextFrame.WordWrap = msoTrue
        ' la forme s'adapte au texte
        .TextFrame.AutoSize = ppAutoSizeShapeToFitText
        ' couleur de la ligne
        .Line.ForeColor.RGB = RGB(200, 200, 100)
        ' position
        .Top = shpSelect.Top + 10
        .Left = shpSelect.Left + 10
    End With
 
    ' ===== on lance la temporisation ====
    t = Timer + 1
    Do Until Timer > t
        DoEvents
    Loop
 
    ' ===== on détruit la bulle =====
    sldParent.Shapes("Bulle").Delete
End Sub

Ensuite sur l'action du survol de votre élément par la souris, sélectionnez la routine AffichageBulleForm. L'info-bulle que vous pouvez paramétrer en forme et couleur, apparaitra 1 seconde.

Remarque : Toutes les formes n'ont pas le même effet, ici, il s'agit d'un rectangle tout simple.

Vous pouvez aussi utiliser un UserForm pour réaliser un message, mais cela demande l'aide d'API pour supprimer la barre et lui donner un aspect plus intéressant.

Starec