Discussion :

[cincap]

Bonjour à toutes et à tous,

Avec mon fichier et FFmpeg je coupe une vidéo en .mp4.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
@echo off

TITLE : CINCAP Cut mp4

::color 0A vert
::color 0B bleu

color 0B
mode 89,21

chcp 65001 > nul

SETLOCAL

set "Dir=  "Cut %date:/=-% à %time:~0,2%h-%time:~3,2%m-%time:~6,2%s"

md %Dir%

ffmpeg -i CINFILM_1994.mp4 -ss 00:16:02 -t 00:03:10 -c:v copy -c copy -y %Dir%\CINFILM_1994_Cut.mp4

Existe t'il une possibilité lorsque le .bat est lancé de pouvoir choisir le fichier, le temps de début et de fin au format 00:00:00.

Merci de votre attention,

@+,

cincap

[ericlm128]

Je suppose que ton script est dans le même dossier tes vidéos.

Tu peux utiliser la complétion du batch pour renseigner le nom du "Fichier". Touche Tabulation lors de la demande du fichier, tu peux aussi mettre une partie comme la première lettre avec d'utiliser Tab.
Plusieurs appuie sur la touche Tab passera au fichier suivant et Shift + tab reviens en arrière.
Sinon tu peux glisser le fichier dans la fenêtre batch ou le saisir à la main ...a ta guise.

J'ai ajouté un contrôle sur le format de début/durée.

Je te propose ceci.

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
cls
@echo off
 
TITLE : CINCAP Cut mp4
 
::color 0A vert
::color 0B bleu
 
color 0B
mode 89,21
 
chcp 65001 > nul
 
SETLOCAL
 
set /p "InputFilePath=Fichier : "
set /p "StartTime=Début (ex : 00:16:02) : "
echo %StartTime%| findstr /r /c:"^[0-9][0-9]:[0-9][0-9]:[0-9][0-9]$" 1>nul || (echo Chaine non valide !&pause&exit)
set /p "Duree=Durée (ex : 00:03:10) : "
echo %Duree%| findstr /r /c:"^[0-9][0-9]:[0-5][0-9]:[0-5][0-9]$" 1>nul || (echo Chaine non valide !&pause&exit)
 
for /f "tokens=*" %%a in ('echo %InputFilePath%') do set "InputFileName=%%~nxa"
set "Dir=Cut %date:/=-% à %time:~0,2%h-%time:~3,2%m-%time:~6,2%s"
md "%Dir%"
 
ffmpeg -i "%InputFileName%" -ss %StartTime% -t %Duree% -c:v copy -c copy -y "%Dir%\%InputFileName%"

[cincap]

Bonjour à toutes et à tous,

@ ericlm128,

merci de ta solution, c'est bien cela que j'aurai aimé de faire.

Au test, pour le choix du fichier avec la touche Tab, j'obtiens le nom d'un autre fichier que le .mp4 par contre en tapant la 1ère lettre du fichier .mp4 c'est parfait comme toutes tes solutions sur ce forum.

Je regarde aussi le pourquoi du choix du fichier.

@+,

cincap

[cincap]

@ericlm128, oups désolé, cela fonctionne correctement, j'avais passé l'appui sur la touche Tab jusqu'au moment de trouver le fichier .mp4

Le topic peut être fermé avec tous mes remerciements.

@+,

cincap

[cincap]

@ ericlm128, juste une petite question.

Avec "%Dir%\%InputFileName%"

j'aimerai ajouter _R avant le nom du film ex: Monfilm.mp4 pour le différencier de l'original soit Monfilm_R.mp4.

Penses tu que c'est faisable ?

@+,

cincap

[ericlm128]

Oui bien sur, je modifie aussi légèrement le code au passage

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
cls
@echo off
 
TITLE : CINCAP Cut mp4
 
::color 0A vert
::color 0B bleu
 
color 0B
mode 89,21
chcp 65001 > nul
 
set /p "InputFilePath=Fichier : "
set /p "StartTime=Début (ex : 00:16:02) : "
echo %StartTime%| findstr /r /c:"^[0-9][0-9]:[0-9][0-9]:[0-9][0-9]$" 1>nul || (echo Chaine non valide !&pause&exit)
set /p "Duree=Durée (ex : 00:03:10) : "
echo %Duree%| findstr /r /c:"^[0-9][0-9]:[0-5][0-9]:[0-5][0-9]$" 1>nul || (echo Chaine non valide !&pause&exit)
 
for /f "tokens=*" %%a in ("%InputFilePath%") do (
	set "InputFileName=%%~nxa"
	set "OutputFileName=%%~na_R%%~xa"
)
 
set "Dir=Cut %date:/=-% à %time:~0,2%h-%time:~3,2%m-%time:~6,2%s"
md "%Dir%"
 
ffmpeg -i "%InputFileName%" -ss %StartTime% -t %Duree% -c:v copy -c copy -y "%Dir%\%OutputFileName%"

[cincap]

Bonjour à toutes et à tous,

@ericlm128, grand merci pour ta solution, c'est impeccable.

Topic fermé avec grande satisfaction.

@+,

cincap

[cincap]

Bonjour à toutes et à tous,

@ericlm128, Avec ta solution, j'aurai aimé sauver le nom du répertoire dans un fichier Dir.txt afin d'utiliser la ligne pour faciliter une lecture du .mp4.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
ffmpeg -i "%InputFileName%" -ss %StartTime% -t %Duree% -c:v copy -c copy -y "%Dir%\%OutputFileName%" 

Echo %Dir% >Dir.txt

J'ai bien mon fichier avec le nom du répertoire mais apparement au format Utf8, existe t'il un moyen de l'obtenir au format Ansi ?

J'ai testé plusieurs solutions depuis le net mais niet...

Merci d'avance,

@+,

cincap

[ericlm128]

Oui

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
chcp 1252
Echo %Dir% >Dir.txt

[cincap]

Bonjour à toutes et à tous,

@ericlm128, merci de ta réponse, dans mon test je l'avais mis au début du code, je ne savais pas que l'on pouvait le placer juste avant une instruction !

En tous les cas merci pour tout.

@+,

cincap