Discussion :

[emilie46120]

onjour à tous

Besoin de votre aide,

J'ai une feuille qui s'appelle "aperçu" et qui contient un tableau à 3 colonnes et 13 lignes.

Je voudrais que ce tableau apparaisse dans mon userForm

Malgré mes recherches je n'y arrive pas, pouvez-vous m'aider

Merci

[deedolith]

Salut,

Le contrôle ListView peut faire le job (il faut ajouter une référence à mscomctl.ocx).

[jurassic pork]

Hello,
pour la listview il y a un exemple ici

Edit : Voici un exemple avec l'affichage d'un tableau de trois colonnes d'une feuille dans un formulaire.
Le code du formulaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
'Force the explicit declaration of variables
Option Explicit
 
Private Sub CommandButton1_Click()
'Unload the UserForm
    Unload Me    
End Sub
 
Private Sub UserForm_Activate()
    'Set a reference to Microsoft Windows Common Controls by
    'using Tools > References in the Visual Basic Editor (Alt+F11)
    'Set some of the properties for the ListView
    With Me.ListView1
        .Gridlines = True
        .HideColumnHeaders = False
        .View = lvwReport
    End With    
    'Call the sub to fill the ListView
    Call LoadListView
End Sub
 
 
Private Sub LoadListView()
    'Declare the variables
    Dim wksSource As Worksheet
    Dim rngData As Range
    Dim rngCell As Range
    Dim LstItem As ListItem
    Dim RowCount As Long
    Dim ColCount As Long
    Dim i As Long
    Dim j As Long
 
    'Set the source worksheet
    Set wksSource = Worksheets("Sheet1")
 
    'Set the source range
    Set rngData = wksSource.Range("A1").CurrentRegion
 
    'Add the column headers
    For Each rngCell In rngData.Rows(1).Cells
        Me.ListView1.ColumnHeaders.Add Text:=rngCell.Value, Width:=90
    Next rngCell
 
    'Count the number of rows in the source range
    RowCount = rngData.Rows.Count
 
    'Count the number of columns in the source range
    ColCount = rngData.Columns.Count
 
    'Fill the ListView
    For i = 2 To RowCount
        Set LstItem = Me.ListView1.ListItems.Add(Text:=rngData(i, 1).Value)
        For j = 2 To ColCount
            LstItem.ListSubItems.Add Text:=rngData(i, j).Value
        Next j
    Next i
 
End Sub

Ami calmant, J.P