Discussion :

[Ginko]

Bonjour à tous,

Je me suis mis très recement au VBA avec Excel, ça fait un petit moment que je bloque sur quelquechose.

J'ai donc un combobox en userform, je lui défini une plage à récupérer (qui se trouve en feuille 2, ce sont plusieurs cases d'une même ligne), et je suis parti sur ce type de code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub UserForm_Initialize()
   Combobox.RowSource = "feuille2!A1:Z1"
    End Sub

seulement, il ne m'affiche que la 1ère cellule, c'est à dire, A1, dans la liste. Est-ce que je fait fausse route en partant sur ce code ou bien j'ai certainement dû oublier quelquechose en route

une petite aide serait la bienvenue
merci d'avance

[ouskel'n'or]

Tu as 26 colonnes dans ton Combo ?

Edit
Bon, je veux bien t'aider mais ce sera demain. Avec RowSource, ça marche pas, tu dois utilier Column et pour ça créer un tableau des données de ta ligne et mettre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Me.ListBox2.Column() = Tableau()

Bonne nuit.

[Ginko]

Bonjour,

j"ai réduit à 23 colonnes, un mot par colonne sur une même ligne

merci

[ouskel'n'or]

Tu n'as comme limite que le nombre de colonnes de ta feuille de calculs. Pas de soucis là-dessus.

A lire pour comprendre
Pour présenter en colonne dans ton combo, des données présentées en ligne dans ta feuille, tu dois créer un tableau à deux dimensions pour que le combo ou listBox retrouve ses petits.
Une dimension lignes
Une dimension colonnes.

Dans l'exemple que je te mets, tu ne lis qu'une ligne et tu n'auras donc qu'une colonne dans ton combo. Mais nous ne sommes pas limités.
Par la même méthode tu peux avoir autant de colonnes dans ton combo que de lignes dans ta feuilles de calculs.

Le code promis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub UserForm_Initialize()
Dim DerLig As Long, DerCol As Integer, NoCol As Integer
Dim Tableau(), NoLig As Long
 
    DerLig = 1  'Dernière ligne de la plage
    DerCol = 26  'Dernière colonne
    ReDim Tableau(DerLig, DerCol)
 
    'On fixe le nbre de colonnes de la liste au nombre de ligne
    Me.ComboBox1.ColumnCount = DerLig
 
    'Création du tableau : Pour chaque ligne, toutes les colonnes
    For NoLig = 1 To DerLig
        For NoCol = 1 To DerCol  '(NoLig-1 et NoCol-1) l'index commençant à 0
            Tableau(NoLig - 1, NoCol - 1) = Cells(NoLig, NoCol).Value
        Next
    Next
    Me.ComboBox1.Column() = Tableau()
End Sub

Dans cette macro j'ai donc limité le nombre de lignes... à 1. Mais tu peux très bien mettre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    DerLig = FL1.Range("A65535").End(xlUp).Row 'Dernière ligne de la plage
    DerCol = FL1.Range("IV1").End(xlToLeft).Column   'Dernière colonne

Et tu pourras ainsi avoir autant de colonnes dans ton combo que tu as de lignes dans ta plage de données de la feuille Excel.
En espérant t'avoir aidé
A+

NB - Par cet méthode je ne connais pas de solution pour avoir une ligne d'en-têtes

[Singular]

Autre solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub UserForm_Initialize()
    Dim i As Long
    Dim rng As Range
 
    Set rng = Worksheets("Feuil1").Range("A1:Z1")
    For i = 1 To rng.Columns.Count
        ComboBox1.AddItem rng.Cells(1).Offset(0, i - 1).Value
    Next i
    ComboBox1.ListIndex = 0 ' Pour que la première ligne soit sélectionnée au départ
End Sub

[ouskel'n'or]

Bonjour Singular,
Pendant que je te tiens, as-tu une solution pour afficher un en-tête de colonne selon la méthode que tu utilises ou la mienne ? (ComboBox1.Column() ou ComboBox1.AddItem ?
Merci pour ton travail.

Juste une remarque à l'intention de Ginko :
Additem ajoute une ligne à la list ou comboBox mais ne permet pas de renseigner plusieurs colonnes (ce qui n'est d'ailleurs pas demandé par Ginko ) Seule la première colonne est renseignée par cette méthode.
Par contre, pour une seule colonne, Additem suffit mais est plus lent.
(Tu me corriges si je me trompe, Singular )