Discussion :

[maroon1970]

saluuuuut !! SVP je cherche un code sous le vb.net ki permet de convertir un chiffre en lettre et merciiiiiiiii d'avance

[sam_XIII]

il suffit d'utiliser la méthode ToString

par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Dim chiffre As Integer
chiffre = 10
 
Dim lettre As String
lettre = chiffre.ToString()

[sharrascript]

bonsoir,

En effet, mais je crois que tu peux aussi faire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim lettre As String
lettre = "10"

Voilà ++

[Poulain]

Je pense que ce qu'il demande, c'est transformer

"10" en "dix"

[hellspawn_ludo]

J'ai compris comme toi Poulain.

[maroon1970]

beh oé je ve un code ki converti des nombre en lettre
exemple on tape 1000 on doit avoir comme résultat "mille" -en lettre- et po en chiffre

[Poulain]

Fait une recherche sur le forum, cette question a déjà été posée.

il me semble que dans la reponse il disait d'utiliser un xml avec je sais plus trop quoi.

En bref, il faut que tu tapes ton code...

[A2rem]

comme c'est un truc que j'ai déjà fait pour une appli, je te donne mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
 
 'fonction transcrivant un nombre en toute lettres.
  Public Function traduire(ByVal N As Integer) As String
    Dim prov As String = ""
    Dim u, d, c, m, ml As Integer
 
    Dim liste As New Hashtable
    liste.Add(0, "zéro")
    liste.Add(1, "un")
    liste.Add(2, "deux")
    liste.Add(3, "trois")
    liste.Add(4, "quatre")
    liste.Add(5, "cinq")
    liste.Add(6, "six")
    liste.Add(7, "sept")
    liste.Add(8, "huit")
    liste.Add(9, "neuf")
    liste.Add(10, "dix")
    liste.Add(11, "onze")
    liste.Add(12, "douze")
    liste.Add(13, "treize")
    liste.Add(14, "quatorze")
    liste.Add(15, "quinze")
    liste.Add(16, "seize")
    liste.Add(17, "dix-sept")
    liste.Add(18, "dix-huit")
    liste.Add(19, "dix-neuf")
    liste.Add(20, "vingt")
    liste.Add(30, "trente")
    liste.Add(40, "quarante")
    liste.Add(50, "cinquante")
    liste.Add(60, "soixante")
    liste.Add(80, "quatre-vingt")
    liste.Add(100, "cent")
    liste.Add(1000, "mille")
    liste.Add(1000000, "million")
 
    If N < 21 Then
      prov = liste.Item(N)
    ElseIf N < 100 Then
      u = N Mod 10
      d = N - u
      Select Case (d \ 10)
        Case 7
          prov = liste.Item(60)
          If u = 1 Then prov &= " et " Else prov &= " "
          prov &= liste.Item(u + 10)
        Case 9
          prov = liste.Item(80)
          If u = 1 Then prov &= " et " Else prov &= " "
          prov &= liste.Item(u + 10)
        Case Else
          prov = liste.Item(d)
          If u > 0 Then
            If u = 1 Then prov &= " et " Else prov &= " "
            prov &= liste.Item(u)
          End If
      End Select
    ElseIf N < 1000 Then
      c = N \ 100
      If c > 1 Then prov = liste.Item(c) & " "
      prov &= "cent "
      If (N - 100 * c > 0) Then prov &= traduire(N - c * 100)
    ElseIf N < 1000000 Then
      m = N \ 1000
      If m > 1 Then prov = traduire(m) & " "
      prov &= "mille "
      If (N - 1000 * m > 0) Then prov &= traduire(N - m * 1000)
    ElseIf N < 1000000000 Then
      ml = N \ 1000000
      If True Then prov = traduire(ml) & " "
      prov &= "million "
      If (N - ml * 1000000) Then prov &= traduire(N - ml * 1000000)
    End If
    Return prov
  End Function

[Poulain]

T'as qu'à déposer ça en source, y en a plein qui seront content de l'avoir.

[TheBlue]

Bonsoir.
Vous avez pensé au truc où on doit ajouter un "s" ou on doit pas, chose que je ne maitrise pas même dans la langue

[SaumonAgile]

Les nombres cent et vingt s'accordent quand ils sont multipliés mais non suivis.
ex :
- deux cents
- deux cent quatre-vingts
- deux cent quatre-vingt quatre

Mille est invariable.

Un s'accorde en genre, mais pas en nombre.
ex : vingt et une pages

Millier, million et milliard s'accordent, ce sont des noms.

Cependant, quand on écrit des années, des jours, des chapitres, des pages, etc, ils restent invariables :
- l'année mille neuf cent (pas de s)
- la page quatre vingt (pas de s non plus)

[Aspic]

Merci pour le cours d'orthographe
En plus bcp de personnes ne connaissent pas les règles (dont moi )
++

[thierry007]

Une idée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
 
Option Explicit
Option Base 1
 
Public Unité As Variant
Public Dizaine As Variant
Public Décimales As Currency
Public CasPart As Variant
Public Lettres As String
Public Cent_Pluriel As Boolean
Public Vingt_Pluriel As Boolean
 
'
Function MontantEnLettre(Nombre As Currency) As String
 
' Limitation à 999 999 999 999 . 99
    If Nombre >= 1000000000000# Then
        MsgBox "Ce nombre est trop grand !", 0, "Message"
        Exit Function
    End If
 
' Initialisation des tableaux
    Unité = Array("UN", "DEUX", "TROIS", "QUATRE", "CINQ", "SIX", "SEPT", "HUIT", "NEUF")
    Dizaine = Array("DIX", "VINGT", "TRENTE", "QUARANTE", "CINQUANTE", "SOIXANTE", "SOIXANTE", "QUATRE-VINGT", "QUATRE-VINGT")
    CasPart = Array("DIX", "ONZE", "DOUZE", "TREIZE", "QUATORZE", "QUINZE", "SEIZE")
 
' Mise à vide de la chaîne de réception de la traduction du nombre
    Lettres = ""
 
' Initialisation des indicateurs de pluriel des nombres cent et vingt
    Cent_Pluriel = True
    Vingt_Pluriel = True
 
' Conversion de la partie décimale en un nombre de 0 à 99
' arrondi à l'unité la plus proche
    Décimales = CInt((Nombre - Fix(Nombre)) * 100)
 
' Conservation de la partie entière du nombre
    Nombre = Fix(Nombre)
 
' Orientation du traitement suivant valeur de la partie entière
    Select Case Nombre
        Case 0
            Lettres = "ZERO"
        Case 1 To 9
            Lettres = Unité(CInt(Nombre))
        Case 10 To 99
            Trt_Dizaines Nombre
        Case 100 To 999
            Trt_Centaines Nombre
        Case 1000 To 999999999999#
            Trt_Multiples_de_Mille Nombre
    End Select
 
' Indication de la monnaie
    If Nombre > 1 Then
        Lettres = Lettres & " EUROS "
    Else
        Lettres = Lettres & " EURO "
    End If
 
' Orientation du traitement suivant valeur de la partie décimale
    Select Case Décimales
        Case 1 To 9
            Lettres = Lettres & Unité(CInt(Décimales))
        Case 10 To 99
            Trt_Dizaines Décimales
    End Select
 
' Indication des centimes
    Select Case Décimales
        Case 1
            Lettres = Lettres & " CENT"
        Case Is > 1
            Lettres = Lettres & " CENTS"
    End Select
 
' Renvoi du nombre traduit en lettres
 
    MontantEnLettre = Lettres
 
End Function
 
'
' --------------------------------
' TRAITEMENT DES MULTIPLES DE 1000
' --------------------------------
'
Sub Trt_Multiples_de_Mille(Nombre As Currency)
 
Dim Rank As Currency
Dim Nom_Rang As String
Dim Reste As Currency
 
    Cent_Pluriel = False
    Vingt_Pluriel = False
 
' Initialisation suivant taille du nombre : milliers, millions ou milliards
    Select Case Nombre
        Case 1000 To 999999
            Rank = Fix(Nombre / 1000)
            Reste = Nombre Mod 1000
            Nom_Rang = "MILLE"
        Case 1000000 To 999999999
            Rank = Fix(Nombre / 1000000)
            Reste = Nombre Mod 1000000
            If Rank > 1 Then
                Nom_Rang = "MILLIONS"
            Else
                Nom_Rang = "MILLION"
            End If
        Case Is > 999999999
            Rank = Fix(Nombre / 1000000000)
            Reste = Nombre - Rank * 1000000000
            If Rank > 1 Then
                Nom_Rang = "MILLIARDS"
            Else
                Nom_Rang = "MILLIARD"
            End If
    End Select
 
' Traitement du rang des milliers, millions ou milliards
    Select Case Rank
        Case 1
            If Nom_Rang = "MILLE" Then
                Lettres = Lettres & Nom_Rang
            Else
                Lettres = Lettres & Unité(CInt(Rank)) & " " & Nom_Rang
            End If
        Case 2 To 9
            Lettres = Lettres & Unité(CInt(Rank)) & " " & Nom_Rang
        Case 10 To 99
            Trt_Dizaines (Rank)
            Lettres = Lettres & " " & Nom_Rang
        Case 100 To 999
            Trt_Centaines Rank
            Lettres = Lettres & " " & Nom_Rang
    End Select
 
    Cent_Pluriel = True
    Vingt_Pluriel = True
 
' Orientation du traitement du reste si > 0
    Select Case Reste
        Case 1 To 9
            Lettres = Lettres & " " & Unité(CInt(Reste))
        Case 10 To 99
            Lettres = Lettres & " "
            Trt_Dizaines Reste
        Case 100 To 999
            Lettres = Lettres & " "
            Trt_Centaines Reste
        Case Is > 999
            Lettres = Lettres & " "
            Trt_Multiples_de_Mille Reste
    End Select
 
    Lettres = Lettres
 
End Sub
 
'
' -----------------------------------
' TRAITEMENT DES NOMBRES DE 100 0 999
' -----------------------------------
'
Sub Trt_Centaines(Nombre As Currency)
 
Dim Rank As Currency
Dim Reste As Currency
 
    Rank = Fix(Nombre / 100)
    Reste = Nombre Mod 100
 
' Traitement du rang des centaines
    If Rank = 1 Then
        Lettres = Lettres & "CENT"
    Else
        If Reste = 0 And Cent_Pluriel Then
            Lettres = Lettres & Unité(CInt(Rank)) & " " & "CENTS"
        Else
            Lettres = Lettres & Unité(CInt(Rank)) & " " & "CENT"
        End If
    End If
 
' Traitement du reste < 100
    Select Case Reste
        Case 1 To 9
            Lettres = Lettres & " " & Unité(CInt(Reste))
        Case Is > 9
            Lettres = Lettres & " "
            Vingt_Pluriel = True
            Trt_Dizaines (Reste)
    End Select
 
End Sub
 
'
' ---------------------------------
' TRAITEMENT DES NOMBRES DE 10 0 99
' ---------------------------------
'
Sub Trt_Dizaines(Nombre As Currency)
 
Dim Reste As Integer
Dim Rank As Integer
 
    Rank = Fix(Nombre / 10)
    Reste = Nombre Mod 10
 
    Select Case Rank
        Case 1
            If Reste < 7 Then
                ' Nombres 10 à 16
                Lettres = Lettres & CasPart(Reste + 1)
            Else
                ' Nombres 17 à 19
                Lettres = Lettres & Dizaine(Rank) & "-" & Unité(CInt(Reste))
            End If
        Case 7
            Select Case Reste
                Case 0
                    ' Nombre 70
                    Lettres = Lettres & Dizaine(Rank) & "-" & Dizaine(Reste + 1)
                Case 1
                    ' Nombre 71
                    Lettres = Lettres & Dizaine(Rank) & " ET " & CasPart(Reste + 1)
                Case Else
                    If Reste < 7 Then
                    ' Nombres 72 à 76
                        Lettres = Lettres & Dizaine(Rank) & "-" & CasPart(Reste + 1)
                    Else
                    ' Nombres 77 à 79
                        Lettres = Lettres & Dizaine(Rank) & "-" & CasPart(1) & "-" & Unité(CInt(Reste))
                    End If
            End Select
        Case 8
            Lettres = Lettres & Dizaine(Rank)
            If Reste = 0 Then
                ' Nombre 80
                If Vingt_Pluriel Then
                    Lettres = Lettres & "S"
                End If
            Else
                ' Nombres 81 à 89
                Lettres = Lettres & "-" & Unité(CInt(Reste))
            End If
        Case 9
            If Reste < 7 Then
                ' Nombres 90 à 96
                Lettres = Lettres & Dizaine(Rank) & "-" & CasPart(Reste + 1)
            Else
                ' Nombres 97 à 99
                Lettres = Lettres & Dizaine(Rank) & "-" & CasPart(1) & "-" & Unité(CInt(Reste))
            End If
        Case Else
            ' Nombres 20 à 69
            Select Case Reste
                Case 0
                    ' Nombres 20, 30, 40, 50, 60
                    Lettres = Lettres & Dizaine(Rank)
                Case 1
                    ' Nombres 21, 31, 41, 51, 61
                    Lettres = Lettres & Dizaine(Rank) & " ET " & Unité(CInt(Reste))
                Case Else
                    ' Autres nombres
                    Lettres = Lettres & Dizaine(Rank) & "-" & Unité(CInt(Reste))
            End Select
    End Select
 
End Sub