Discussion :

[Thomas69]

Bonjour,

J'ai une macro qui me genere un graphique voir ci dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub Graph1()
Dim graph_name As String
 
graph_name = Selection.Value
 
 
 
    Charts.Add
    ActiveChart.ChartType = xlLineMarkers
    ActiveChart.SetSourceData Source:=Sheets("Production").Range("H60000")
    ActiveChart.SeriesCollection.NewSeries
    ActiveChart.SeriesCollection(1).XValues = "=Production!R2C3:R26000C3"
    ActiveChart.SeriesCollection(1).Values = "=Production!R2C10:R26000C10"
    ActiveChart.Location Where:=xlLocationAsNewSheet
    With ActiveChart
        .HasTitle = True
        .ChartTitle.Characters.Text = graph_name
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "Lots"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Valeurs"
    End With
    ActiveChart.HasLegend = False
 
End Sub

ce que je voudrais faire c'est de trasher (supprimer) ce graphique quand je sort de l'onglet de celui ci
je m'explique

je crée un graphique et quand je part sur un autre onglet d'une autre feuille,le graphique s'efface automatiquement sans me poser de question ou autre

Si vous avez une idée je suis tout ouie
je vous en remercie d'avance

[Bigalo]

Bonjour,

Dans ta procédure, remplace

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    Charts.Add
    ActiveChart.ChartType = xlLineMarkers

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    Charts.Add
    ActiveWorkbook.Names.Add "GraphTemp", ActiveChart.Name
    ActiveChart.ChartType = xlLineMarkers

Ajoute ensuite dans le module "ThisWorkbook" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
        If Sh.Name = Evaluate("GraphTemp") Then
            Application.DisplayAlerts = False
            Sh.Delete
            Application.DisplayAlerts = True
        End If
End Sub

En clair, lors de la création du graphique, on stocke son nom dans un nom ajouté au classeur, "GraphTemp".

Par ailleurs, à chaque fois qu’une feuille est désactivée, la procédure "SheetDeactivate" est lancée. Si le nom de la feuille concernée correspond à "GraphTemp", la feuille est supprimée.

Cordialement,



Michel Gaboly