Discussion :

[lito74]

Bonjour,
Dans un formulaire, j'ai un sous-formulaire et une zone de liste.
Sur l'évènement 'After update' d'un contrôle texte de mon sous-formulaire je met à jour la zone de liste.
Je souhaite ensuite me repositionner sur le dernier enregistrement de mon sous-formulaire, mais celui-ci reste tout en haut de mon sous-formulaire

Comment faire ?
Merci

[totofe]

j'ai une solution. je c'est pas si c'est la meilleur mais bon elle fonctionne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Me.Recordset.AbsolutePosition=Me.Recordset.RecordCount

[pgz]

Bonjour.

Faudrait voir ce qu'il y a en FAQ...
Sinon voici un bout de code qui permet dans un formulaire ou un sous formulaire de sélectionner un enregistrement et de l'afficher sur une ligne particulière du formulaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Public Function fctAfficherEnr(frm As Form, ByVal lEnr As Long, ByVal lPos As Long) As Boolean
'sélectionne l'enregistrement de [frm] dont AbsolutePosition = [lEnr] et place, si possible
'cet enregistrement sur la ligne [lPos] de [frm]
Dim rst As DAO.Recordset
Dim lPrem As Long 'numéro de l'enregistrement à placer en ligne1
 
Set rst = frm.RecordsetClone
 
'vérifier la valeur lEnr
rst.MoveLast
If rst.AbsolutePosition < lEnr Then GoTo SortieEnErreur
 
On Error GoTo SortieEnErreur
 
If frm.DefaultView <> 1 Then
'si le frm n'est pas en mode continu
    rst.AbsolutePosition = lEnr
    frm.Bookmark = rst.Bookmark
 
Else
'si le frm est en mode continu
    'numéro de l'enegistrement en première ligne
    lPrem = lEnr - lPos + 1
    If lPrem < 0 Then lPrem = 0
 
    'afficher Enr(lPrem) en haut
    rst.MoveLast
    frm.Bookmark = rst.Bookmark
    rst.AbsolutePosition = lPrem
    frm.Bookmark = rst.Bookmark
 
    'sélectionner lEnr
    rst.AbsolutePosition = lEnr
    frm.Bookmark = rst.Bookmark
End If
 
fctAfficherEnr = True
 
Sortie:
    Set rst = Nothing
    Exit Function
 
SortieEnErreur:
    fctAfficherEnr = False
    GoTo Sortie
 
End Function

Par exemple l'enregitrement 231 sur la 4ème ligne du formulaire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

call fctAfficherEnr(Me,230,4)

Bien sûr on ne peut pas afficher l'enregistrement 2 sur la ligne 5...
En espérant que cela t'inspire,

PGZ