Discussion :

[amateur_will]

bonjour a tous, je me vois bloqué, avec se type d'erreur "6" 'dépassement de capacité'

le code a déjà bien fonctionné, mais j'ai récupéré, un format de date différent (comme visible dans se post ci-dessous )

le scénario est le suivant:

la source vient d'un fichier csv format date ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
1993012;SA;19930327;19930526.....

ensuite aussi simple, je récupère la date qui est en indice(2) ; que je mets dans ma colonne 2

le code d'extraction ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Open fichier For Input As #1
    Do While Not EOF(1)
    Line Input #1, texte
        If compteur > 1 Then
            elements = Split(texte, ";")
            'Cells(ligne, 2).Value = DateValue(Format(elements(2), "dd/mm/yyyy")) '( sur se format de date, le code fonctionne correctement )
            Cells(ligne, 2).Value = DateValue(Format(elements(2), "yyyymmdd"))
            For i = 3 To 8 'Correspondance - décalage une colonne
                Cells(ligne, i).Value = elements(i + 1)
            Next i
            ligne = ligne + 1
        End If
         'MsgBox texte
        compteur = compteur + 1
    Loop
Close #1

mais je m'aperçois, que la ligne : DateValue(Format(elements(2), "yyyymmdd" me pose problème, et je comprends pas le 'dépassement de capacité'

tous, est spécifiés dans mon fichier csv, d'où je veux extraire la date; mais pour la méthode format, je l'ai correctement renseigné ?? ( extrait du fichier csv plus haut )

merci a tous solutions de contournements , je veux exploité aussi les dates de "1993"

[deedolith]

Salut,

Peut être en passant par une regex:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Public Function GetDate(ByVal Value As String) As Date
    Dim Rx As Object    '// VBScript.RegExp
    Set Rx = CreateObject("VBScript.RegExp")
 
    Rx.MultiLine = False
    Rx.Global = False
        '// Format attendu: yyyymmdd
    Rx.Pattern = "(\d{4})((?:0[1-9])|(?:1[012]))((?:0[1-9])|(?:[12]\d)|(?:3[01]))"
 
        '// Si l'assertion se déclenche,
        '// C'est que l'argument donné à la fonction n'est pas bon
        '// Faute de programmation
    Debug.Assert Rx.Test(Value)
 
    Dim Jour As Integer
    Jour = CInt(Rx.Replace(Value, "$3"))
 
    Dim Mois As Integer
    Mois = CInt(Rx.Replace(Value, "$2"))
 
    Dim Annee As Integer
    Annee = CInt(Rx.Replace(Value, "$1"))
    GetDate = DateSerial(Annee, Mois, Jour)
End Function

[jurassic pork]

Hello,

Peut être en passant par une regex:

toujours en regex mais en plus simple car pas de vérification que la chaîne date est valide. Accepte des chaînes date sous forme yyyymmd ou yyyymmdd :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Public Function GetDate(ByVal Value As String) As Date
    Dim Rx As Object    '// VBScript.RegExp
    Set Rx = CreateObject("VBScript.RegExp")
    Rx.Pattern = "(\d{4})(\d{2})(\d{1,2})"
    GetDate = DateValue(Rx.Replace(Value, "$3/$2/$1"))
End Function
 
 
Sub TestDateJP()
  Debug.Print Format(GetDate(1993022), "dd/mm/yyyy")
  Debug.Print Format(GetDate(19981225), "dd/mm/yyyy")
End Sub

Ami calmant, J.P

[amateur_will]

Bonjour à deedolith, et merci pour l'exemple donné, que je vais essayé...je donnerai la suite

et merci à jurassic pork, de son exemple aussi donné, que je vais essayé

[amateur_will]

Bravo à vous 2 , mais après la remarque de jurassic pork, j'ai pris mes précautions et avoir essayé quand même

la fonction de deedoliht , qui m'a mis quelques erreurs .

j'ai essayé la fonction de jurrassic pork; qui est un concentré de ligne essentiel; et simple bravo...!! pour cette robustesse .

mon code se déroule correctement .....

[deedolith]

la fonction de deedoliht , qui m'a mis quelques erreurs .

heu ouais ?
Lesquelles ?