Discussion :

[Jeff_55]

Bonjour,

Je me présente, ancien analyste programmeur (VB, Turbo Pascal, Windev, C/C++, SQL, .....)
Je connais un peu la programmation sans être un monstre.

Je suis maintenant dans une autre entreprise, à un autre poste, et j'aimerais développer, afin d'aider mon service, un utilitaire (en vba sous excel 365).

Le but est de rechercher une référence saisie (ex:VP 7010) dans une arborescence de fichier autocad.

J'ai déjà développé toute la partie de parcours de fichiers prenant en compte un dossier et ses sous-dossiers correspondants =>ok

Ma plus grosse difficulté est la méthode à utiliser afin d'ouvrir un fichier autocad, recherche de ma référence saisie dans les zones de texte du fichier autocad et ensuite refermer le fichier

Si quelqu'un à des idées et du temps pour m'orienter, m'aider.....

En espérant avoir était clair, je vous remercie par avance.

Geoffroy.

[Franc]

Salut, ceci devrait te servir de base de travail, adapte en fonction de ton code déjà existant. N'oublie pas de référencer la bibliothèque ACAD dans VBA.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Sub RechercherReferenceAutoCAD()
    Dim acadApp As Object
    Dim acadDoc As Object
    Dim textObj As Object
    Dim refRecherche As String
    Dim dossier As String
 
 
    refRecherche = "VP 7010" ' À remplacer par votre référence
    dossier = "C:\Chemin\Vers\Votre\Fichier.dwg" ' Chemin du fichier AutoCAD
 
    ' Ouvrir AutoCAD
    On Error Resume Next
    Set acadApp = GetObject(, "AutoCAD.Application")
    If acadApp Is Nothing Then
        Set acadApp = CreateObject("AutoCAD.Application")
        acadApp.Visible = True
    End If
    On Error GoTo 0
 
    ' Ouvrir le fichier AutoCAD
    Set acadDoc = acadApp.Documents.Open(dossier)
 
    ' Parcourir tous les objets du modèle
    Dim found As Boolean
    found = False
    For Each textObj In acadDoc.ModelSpace
        ' Vérifier si l'objet est du texte
        If textObj.ObjectName = "AcDbText" Or textObj.ObjectName = "AcDbMText" Then
            ' Comparer le contenu du texte avec la référence
            If InStr(1, textObj.TextString, refRecherche, vbTextCompare) > 0 Then
                MsgBox "Référence trouvée : " & refRecherche
                found = True
                Exit For
            End If
        End If
    Next textObj
 
    ' Fermer le fichier si la référence n'est pas trouvée
    If Not found Then
        MsgBox "Référence non trouvée dans le fichier " & dossier
    End If
 
    ' Fermer le fichier AutoCAD
    acadDoc.Close False
 
    Set acadDoc = Nothing
    Set acadApp = Nothing
End Sub

[Jeff_55]

Bonjour Frank,

Désolé pour ma réponse tardive mais j'ai eu des modifications de planning.

Je te remercie pour ta réponse, je suis sur que cela va m'aider .


Dès que je peux j'essaie cela.
Je te tiendrais au courant.

Salut,
Geoffroy.