Discussion :

[didier.007]

Bonjour,
,
je suis actuellement sur la construction d'un planning automatisé que je vous joins.
toutes les cellules de l'onglet "calendrier" récupèrent le texte dans l'onglet "données" a l'aide d'une fonction (Aucun saisie n'est acceptée dans calendrier).

Sur les mois de moins de 31 jours, J'ai #N/A dans les cellules.

Je ne trouve pas de solution pour ne plus voir ces caractères après le dernier jour du mois.

Merci d'avance.

Didier.
Planning Pro.xlsx

[njhub]

Bonjour didier.007, le forum,

Testez la formule ci-dessous en ligne 5, colonne AE dans la feuille "calendrier", à étendre vers la droite jusqu'en colonne AG

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(OU(ESTNUM(EQUIV(FIN.MOIS(DATE($A$1;$A$2;1);0);$A$5:AD$5;0));MOIS(AD5+1)<>MOIS(AD5));"";AD5+1)

D'autre part dans les lignes 8 à 16 des colonnes AE à AG essayez avec ESTERREUR à la place de ESTVIDE :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERREUR(INDEX($Données.$E$2:$NE$17;EQUIV($B$8;salariés;0);EQUIV(AE5;T_Dates;0)));"";INDEX($Données.$E$2:$NE$17;EQUIV($B$8;salariés;0);EQUIV(AE5;T_Dates;0)))

[Pierre Dumas]

Bonsoir

Si je puis me permettre, sans avoir regardé le fichier ni testé la formule, il me semblerait que l'on puisse faire plus simple que SI(ESTERREUR(... en utilisant tout simplement SIERREUR(

[...]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERREUR(INDEX($Données.$E$2:$NE$17;EQUIV($B$8;salariés;0);EQUIV(AE5;T_Dates;0)));"";INDEX($Données.$E$2:$NE$17;EQUIV($B$8;salariés;0);EQUIV(AE5;T_Dates;0)))

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX($Données.$E$2:$NE$17;EQUIV($B$8;salariés;0);EQUIV(AE5;T_Dates;0));"")

En espérant que cela aide

Bonne soirée

Pierre Dumas

[didier.007]

Bonsoir,

merci pour votre aide, vous m'avez permis de trouver.

La solution :

=SIERREUR(SI(MOIS($AG$5)=RECHERCHEV(calendrier!$A$2;T_Mois;2;FAUX);SI(ESTVIDE(INDEX(Données!$E$2:$NE$17;EQUIV($B$8;salariés;0);EQUIV($AG$5;T_Dates;0)));"";INDEX(Données!$E$2:$NE$17;EQUIV($B$8;salariés;0);EQUIV($AG$5;T_Dates;0)));"");"")

Bon Week end

Didier