Discussion :

[Currahee]

Bonjour,

Je dois automatiser la création de graphiques sous excel.

J'aimerai savoir s'il existe un moyen de gérer l'emplacement d'un graphique en fonction des cellules de la feuille ou il est placé.

Je m'explique :

J'aimerai pouvoir dire que mon graphique doit être placé et remplir toute la zone de B1 (coin haut gache) à F10 (coin bas droite du graphique) sur ma feuille.

Et de ce fait si je modifie les dimensions de mes colonnes, il me suffit de relancer ma macro pour regénérer le graphe afin qu'il suive les modifications de mise en page.

Quelqu'un a déjà fait ça ?????

Merci d'avance,

[helios77]

Pour le positionnement de tes graphiques, il y a ceci... en fait, il les déplace apr rapport à leur point d'oorigine.....Pour cela, faut que tu voies ou il le place et que tu le palces manuellement comme tu veux pour savoir les inccrment (via l'éditeur de amcro)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
    ActiveSheet.Shapes("Graphique 1").IncrementLeft -193.5
    ActiveSheet.Shapes("Graphique 1").IncrementTop -158.25

Pour le dimensionnement, y a ceci mais apperremment c'est du pourcentage de la taille initiale.....
Je pense que tu devrais pouvoir recalculer ce pourcentage en regardant la largeur d'une colonne apr défaut (10.71) et d'une ligne(12.75) et en regardant les nouvelles dimensions de tes celllules..

Ainsi, si tes cellules sont diminué de 15% alors tu diminue ton graphique de 15%

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
ActiveSheet.Shapes("Graphique 1").ScaleWidth 0.87, msoFalse, _
        msoScaleFromTopLeft
    ActiveSheet.Shapes("Graphique 1").ScaleHeight 0.88, msoFalse, _
        msoScaleFromTopLeft

malheureusement, je n'ai aps le temps de te donner un exemple complet mais je procèderait ainsi si j'avais besoin de faire çà

[Currahee]

Merci,

J'avais déjà repéré ces méthodes avec un l'enregistreur de macros, mais c'est justement pas un placement et une méthode de déplacement en relatif que je cherche, c'est bien un placement en fonction des cellules.

En fait j'ai vu que si je redimensionnais mes colonnes ou lignes les graphes suivaient avec l'option Format de la zone graphique -> Proprietes -> Deplacer et dimensionner avec les cellules. Donc ça c'est OK

Maintenant ce qu'il me faut c'est le placement initial sur la feuille en fonction des cellules (ou au pire en pixels, cm ou autre...)

PS: Le truc c'est que j'ai une trentaine de graphiques à placer sur des feuilles, que ce nombre de graphique évoluera dans le temps, tout comme la mise en page, etc... Vive les clients qui savent pas ce qu'ils veulent...

[bidou]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim MonGraph As ChartObject
Dim Gauche As Single, Haut As Single, Largeur As Single, Hauteur As Single
Gauche = Range("B1").Left
Haut = Range("B1").Top
Largeur = Range("F10").Left + Range("F10").Width - Gauche
Hauteur = Range("F10").Top + Range("F10").Height - Haut
Set MonGraph = ActiveSheet.ChartObjects.Add(Gauche, Haut, Largeur, Hauteur)

[Currahee]

Merci !

S'il existe pas de méthode pour se référer directement aux cellules , cette stratégie de contournement du problème m'a l'air parfaite

[Currahee]

Voilà le code que j'ai finalement écrit. C'est encore optimisable mais ça ça fait exactement ce que je voulais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub Creation_Graphe()
 
    ' ...Creation graphe ...
 
    ' Nommage du graph actif
    ActiveSheet.ChartObjects(ActiveChart.Parent.Name).Name = "Graphe_Test"
 
    ' Placement et dimensionnement
    Placer_Graphique "Graphe_Test", Range("K3"), Range("S17")
 
End Sub
 
Function Placer_Graphique(graphe As String, origine As Range, fin As Range)
 
    Dim x_origine As Single
    Dim y_origine As Single
 
    Dim largeur_graphe As Single
    Dim hauteur_graphe As Single
 
    x_origine = origine.Left
    y_origine = origine.Top
 
    largeur_graphe = fin.Left + fin.Width - x_origine
    hauteur_graphe = fin.Top + fin.Height - y_origine
 
    With ActiveSheet.Shapes(graphe)
      .Left = x_origine
      .Top = y_origine
      .Width = largeur_graphe
      .Height = hauteur_graphe
    End With
 
End Function

Si vous avez des remarques sur ce code, n'hésitez pas. Pour le nommage du graphe actif, j'ai récupéré cette ligne de code sur le net, mais j'avoue que je la comprends pas à 100%...

Merci à ceux qui m'ont aidé , et à la prochaine