Affichage 2eme textbox après saisie 1ere textbox et passage focus

**IphilG00d** · 03/11/2024, 19h54

Bonjour à tous et merci d'avance pour votre temps et votre aide

Malgré mes recherches je n'ai pas trouvé de solution à mon problème. Peut-être s'agit-il d'un problème de conception.
Dans un formulaire Excel j'ai 2 textbox (F_List_Nom et F_List_Discipline) et un bouton F_BUT_Enregistrer.
A l'appel de mon formulaire je rend invisible la deuxième textbox(F_List_Discipline) ainsi que le bouton F_BUT_Enregistrer.
J'aimerais qu'après la saisie de la première textbox je rende visible la deuxieme textbox et le bouton et que le focus passe directement sur cette deuxième textbox.
Le code VBA semble donc relativement simple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub UserForm_Initialize()
    'Effacement champs
    Me.Controls.Item("F_List_Discipline").Visible = False
    Me.Controls.Item("F_List_Discipline").Enabled = False
    Me.Controls.Item("F_BUT_Enregistrer").Visible = False
    Me.Controls.Item("F_BUT_Enregistrer").Enabled = False
End Sub
 
Private Sub F_List_Nom_Change()
    'Effacement champs
    Me.Controls.Item("F_List_Discipline").Visible = False
    Me.Controls.Item("F_List_Discipline").Enabled = False
    Me.Controls.Item("F_BUT_Enregistrer").Visible = False
    Me.Controls.Item("F_BUT_Enregistrer").Enabled = False
End Sub
 
Private Sub F_List_Nom_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If Me.Controls.Item("F_List_Nom").Text <> "" Then
        Me.Controls.Item("F_List_Discipline").Visible = True
        Me.Controls.Item("F_List_Discipline").Enabled = True
        Me.Controls.Item("F_List_Discipline").SetFocus
    End If
End Sub
 
Private Sub F_List_Discipline_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    'Affichage zones saisie
    If Me.Controls.Item("F_List_Discipline").Text <> "" Then
        Me.Controls.Item("F_BUT_Enregistrer").Visible = True
        Me.Controls.Item("F_BUT_Enregistrer").Enabled = True
    End If
End Sub
 
Private Sub F_BUT_Enregistrer_Click() ' Enregistre points saisis
    If Me.Controls.Item("F_List_Discipline").Text <> "" Then
        MsgBox ("Fiche Point enregistrée")
        Unload Me
    End If
End Sub

Nom : 2024-11-03 19_49_36-Microsoft Visual Basic pour Applications - test.xlsm - [test.xlsm - UF_Grill.png
Affichages : 113
Taille : 8,8 Ko

Nom : 2024-11-03 19_52_40-test.xlsm - Excel.png
Affichages : 104
Taille : 4,0 Ko

Hors à l'exécution, le focus boucle sur la 1ère textbox (F_List_Nom) et la 2ème textbox ainsi que le bouton reste invisibles.
J'avoue ne rien comprendre

Merci encore pour votre expérience

Phil

**Franc** · 04/11/2024, 10h11

Salut, tu utilises l'évènement _Change du textbox, mais à quel moment tu quittes le textbox ? A un moment il faut valider ton entrée, ce que tu ne fais pas, donc _Change tourne en boucle et tes contrôles restent invisibles.
J'utilise _KeyDown pour détecter l'appui sur ENTER ou TAB, change si nécessaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub UserForm_Initialize()
    Me.F_List_Discipline.Visible = False
    Me.F_BUT_Enregistrer.Visible = False
End Sub
 
Private Sub F_List_Nom_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    ' Si l'utilisateur appuie sur Entrée (13) ou Tab (9)
    If KeyCode = 13 Or KeyCode = 9 Then
        If Me.F_List_Nom.Text <> "" Then
            Me.F_List_Discipline.Visible = True
            Me.F_List_Discipline.SetFocus
            KeyCode = 0 ' Empêche un comportement supplémentaire après la touche
        Else
            MsgBox "Veuillez saisir une valeur dans le champ 'Nom' avant de continuer.", vbExclamation
        End If
    End If
End Sub
 
Private Sub F_List_Discipline_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    ' Si l'utilisateur appuie sur Entrée (13) ou Tab (9)
    If KeyCode = 13 Or KeyCode = 9 Then
        If Me.F_List_Discipline.Text <> "" Then
            Me.F_BUT_Enregistrer.Visible = True
            KeyCode = 0 ' Empêche un comportement supplémentaire après la touche
        Else
            MsgBox "Veuillez saisir une valeur dans le champ 'Discipline' avant de continuer.", vbExclamation
        End If
    End If
End Sub
 
Private Sub F_BUT_Enregistrer_Click()
    If Me.F_List_Nom.Text <> "" And Me.F_List_Discipline.Text <> "" Then
        MsgBox "Fiche Point enregistrée"
        Unload Me
    Else
        MsgBox "Veuillez remplir tous les champs avant d'enregistrer.", vbExclamation
    End If
End Sub

**Valtrase** · 04/11/2024, 11h08

Bonjour,
Tout d'abords appelons les contrôles par leurs types respectifs, Vous nous parlez de zone de texte alors que l'image montre des zone de listes déroulantes.
Puis nul besoin de passer par la collection de contrôle du formulaire, un simple F_List_Discipline.Visible fait l'affaire.
Concernant vôtre demande vous pouvez tester si la valeur de vos zone de liste sont à remplies. Si oui alors on affiche les contrôles concernés.
Nul besoin de mettre les propriétés visible et Enabled à False, si les contrôles ne sont pas visible aucune interaction ne sera possible.
Donc cela donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub UserForm_Initialize()
    With F_List_Nom
        F_List_Discipline.Visible = (.Value > vbNullString)
        F_BUT_Enregistrer.Visible = (.Value > vbNullString)
    End With
End Sub
 
Private Sub F_List_Nom_Change()
    With F_List_Nom
        F_List_Discipline.Visible = (.Value > vbNullString)
    End With
End Sub
 
Private Sub F_List_Discipline_Change(ByVal Cancel As MSForms.ReturnBoolean)
    With F_List_Discipline
        F_BUT_Enregistrer.Visible = (.Value > vbNullString)
    End With
End Sub
 
Private Sub F_BUT_Enregistrer_Click()            ' Enregistre points saisis
    If F_List_Discipline.Text <> vbNullString Then
        MsgBox ("Fiche Point enregistrée")
        Unload Me
    End If
End Sub

Nous pouvons aussi tester que la valeur entrée dans la zone de liste fait bien partie de la liste des Items:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub UserForm_Initialize()
        F_List_Discipline.Visible = False
        F_BUT_Enregistrer.Visible = False
End Sub
 
Private Sub F_List_Nom_Change()
    With F_List_Nom
 
        F_List_Discipline.Visible = (.ListIndex > -1)
    End With
End Sub
 
Private Sub F_List_Discipline_Change(ByVal Cancel As MSForms.ReturnBoolean)
    With F_List_Discipline
        F_BUT_Enregistrer.Visible = (.ListIndex > -1)
    End With
End Sub
 
Private Sub F_BUT_Enregistrer_Click()            ' Enregistre points saisis
    If F_List_Discipline.ListIndex > -1 Then
        MsgBox ("Fiche Point enregistrée")
        Unload Me
    End If
End Sub

ps : Code tapé à la volée et non testé.

**IphilG00d** · 04/11/2024, 12h07

Envoyé par Valtrase

Bonjour,
Tout d'abords appelons les contrôles par leurs types respectifs, Vous nous parlez de zone de texte alors que l'image montre des zone de listes déroulantes.
Puis nul besoin de passer par la collection de contrôle du formulaire, un simple F_List_Discipline.Visible fait l'affaire.
Concernant vôtre demande vous pouvez tester si la valeur de vos zone de liste sont à remplies. Si oui alors on affiche les contrôles concernés.
Nul besoin de mettre les propriétés visible et Enabled à False, si les contrôles ne sont pas visible aucune interaction ne sera possible.
Donc cela donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub UserForm_Initialize()
    With F_List_Nom
        F_List_Discipline.Visible = (.Value > vbNullString)
        F_BUT_Enregistrer.Visible = (.Value > vbNullString)
    End With
End Sub
 
Private Sub F_List_Nom_Change()
    With F_List_Nom
        F_List_Discipline.Visible = (.Value > vbNullString)
    End With
End Sub
 
Private Sub F_List_Discipline_Change(ByVal Cancel As MSForms.ReturnBoolean)
    With F_List_Discipline
        F_BUT_Enregistrer.Visible = (.Value > vbNullString)
    End With
End Sub
 
Private Sub F_BUT_Enregistrer_Click()            ' Enregistre points saisis
    If F_List_Discipline.Text <> vbNullString Then
        MsgBox ("Fiche Point enregistrée")
        Unload Me
    End If
End Sub

Nous pouvons aussi tester que la valeur entrée dans la zone de liste fait bien partie de la liste des Items:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub UserForm_Initialize()
        F_List_Discipline.Visible = False
        F_BUT_Enregistrer.Visible = False
End Sub
 
Private Sub F_List_Nom_Change()
    With F_List_Nom
 
        F_List_Discipline.Visible = (.ListIndex > -1)
    End With
End Sub
 
Private Sub F_List_Discipline_Change(ByVal Cancel As MSForms.ReturnBoolean)
    With F_List_Discipline
        F_BUT_Enregistrer.Visible = (.ListIndex > -1)
    End With
End Sub
 
Private Sub F_BUT_Enregistrer_Click()            ' Enregistre points saisis
    If F_List_Discipline.ListIndex > -1 Then
        MsgBox ("Fiche Point enregistrée")
        Unload Me
    End If
End Sub

ps : Code tapé à la volée et non testé.

Bonjour Valtrase,
Merci à toi aussi d'avoir pris le temps de me répondre. J'ai utilisé le code de Franc qui a solutionné mon problème, ou plutôt corriger mes erreurs de logiques.
Tu as raison je faisais référence à tes list-box et non des text-box (erreur d'attention).
Je garde ton code très intéressant par rapport à l'utilisation de .ListIndex qui va me servir dans un autre module.
Merci encore

**IphilG00d** · 04/11/2024, 11h56

Envoyé par Franc

Salut, tu utilises l'évènement _Change du textbox, mais à quel moment tu quittes le textbox ? A un moment il faut valider ton entrée, ce que tu ne fais pas, donc _Change tourne en boucle et tes contrôles restent invisibles.
J'utilise _KeyDown pour détecter l'appui sur ENTER ou TAB, change si nécessaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub UserForm_Initialize()
    Me.F_List_Discipline.Visible = False
    Me.F_BUT_Enregistrer.Visible = False
End Sub
 
Private Sub F_List_Nom_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    ' Si l'utilisateur appuie sur Entrée (13) ou Tab (9)
    If KeyCode = 13 Or KeyCode = 9 Then
        If Me.F_List_Nom.Text <> "" Then
            Me.F_List_Discipline.Visible = True
            Me.F_List_Discipline.SetFocus
            KeyCode = 0 ' Empêche un comportement supplémentaire après la touche
        Else
            MsgBox "Veuillez saisir une valeur dans le champ 'Nom' avant de continuer.", vbExclamation
        End If
    End If
End Sub
 
Private Sub F_List_Discipline_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    ' Si l'utilisateur appuie sur Entrée (13) ou Tab (9)
    If KeyCode = 13 Or KeyCode = 9 Then
        If Me.F_List_Discipline.Text <> "" Then
            Me.F_BUT_Enregistrer.Visible = True
            KeyCode = 0 ' Empêche un comportement supplémentaire après la touche
        Else
            MsgBox "Veuillez saisir une valeur dans le champ 'Discipline' avant de continuer.", vbExclamation
        End If
    End If
End Sub
 
Private Sub F_BUT_Enregistrer_Click()
    If Me.F_List_Nom.Text <> "" And Me.F_List_Discipline.Text <> "" Then
        MsgBox "Fiche Point enregistrée"
        Unload Me
    Else
        MsgBox "Veuillez remplir tous les champs avant d'enregistrer.", vbExclamation
    End If
End Sub

Hello Franc,
Tout d'abord merci pour tes efforts. Effectivement je pensais que l'évènement EXIT permettait de valider ma saisie. Ton code fonctionne à merveille.
Vraiment merci ... je commençais à tourner en rond comme ma list-box

Affichage 2eme textbox après saisie 1ere textbox et passage focus [XL-2016]

Macros et VBA Excel

Vue hybride

Discussions similaires

Partager

Partager