Discussion :

[jeff1494]

Bonjour à toutes et tous;
J'aimerais savoir comment trier deux colonnes liées, à savoir que dans la colonne A j'ai des catégories d'objets, et pour chaque catégorie j'ai plusieurs type d'objets.

• La colonne A est nommée "Categorie" et définie avec DECALER.
• La colonne B est nommée "Typ" et définie avec DECALER.

Je voudrais en VBA pouvoir trier les colonnes de la manière suivante :
Tri sur la colonne A (Ascendant) PUIS sur la colonne B Ascendant également.

Ces deux colonnes sont utilisées dans un formulaire et bien sûr il y a la possibilité d'ajouter de nouvelles valeurs soit dans la catégorie soit dans le type. Ajout nouvelle catégorie, soit ajout nouveau type objet dans une catégorie existante. A la fermeture du formulaire si la catégorie ou le type n'existent pas dans la liste alors on l'ajoute. Et donc je veut trier l'ensemble, une fois l'ajout fait.

Je joins un fichier exemple à toutes fins utiles.
D'avance un grand merci à tous ceux et celles qui voudront bien m'aider.

Bonne journée à vous.

Voici le fichier en question JFCtri.xlsm

[Franc]

Bonjour, pas sûr de bien comprendre. Tu veux trier la colonne A puis la colonne B indépendamment l'une de l'autre ?
Si avant le tri tu as par exemple Sacs en A et Besace en B, après le tri ça pourrait être Sacs en A et Ras du cou en B ?

[jeff1494]

Bonsoir Franc, et merci pour ta réponse.

En fait je veux regrouper tous les éléments d'une même catégorie (triée en ordre ascendant) et pour cette catégorie tous les types d'objets (triés en ordre ascendant).

Par exemple :

ColA ColB
Bijoux Autres
Bijoux Bague
Bijoux Boucles oreilles
Bijoux Bracelet
Bijoux Collier
Bijoux Montre
Bijoux Ras de Cou
Chaussures Autres
Chaussures Sport-Randonnée
Chaussures Ville talons bas
Chaussures Ville Talons hauts
Déco Divers
Déco Lampes
Déco Statuettes


J'espère que j'ai mieux expliqué ce que je veux.
Merci d'avance.

[Franc]

Voilà qui devrait faire l'affaire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub TrierCatEtType()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim sortRange As Range
 
    Set ws = ThisWorkbook.Worksheets("BDCAT")
 
    ' Trouver la dernière ligne avec des données dans la colonne A
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
 
    ' Définir la plage à trier (colonnes A et B)
    Set sortRange = ws.Range("A2:B" & lastRow)
 
    ' Trier d'abord par les catégories (colonne A) puis par les produits (colonne B)
    With ws.Sort
        .SortFields.Clear
        .SortFields.Add2 Key:=sortRange.Columns(1), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SortFields.Add2 Key:=sortRange.Columns(2), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange sortRange
        .Header = xlYes ' Si la première ligne contient des en-têtes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .Apply
    End With
End Sub

[jeff1494]

Merci Franc;
Je regarde ta solution et te tiens au courant.

[jeff1494]

Franc;
C'est parfait. il ne me reste plus qu'à éplucher ton code pour le comprendre.
Un grand merci.
Bonne soirée à toi.