Discussion :

[Aymeric22]

Voila mon problème, après avoir demandé de l'aide hier sur ce forum j'ai réussi à faire quelque chose qui me convient à peu près mais il me reste un problème que je n'arrive pas à résoudre voila mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub BoutonMesure_Click()
Dim i As Integer
 
    If i = 10 Then i = 0              ' On vérifie que l'on a pas dépassé les 10 textbox, sinon on passe au premier
    Text(i).Text = MSCommCAN.Input    ' On écrit dans le Text(i) le résultat de la mesure
    Text(i).BackColor = vbWhite       'pour remettre le backcolor en blanc
    i = i + 1
 
End Sub
 
Private Sub BoutonCommande_Click()
Dim i As Integer
 
    MSCommCAN.Output = Text(i).Text
    Text(i).BackColor = vbGreen    'pour mettre en vert le backcolor losque la donnée est envoyée
    i = i + 1
 
 End Sub

En fait quand ce que je veut c'est que j'appui sur le bouton mesure, j'ai la mesure qui s'affiche dans le text box 1 puis je fais commande je l'envoie le textbox1 devient vert puis je fais une nouvelle fois mesure, une seconde mesure s'affiche dans le text box 2 puis je l'envoi etc et cela pour 10 textbox.
Mais la avec ce programme, le textbox1 s'éfface à chaque fois et ne passe pas au textbox2.

Merci d'avance pour vos réponses

[sovo]

Tout d'abord comme te l'as demande La Praline, prierre d'utiliser les balise de code.

Mais la avec ce programme, le textbox1 s'éfface à chaque fois et ne passe pas au textbox2.

Pour ton probleme. Je crois que le probleme viens du fait que tu n'as pas utilise le groupe de controle (et pourtant j'avais commence par ca). Je presume donc que tu ne sais pas le mettre en place.

C'est tout simple.

renome tous les textbox en Text et a chaque fois increment le numeros d'index. C'est a dire :
Pour le premier tu aura : Name = Text; Index = 0
pour le deuxieme : Name = Text; Index = 1
.....
pour le dernier (le 10 eme) : Name Text; Index = 9


Avec ca je crois que ton code devrais marche.

[Ntotor]

Hello, si je ne m'abuse i devrait etre declaré en variable globale et pas dans les subs.

[zazaraignée]

Hello, si je ne m'abuse i devrait etre declaré en variable globale et pas dans les subs.

Pas forcément

En déclarant i statique, sa valeur sera conservée entre chaque click. Mais il faudra réititialiser i lorsqu'il aura atteint 10

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Static i As Integer
...
i = i + 1
i = IIf(i = 10, 0, i)

Si tu ne connais pas la fonction IIf, F1 t'expliquera tout.

[Edit] Cependant, Ntotor a raison pour un point, si tu utilises un deuxième bouton avec un i déclaré dans sa procédure Click, i vaudra toujours 0 (zéro) parce que pas initialisé. Ce sera donc toujours le contenu de ton premier textbox qui sera envoyé. Il faut revoir la logique de ton interface et de son utilisation.

[Aymeric22]

Je viens de résoudre le problème et il fallait bien que je la déclare en global. Cela fonctionne normalement.
Mais, zazaraignée ta méthode fonctionne aussi très bien!!

En tout cas merci à tous pour votre aide

A bientot

[zazaraignée]

Bon alors, n'oublie pas de cliquer sur .

À tout hasard, j'ai fait ce test pour la postérité... J'ai bien sur remplacé l'entrée de données de ton périphérique par un inputBox. J'ai mis un groupe de labels (lblMesureEnvoyee) avec une bordure et un fond vert, invisibles au départ. Un textbox verrouillé (Locked = False) pour empêcher la saisie directe. Un autre groupe de labels (Label1, j'avais oublié de le nommer...) servent à identifier la mesure (Mesure 1, Mesure 2... Facultatif).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Option Explicit
Private i As Integer
 
Private Sub Form_Load()
    ' Initialiser i, ça fait un code plus propre.
    i = 0
    ' et
    txtMesure.Locked = True 'empêche la saisie directe
End Sub
 
Private Sub cmdMesurer_Click()
    txtMesure.Text = InputBox("Entrez une donnée", "Mesure", "valeur " & i + 1)
    cmdEnvoyer.SetFocus
End Sub
 
Private Sub cmdEnvoyer_Click()
    lblMesureEnvoyee(i).Caption = txtMesure.Text
    'le code spécifique à l'envoi de donnée
    '...
 
    'le code pour l'affichage
    lblMesureEnvoyee(i).Visible = True
 
    ' incrémentation
    i = i + 1
 
    ' si les mesures sont finies,
    If i = 10 Then
        ' désactiver les boutons de mesure et d'envoi, et le textbox
        cmdMesurer.Enabled = False
        cmdEnvoyer.Enabled = False
        txtMesure.Visible = False
        ' si nécessaire
        'i = 0
      Else  ' sinon
        ' vider le textbox
        txtMesure.Text = ""
        ' déplacer le textbox et continuer
        txtMesure.Top = lblMesureEnvoyee(i).Top
        ' préparer et afficher le label du champ suivant
        Label1(i).Caption = "Mesure " & i + 1 & " :"
        Label1(i).Visible = True
        ' donner le focus au bouton de mesure
        cmdMesurer.SetFocus
    End If
 
End Sub
 
Private Sub cmdFermer_Click()
    End
    ' ou
    'Unload me
    ' ou
    'Me.Hide  ' il faut alors remettre i à zéro et vider les lblMesureEnvoyee
    ' c'est selon...
End Sub

Tout marche en appuyant sur Entrée sans cliquer nullepart.

[Aymeric22]

Ok merci je prends note sa pourra probablement me servir.

Merci beaucoup