Sauvegarde contenus combobox

**TheBlackReverand** · 18/10/2006, 17h44

Bonjour,

j'ai dans mon programme 2 listbox a enregistrè a chaque fin de programme.

j'ai donc "lstDefinition" et "lstMot"

j'ai mis en place le code d'ecriture dans "Form/Terminate" et le code de lecture dans 1 Bouton

je lance le programme, j'y insert des valeurs, je ferme, je vais voir mes 2 fichiers(lstDefinition.lst et lstMot.lst) deja je suis surpris car il sont vide(0Ko). je relance, chargement et la avec moins de surprise rien....

le problème viens donc de l'écriture. je comprend le code et je vois pas d'ou pourrais provenir l'erreur...

merci a vous

PS: la diference est que j'utilise Write au lieu de Print et je n'ai pas utilise EOF(je sais pas a quoi il sert)

**Phifi** · 18/10/2006, 17h56

Bonjour,

EOF = End Of File.

Voyons un peu de ce code !

**TheBlackReverand** · 18/10/2006, 18h21

code d'ecriture qui s'execute a la fermeture de l'unique feuille du programme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Private Sub Form_Terminate()
'Lecture du nombre d'objet dans les listes
NbreDef = lstDef.ListCount
 
'Sauvegarde des variables
Open App.Path & "\" & "save.txt" For Append As #1
Write #1, NFaute; NBien;
Close #1
 
'Sauvegarde de la liste de definition
Open App.Path & "\" & "Definition.lst" For Append As #2
Close #2
Open App.Path & "\" & "Definition.lst" For Output As #2
For i = 0 To lstDef.ListCount - 1
    lstDef.ListIndex = i
    Write #2, lstDef.Text
Next
Close #2
 
'Sauvegarde de la liste de mot
Open App.Path & "\" & "Mot.lst" For Append As #3
Close #3
Open App.Path & "\" & "Mot.lst" For Output As #3
For i = 0 To lstMot.ListCount - 1
    lstMot.ListIndex = i
    Print #3, lstMot.Text
Next
Close #3
 
End Sub

code de lecture contenu pas 1 bouton de commande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub cmdChargement_Click()
'Chargement des variables
Open App.Path & "\" & "save.txt" For Input As #1
Input #1, NFaute, NBien
Close #1
 
'Chargement de la liste de definition
Open App.Path & "\" & "Definition.lst" For Input As #2
For i = 0 To NbreDef - 1
    Input #2, Tempo$
    lstDef.AddItem (Tempo$)
Next
Close #2
 
'Chargement de la liste de mot
Open App.Path & "\" & "Mot.lst" For Input As #3
For i = 0 To NbreDef - 1
    Input #3, Tempo$
    lstMot.AddItem (Tempo$)
Next
Close #3
 
'Redistribution du focus
If optTest.Value = True And optParam.Value = False Then
    txtRep.SetFocus
ElseIf optParam.Value = True And optTest.Value = False Then
    txtMot.SetFocus
End If
 
End Sub

**AlainTech** · 18/10/2006, 21h11

Juste pour ne pas mourir idiot...

Ca sert à quoi ton

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Open App.Path & "\" & "Definition.lst" For Append As #2
Close #2

juste avant le Open For Output?

**TheBlackReverand** · 18/10/2006, 22h19

A la 1er exection les fichiers de sauvegarde n'existe pas
OutPut ne fait que de l'écriture et Append crèè si le fichier n'existe pas

1er execution:
ouverture lecture seul et creation
fermeture
ouverture en ecriture seul

N-iéme execution:
ouverture lecture seul
fermeture
ouverture en ecriture seul

**AlainTech** · 18/10/2006, 23h14

Un Open For Output crée le fichier s'il n'existe pas...

Edit: Et pas seulement s'il n'existe pas.
Merci delbeke de m'avoir corrigé.

**Delbeke** · 18/10/2006, 23h17

Nan, c'est pas comme çà que ca marche
L'ouverture en OutPut écrase le fichier s'il existe déjà et en crée un nouveau
L'ouverture en Append ouvre un fichier existant ou en cree un nouveau s'il n'existe pas. Les ecritures dans le fichier se feront apres la fin du fichier existant.
Donc, dans

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
'Sauvegarde de la liste de definition
Open App.Path & "\" & "Definition.lst" For Append As #2
Close #2
Open App.Path & "\" & "Definition.lst" For Output As #2
For i = 0 To lstDef.ListCount - 1
    lstDef.ListIndex = i
    Write #2, lstDef.Text
Next
Close #2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Open App.Path & "\" & "Definition.lst" For Append As #2
Close #2

ne sert strictement à rien.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Open App.Path & "\" & "Definition.lst" For Output As #2

Ecrase le fichier App.Path & "\" & "Definition.lst" et en recréée un nouveau completement vide.

**Delbeke** · 18/10/2006, 23h19

Par contre j'emets des doute sur la boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
For i = 0 To lstDef.ListCount - 1
    lstDef.ListIndex = i
    Write #2, lstDef.Text
Next

J'aurais plutot vu

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For i = 0 To lstDef.ListCount - 1
    Write #2, lstDef.List(i)
Next

**TheBlackReverand** · 19/10/2006, 18h31

oui moi ausi mais dans l'exemple dont je me suis inspiret(voir 1er message) il avais utiliser sa donc comment cela ne fonctionnè pas j'ai mis exactement toute sa methode

ok donc maintenant j'ai pour la sauvegarde a la fermeture de l'application:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub Form_Terminate()
'Sauvegarde des variables
Open App.Path & "\" & "save.txt" For Append As #1
Write #1, NFaute; NBien;
Close #1
 
'Sauvegarde de la liste de definition
Open App.Path & "\" & "Definition.lst" For Output As #2
For i = 0 To lstDef.ListCount - 1
    Write #2, lstDef.List(i)
Next
Close #2
 
'Sauvegarde de la liste de mot
Open App.Path & "\" & "Mot.lst" For Output As #3
For i = 0 To lstMot.ListCount - 1
    Print #3, lstMot.List(i)
Next
Close #3
 
End Sub

et pour la lecture:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub cmdChargement_Click()
'Chargement des variables
Open App.Path & "\" & "save.txt" For Input As #1
Input #1, NFaute, NBien
Close #1
 
'Chargement de la liste de definition
Open App.Path & "\" & "Definition.lst" For Input As #2
For i = 0 To NbreDef - 1
    Input #2, Tempo$
    lstDef.AddItem (Tempo$)
Next
Close #2
 
'Chargement de la liste de mot
Open App.Path & "\" & "Mot.lst" For Input As #3
For i = 0 To NbreDef - 1
    Input #3, Tempo$
    lstMot.AddItem (Tempo$)
Next
Close #3
 
'Redistribution du focus
If optTest.Value = True And optParam.Value = False Then
    txtRep.SetFocus
ElseIf optParam.Value = True And optTest.Value = False Then
    txtMot.SetFocus
End If
 
End Sub

petit test et la j'ai 1 fichier texte avec NBien NFaute
2 fichier lst qui eux font 0 Ko....

help me svp

**avigeilpro** · 20/10/2006, 11h04

Façon simple de sauver une liste dans un fichier :
Transférer la liste dans un tableau.
Utiliser la fonction qui fait l'inverse de Split (je ne me souviens plus de son nom mais il suffit de chercher dans l'aide) afin de mettre chacune des valeurs dans une variable chaine avec un séparateur ( ";" par exemple).
Supprimer le fichier de sauvegarde si celui-ci existe avec Kill.
Enfin sauver la variable chaine de la façon suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim Adresse As String
Dim Contenu As String
Adresse = "C:\MaListe.lst"
 
Contenu = "ValA;ValB" 'à remplacer par la transformation de la liste en chaine
 
Open Adresse For Binary As #1
Put #1,,Contenu
Close #1

Lecture du fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Dim Adresse As String
Dim Contenu As String
Dim MonTab() As String
 
Adresse = "C:\MaListe.lst"
Contenu = Space(Filelen(Adresse))
 
Open Adresse For Binary As #1
Get #1,,Contenu
Close #1
 
MonTab = Split(Contenu,";")

Il ne reste plus qu'a remettre le tableau MonTab dans la liste

**ThierryAIM** · 20/10/2006, 12h56

Envoyé par avigeilpro

Utiliser la fonction qui fait l'inverse de Split

Join

**avigeilpro** · 20/10/2006, 16h00

Exacte ThierryAIM j'avais un petit trou de mémoire

Bref ce code est assez simple (du moins je pense) et très efficace, on peu l'ameliorer et sauvegarder les deux listes dans le même fichier aussi, il suffit de mettre les deux donnée avec un séparateur différent ( "|" par exemple) entre chaque ";" et de refaire un split pour les séparer.

**Delbeke** · 20/10/2006, 19h10

Je viens de me rendre compte que tu mettais ton code dans le Form_Terminate, a tout hasard, essaye de la placer dans le Form_Unload

**TheBlackReverand** · 21/10/2006, 01h28

en effet après verification il fallait placer le code dans "Unload" et non pas "Terminate"

après quelque essay mes valeurs sont bien enregistrè avec separateur mais lorsque j'effectue la lecture du fichier le String recepteur et vide.

Declarations en general:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim NbreDef As Integer   'Nombre de definition
Dim TabDef() As String   'Tableau de sauvegarde des Definitions
Dim TabMot() As String   'Tableau de sauvegarde des Mots
Dim TabDefCharge() As String   'Tableau de sauvegarde des Definitions
Dim TabMotCharge() As String   'Tableau de sauvegarde des Mots
Dim strMot As String     'String contenant tous les mots
Dim strDef As String     'String contenant toutes les definitions

Code de sauvegarde:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Private Sub Form_Unload(Cancel As Integer)
'Dimensionement des tableaux
ReDim TabDef(lstDef.ListCount - 1) As String
ReDim TabMot(lstMot.ListCount - 1) As String
 
'Constitution des Tableaux et des Strings de sauvegarde
For i = 0 To lstDef.ListCount - 1
    TabDef(i) = lstDef.List(i)
Next
 
strDef = Join(TabDef, "£")
 
For i = 0 To lstMot.ListCount - 1
    TabMot(i) = lstMot.List(i)
Next
 
strMot = Join(TabMot, "£")
 
'Sauvegarde du nombre d'elements pour creation des tableaux de chargement
NbreDef = lstDef.ListCount - 1
 
'Sauvegarde des variables
Open App.Path & "\" & "save.txt" For Output As #1
Write #1, NFaute; NBien; NbreDef;
Close #1
 
'Sauvegarde des Strings
Open App.Path & "\" & "Def.lst" For Binary As #2
Put #2, 1, strDef
Close #2
 
Open App.Path & "\" & "Mot.lst" For Binary As #3
Put #3, 1, strMot
Close #3
 
End Sub

Code de chargement:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
'Chargement des variables
Open App.Path & "\" & "save.txt" For Input As #1
Input #1, NFaute, NBien, NbreDef
Close #1
 
'Chargement des Strings
Open App.Path & "\" & "Def.lst" For Binary As #2
Get #2, 1, strDef
Close #2
 
Open App.Path & "\" & "Mot.lst" For Binary As #3
Get #3, 1, strMot
Close #3
 
'Extraction des mots et definitions
TabMotCharge = Split(strMot, "£")
TabDefCharge = Split(strDef, "£")
 
ReDim Preserve TabMotCharge(NbreDef) As String
ReDim Preserve TabDefCharge(NbreDef) As String
 
'Extraction des elements des tableaux
For i = 0 To NbreDef
    lstDef.AddItem (TabDefCharge(i))
    lstMot.AddItem (TabMotCharge(i))
Next
 
'Redistribution du focus
If optTest.Value = True And optParam.Value = False Then
    txtRep.SetFocus
ElseIf optParam.Value = True And optTest.Value = False Then
    txtMot.SetFocus
End If

donc strMot="" et strDef="" après le chargement donc il m'ajoute des Item vide dans mes listes.....

merci pour votre aide

**Delbeke** · 21/10/2006, 08h02

N'oublie pas le tag

**ThierryAIM** · 21/10/2006, 09h41

il te manque un buffer pour la lecture en mode Binary

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
'Chargement des Strings
strDef = Space(LOF(2)) '<- buffer
Open App.Path & "\" & "Def.lst" For Binary As #2
Get #2, 1, strDef
Close #2
 
'Chargement des Strings
strMot = Space(LOF(3)) '<- buffer
Open App.Path & "\" & "Mot.lst" For Binary As #3
Get #3, 1, strMot
Close #3

**TheBlackReverand** · 21/10/2006, 13h25

je viens de corriger le buffer d'ecriture et lecture mais le problème ne change pas.... il m'insert toujours des champ vide dans mes list

**Delbeke** · 21/10/2006, 13h37

Je pense que ThierryAIM a fait une petite erreur dans la sequence des lignes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
'Chargement des Strings
Open App.Path & "\" & "Def.lst" For Binary As #2
  strDef = Space(LOF(2)) '<- buffer
  Get #2, 1, strDef
Close #2
 
'Chargement des Strings
Open App.Path & "\" & "Mot.lst" For Binary As #3
  strMot = Space(LOF(3)) '<- buffer
  Get #3, 1, strMot
Close #3

**TheBlackReverand** · 21/10/2006, 13h58

SA MARCHEEEE

merci beaucoup!!

se morceau de code manquait dans nombreux de mes programme et je vais pouvoir bien avancer

par contre pourrais tu me dir a quoi sert se buffer?? et comment il fonctionne??

car c'est bien de savoir le fair mais encore mieu de comprendre comment on le fait

merci a tous

**Delbeke** · 21/10/2006, 14h50

En mode binaire, le get #hfich,, strTemp lit dans le fichier autant d'octets que la taille de la variable strTemp, il faut donc dimensionner la variable à la bonne taille, d'ou l'instruction Lof(hFich) pour connaitre la taille du fichier.
Seulement l'intruction lof(hFich) ne fonctionne que sur un fichier ouvert.

Sauvegarde contenus combobox

VB 6 et antérieur

Discussions similaires

Partager

Partager