Discussion :

[clao260]

Bonjour,

Et un nouveau probleme se pose à moi !!!

Je voudrais savoir s'il est possible de tester la presence d'une table.
Un truc qui ressemblerai à ca :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
 
if ( table1 ) existe Then
DROP TABLE TABLE1
Else
Exit sub
End if

Quelqu'un a une idée ?
Merci

[Jean-Philippe André]

bonjour,

deux fonctions :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
'*****************************
'fonction de test d'existence d'une table par les propriétés VBA
'input = nom de la table
'output = booleen
'*****************************
Function DoesTableExist(ByVal NomTable As String) As Boolean
    Dim str As String
    On Error GoTo NoTable
    str = CurrentDb.TableDefs(NomTable).Name
    DoesTableExist = True
    Exit Function
NoTable:
    Select Case err.Number
        Case 3265
            DoesTableExist = False
    End Select
End Function
 
'*****************************
'fonction de test d'existence d'une table par les requêtes SQL
'input = nom de la table
'output = booleen
'*****************************
Function DoesTableExist2(ByVal NomTable As String) As Boolean
    Dim rs As DAO.Recordset
    On Error GoTo NoTable
    Set rs = CurrentDb.OpenRecordset("SELECT * FROM [" & NomTable & "]")
    DoesTableExist2 = True
ExitDoesTable:
    Set rs = Nothing
    Exit Function
NoTable:
 
    Select Case err.Number
        Case 3078
            DoesTableExist2 = False
    End Select
    Resume ExitDoesTable
End Function

[clao260]

Merci c'est nickel ...

@+