Discussion :

[detetop]

Comment peut-on détecter les lecteurs de mon PC par code en VB 6?

[OhMonBato]

Pour être honnête, j'ai un peu hésité à répondre, je crains que tu n'ais pas fait une recherche très approfondie avant de poser ta question.

Ajoute un controle Command et un controle DriveListBox à ta feuille puis mets ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Option Explicit
 
Private Sub Command1_Click()
Dim i As Byte
 
For i = 1 To Drive1.ListCount
  Debug.Print Drive1.List(i - 1)
Next i
End Sub

[avigeilpro]

Un peu plus complexe mais sans un seul control :
Tu met ceci dans un module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
Attribute VB_Name = "DriveRead"
'lancer le sub DList
'strDrives est un tableau qui contient tout les nom des drives et leur types
 
 
 
 
Option Explicit
'Constante
Private Const DRIVE_UNKNOWN = 0
Private Const DRIVE_ABSENT = 1
Private Const DRIVE_REMOVABLE = 2
Private Const DRIVE_FIXED = 3
Private Const DRIVE_REMOTE = 4
Private Const DRIVE_CDROM = 5
Private Const DRIVE_RAMDISK = 6
 
 
'API
Private Declare Function GetLogicalDriveStrings Lib "kernel32" Alias _
    "GetLogicalDriveStringsA" (ByVal nBufferLength As Long, _
    ByVal lpBuffer As String) As Long
Private Declare Function GetDriveType Lib "kernel32" Alias "GetDriveTypeA" _
    (ByVal nDrive As String) As Long
 
 
'Function
Private Function fGetDrives() As String
    Dim lngRet As Long
    Dim buffer As String * 255
 
    lngRet = GetLogicalDriveStrings(255, buffer)
    fGetDrives = Left(buffer, lngRet)
End Function
 
Public Function fDriveType(strDriveName As String) As String
    Dim lngRet As Long
    Dim strDrive As String
    lngRet = GetDriveType(strDriveName)
    Select Case lngRet
        Case DRIVE_FIXED
            strDrive = "Disque fixe"
        Case DRIVE_REMOTE
            strDrive = "Lecteur réseau"
            Case DRIVE_UNKNOWN
            strDrive = "Inconnu"
        Case DRIVE_ABSENT
            strDrive = "Absent"
        Case DRIVE_REMOVABLE
            strDrive = "Amovible"
        Case DRIVE_CDROM
            strDrive = "CD Rom"
        Case DRIVE_RAMDISK
            strDrive = "Disque ram"
    End Select
    fDriveType = strDrive
End Function
 
 
Public Function ListAllDrives(ByRef strDrives)
 
    Dim strAllDrives As String
    Dim strTmp As String
    Dim NbOccurence As Byte
   'Dim strDrives(0 To 254, 0 To 254) As String 'Tableau qui contient les drives
 
    strAllDrives = fGetDrives
    If strAllDrives <> "" Then
        Do
            strTmp = Mid$(strAllDrives, 1, InStr(strAllDrives, vbNullChar) - 1) 'lecture du lecteur (ex: A:\vbNullChar) jusqu'à vbnullchar
            strAllDrives = Mid$(strAllDrives, InStr(strAllDrives, vbNullChar) + 1) 'supprime le lecteur lu de la liste
 
            strDrives(NbOccurence, 0) = strTmp
            strDrives(NbOccurence, 1) = fDriveType(strTmp)
 
 
            NbOccurence = NbOccurence + 1
        Loop While strAllDrives <> ""
    End If
 
 
End Function
 
Public Sub DList()
Dim strDrives(0 To 254, 0 To 254) As String 'Tableau qui contient les drives
Call ListAllDrives(strDrives)
MsgBox strDrives(4, 1)
End Sub