Discussion :

[Julien42]

Bonjour,

voici une ligne de code que j'utilise pour faire une différence de date :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SELECT DateDiff("d",[Texte53],[Texte57]) AS Expr1;

Ceci marche tres bien, aucun probleme!!! Cependant je souhaite integrer une nouvelle grande ligne de code me permettant de calculer la difference de date en jours ouvrables uniquement. Voici ligne de code que j'ai trouvé, mais malheureusement je ne sais pas ou l'implanter dans mon sql.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
Function Work_Days(BegDate As Variant, EndDate As Variant, _
                   Optional bAvecJFerie As Boolean = True) As Variant
    Dim dt As Date
 
On Error GoTo Work_Days_Error
    If IsNull(BegDate) Or IsNull(EndDate) Then Err.Raise vbObjectError + 1
    If Not IsDate(BegDate) Or Not IsDate(EndDate) Then Err.Raise vbObjectError + 2
    If BegDate > EndDate Then Err.Raise vbObjectError + 3
 
    dt = BegDate
    Work_Days = 0
    While dt <= EndDate
        If DatePart("w", dt, vbMonday) < 6 And IIf(bAvecJFerie, Not EstFerie(dt), True) Then
            Work_Days = Work_Days + 1
        End If
        dt = DateAdd("d", 1, dt)
    Wend
    Exit Function
 
Work_Days_Error:
    Select Case Err.Number
        Case vbObjectError + 1: Work_Days = "Les 2 dates sont obligatoires."
        Case vbObjectError + 2: Work_Days = "Format de date incorrect."
        Case vbObjectError + 3: Work_Days = "La date de fin doit être postérieure à la date de début."
        Case Else: Work_Days = Err.Description
    End Select
End Function
 
 
Function EstFerie(ByVal QuelleDate As Date) As Boolean
Dim anneeDate As Integer
Dim joursFeries(1 To 11) As Date
Dim i As Integer
  anneeDate = Year(QuelleDate)
 
  joursFeries(1) = DateSerial(anneeDate, 1, 1)
  joursFeries(2) = DateSerial(anneeDate, 5, 1)
  joursFeries(3) = DateSerial(anneeDate, 5, 8)
  joursFeries(4) = DateSerial(anneeDate, 7, 14)
  joursFeries(5) = DateSerial(anneeDate, 8, 15)
  joursFeries(6) = DateSerial(anneeDate, 11, 1)
  joursFeries(7) = DateSerial(anneeDate, 11, 11)
  joursFeries(8) = DateSerial(anneeDate, 12, 25)
 
  joursFeries(9) = fLundiPaques(anneeDate)
  joursFeries(10) = joursFeries(9) + 38 ' Ascension = lundi de Paques + 38
  joursFeries(11) = joursFeries(9) + 49 ' Lundi Pentecôte = lundi de Paques + 49
 
  For i = 1 To 11
    If QuelleDate = joursFeries(i) Then
      EstFerie = True
      Exit For
    End If
  Next
End Function
 
Private Function fLundiPaques(ByVal Iyear As Integer) As Date
        'Adapté de +ieurs scripts...
        Dim L(6) As Long, Lj As Long, Lm As Long
 
        L(1) = Iyear Mod 19: L(2) = Iyear Mod 4: L(3) = Iyear Mod 7
        L(4) = (19 * L(1) + 24) Mod 30
        L(5) = ((2 * L(2)) + (4 * L(3)) + (6 * L(4)) + 5) Mod 7
        L(6) = 22 + L(4) + L(5)
 
        If L(6) > 31 Then
                Lj = L(6) - 31
                Lm = 4
        Else
                Lj = L(6)
                Lm = 3
        End If
 
        ' Lundi de Pâques = Paques + 1 jour
        fLundiPaques = DateAdd("d", 1, (Lj & "/" & Lm & "/" & Iyear))
 
End Function

Si quelqu'un puvait me l'implanter dans mon 1er lsql afin que je puisse simplement faire un copier/coller, cela serait merveilleux

d'avance merci

[Oleff]

Bonjour,
Tout simplement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SELECT Work_Days(BegDate, EndDate, bAvecJFerie) FROM ...

[Julien42]

merci pour ta reponse mais malheureusement je debute sur le sql ainsi que le vba et donc je ne sais vraiment pas comment le mettre en place meme avec le " SELECT "

est il possible que tu me l'integre dans mon code de départ stp afin que je fasse un copier/coller.........cela serait formidable afin que je puisse comprendre comment cela fonctionne et pour ma requete....merci d'avance

[Oleff]

N'hésites pas à consulter l'aide access
Dans acces, les requêtes permettent d'utiliser des fonctions.

Donc ton code sélectionne la valeur de la fonction Work_Days selon les paramètres passés (date de début et date de fin). Ces paramètres proviennent soit d'une table, soit d'un formulaire.
Ecrire ton code n'est pas possible, ne connaissant pas le contexte de développement.