Discussion :

[Narf!]

Bonjour,

Voici mon problème. Je créé en VBA des graphiques.
Vu le nombre que j'ai à faire, je fait une fonction par graphique.
La où je bloque, c'est que j'aimerais nommer ces graphiques afin d'avoir plus de souplesse car graph1, graph2, ça ne peut aller qu'un temps. Et il faut se poser la question suivant l'ordre de création des graphiques (ordre d'appel des fonctions) qui deviens fixe.

Pour le graphique en lui même, je pense y être arrivé avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveChart.Name = "Repartition"

Par contre, je cherche à placer ces graphiques. J'ai trouver à le faire avec le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
    Set Grph = Sheets("Stats").ChartObjects(1)
    Set Emplacement = Range("A3:J20")
 
    With Grph
        .Left = Emplacement.Left
        .Top = Emplacement.Top
        .Height = Emplacement.Height
        .Width = Emplacement.Width
    End With

Là ou je bloque, c'est que j'aimerais changer ChartObjects(1) en quelque chose de plus parlant. Mais l'objet Chart que je nome Repartition semble différent de l'objet ChartObjects que je manipule pour placer le graph.
Je m'y prends peut être mal.
Je met quand même ici le code complet de la partie de création du graph :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
    Range("AA1:AD10").Select
    Charts.Add
    ActiveChart.Name = "Repartition"
    ActiveChart.ChartType = xl3DColumnClustered
    ActiveChart.SetSourceData Source:=Sheets("Stats").Range("AA1:AD10"), PlotBy _
        :=xlColumns
    ActiveChart.Location Where:=xlLocationAsObject, Name:="Stats"
 
    With ActiveChart
        .HasTitle = True
        .ChartTitle.Characters.Text = _
        "Répartition des incidents"
        .Axes(xlCategory).HasTitle = False
        .Axes(xlSeries).HasTitle = False
        .Axes(xlValue).HasTitle = False
        .HasDataTable = True
        .DataTable.ShowLegendKey = True
        .WallsAndGridlines2D = False
        .HasLegend = False
        .ChartType = xl3DColumnClustered
        .Axes(xlCategory).HasMajorGridlines = False
        .Axes(xlCategory).HasMinorGridlines = False
        .Axes(xlSeries).HasMajorGridlines = False
        .Axes(xlSeries).HasMinorGridlines = False
        .Axes(xlValue).HasMajorGridlines = True
        .Axes(xlValue).HasMinorGridlines = False
        .RightAngleAxes = True
        .HeightPercent = 100
        .AutoScaling = True
        .Elevation = 29
        .Perspective = 30
        .Rotation = 44
    End With
 
    Set Grph = Sheets("Stats").ChartObjects(1)
    Set Emplacement = Range("A3:J20")
 
    With Grph
        .Left = Emplacement.Left
        .Top = Emplacement.Top
        .Height = Emplacement.Height
        .Width = Emplacement.Width
    End With

Par avance, merci

[Singular]

Ce bout de code te donnera une piste sur laquelle travailler.

J'assume ici que tes données se trouvent sur la feuille "Stats" et que tu veux y insérer un graphique.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub MakeChart2()
    Dim ch As ChartObject
 
    Set ch = Worksheets("Stats").ChartObjects.Add(100, 30, 400, 250)
    ch.Name = "Repartition"
    ch.Chart.ChartWizard Source:=Worksheets("Stats").Range("AA1:AD10"), _
            gallery:=xl3DColumn, PlotBy:=xlColumns, Title:="Repartition"
    ch.Chart.ChartType = xl3DColumnClustered
End Sub

Par la suite, tu peux faire référence au graphique par le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Stats").ChartObjects("Repartition")

[Narf!]

Ha oui, beaucoup mieux.
Et je le place dès le début.
Bon avec placement en pixel mais ça me vas aussi, j'suis pas sectaire.
Merci beaucoup!