Discussion :

[tacleur]

Bonjour à toute la communauté !

J'espère que vous allez bien.

Je réalise des extractions de données. Dans un souci de nettoyer les données inutiles afin de les exploiter, je souhaite créer un code VBA.
J'ai quelques bases mais je ne trouve pas la solution pour ce que je souhaite réalsier.

Mon tableau excel comporte de nombreuses lignes et colonne.
Dans une colonne, j'ai la date du jour sous format "31/08/2023 09:00:35"
Je souhaiterai que chaque jour, on ne garde que la ligne ayant l'heure la plus tardive entre 18h et 21H.
Une fois trouvé, les autres lignes du jour peuvent alors être supprimées par le code.

Je n'aurai alors qu'une ligne par jour dans mon tableur où l'heure max sera bien entre 18h et 21h.

J'espère avoir été explicite. Si ce n'est pas le cas, n'hésitez pas, je fournirai d'autres détails.

Belle journée,

Bob

[ARTURO83]

Bonjour,

Vos ne donnez aucune précision, vu que c'est une extraction de données, on peut penser que le format de la date/heure n'est pas au format excel donc, il faudra peut-être faire une manipulation de ce côté là.
Dans quelle colonne se trouve la date?
Les dates sont elles rangées dans l'ordre chronologique?

Le plus simple est de fournir un extrait de votre fichier anonymisé, et vous obtiendrez plus facilement des réponses.

Sinon pour le principe:
-En premier lieu, faire un tri chronologique (de l'ancienne date à la plus récente).
-Puis faire une bouche qui part de l'avant dernière ligne en remontant vers la première ligne, en testant la date de la ligne traitée par rapport à la date de la ligne suivante,
-Si c'est le même jour alors, supprimer la ligne en cours,
-Sinon, c'est forcément la date avec l'horaire le plus tardif et donc, on conserve la ligne.
-On passe à la ligne du dessus et on recommence le test.

Cdlt

[Franc]

Bonjour, voici une méthode basée sur l'idée de ARTURO83 (que je salue).
Je considère que les dates sont en colonne A et démarrent en ligne 2. Adapte au besoin.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Sub NettoyerDonnees()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim dictDates As Object
    Set dictDates = CreateObject("Scripting.Dictionary")
 
    ' Remplacez "Feuil1" par le nom de votre feuille de données
    Set ws = ThisWorkbook.Sheets("Feuil1")
 
    ' Trouver la dernière ligne avec des données
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
 
    ' Supprimer les lignes qui ne sont pas dans la plage horaire (18h à 21h)
    For i = lastRow To 2 Step -1
        ' Extraire la date et l'heure
        Dim dateValeur As Date
        dateValeur = ws.Cells(i, 1).Value
 
          ' Vérifier si l'heure est dans la plage horaire
        If Hour(dateValeur) < 18 Or Hour(dateValeur) >= 21 Then
            ' Si l'heure n'est pas dans la plage, supprimer la ligne
            ws.Rows(i).Delete
        End If
    Next i
 
    ' Trier le tableau par date et heure (colonne A)
    With ws.Sort
        .SortFields.Clear
        .SortFields.Add Key:=Range("A2:A" & lastRow), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange ws.UsedRange
        .MatchCase = False
        .Orientation = xlTopToBottom
        .Apply
    End With
    ' Parcourir les lignes restantes du bas vers le haut pour éviter les problèmes lors de la suppression
    For i = lastRow To 3 Step -1
        ' Extraire la date
        dateValeur = ws.Cells(i, 1).Value
 
         ' Si la date n'est pas déjà dans le dictionnaire, l'ajouter
        If Not dictDates.exists(Int(dateValeur)) Then
            dictDates.Add Int(dateValeur), i
        Else
            ' Si la date est déjà présente, supprimer la ligne puisque suite au tri
            ' c'est forcément l'heure la plus élevée qui est dans le dictionnaire
            ws.Rows(i).Delete
        End If
    Next i
End Sub

[tacleur]

Bonjour,

Je tiens à vous remercier pour votre aide.
Cela a été très utile !

Merci !!!!

Belle journée,